build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'idea'
    id 'net.neoforged.moddev' version '2.0.42-beta'
    id 'org.jetbrains.kotlin.jvm' version '2.1.0'
}

repositories {
    mavenLocal()
    maven {
        name = 'Kotlin for Forge'
        url = 'https://thedarkcolour.github.io/KotlinForForge/'
        content { includeGroup "thedarkcolour" }
    }
    maven {
        // location of the maven that hosts JEI files since January 2023
        name = "Jared's maven"
        url = "https://maven.blamejared.com/"
    }
    maven {
        // location of a maven mirror for JEI files, as a fallback
        name = "ModMaven"
        url = "https://modmaven.dev"
    }
    maven {
        url = "https://www.cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
}

version = mod_version
group = mod_group_id

base {
    archivesName = mod_id
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)
kotlin.jvmToolchain(21)

neoForge {
    // Specify the version of NeoForge to use.
    version = project.neo_version

    parchment {
        minecraftVersion = "1.21.1"
        mappingsVersion = "2024.11.17"
    }

    accessTransformers {
        file('src/main/resources/META-INF/accesstransformer.cfg')
    }

    runs {
        client {
            client()
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        server {
            server()
            programArgument '--nogui'
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        gameTestServer {
            type = "gameTestServer"
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        data {
            data()
            programArguments.addAll(
                    '--mod', project.mod_id,
                    '--all',
                    '--output', file('src/generated/resources/').getAbsolutePath(),
                    '--existing', file('src/main/resources/').getAbsolutePath()
            )
        }

        configureEach {
            // Logging data for a UserDev environment
            // "SCAN": For mods scan.
            // "REGISTRIES": For firing of registry events.
            // "REGISTRYDUMP": For getting the contents of all registries.
            // systemProperty 'forge.logging.markers', 'REGISTRIES'
            logLevel = org.slf4j.event.Level.INFO
        }
    }

    mods {
        "${mod_id}" {
            sourceSet(sourceSets.main)
        }
    }
}

dependencies {
    // Mod Dependencies //

    // KFF
    implementation "thedarkcolour:kotlinforforge-neoforge:${kotlin_for_forge_version}"

    // Nvidia PhysX
    compileOnly("de.fabmax:physx-jni:2.5.0")

    // Mod Compatibility //

    // Jade (WAILA)
    implementation "curse.maven:jade-324717:5976517"
//    runtimeOnly "curse.maven:the-one-probe-245211:5836106"

    // Just Enough Items (JEI)
    compileOnly("mezz.jei:jei-1.21.1-neoforge-api:19.10.0.126")
    runtimeOnly("mezz.jei:jei-1.21.1-neoforge:19.10.0.126")

    // Mekanism
    compileOnly "mekanism:Mekanism:${mekanism_version}:api"

    runtimeOnly("mekanism:Mekanism:${mekanism_version}")
    runtimeOnly("mekanism:Mekanism:${mekanism_version}:additions")
    runtimeOnly("mekanism:Mekanism:${mekanism_version}:generators")
    runtimeOnly("mekanism:Mekanism:${mekanism_version}:tools")
}

// This block of code expands all declared replace properties in the specified resource targets.
// A missing property will result in an error. Properties are expanded using ${} Groovy notation.
var generateModMetadata = tasks.register("generateModMetadata", ProcessResources) {
    var replaceProperties = [minecraft_version      : minecraft_version,
                             minecraft_version_range: minecraft_version_range,
                             neo_version            : neo_version,
                             neo_version_range      : neo_version_range,
                             loader_version_range   : loader_version_range,
                             mod_id                 : mod_id,
                             mod_name               : mod_name,
                             mod_license            : mod_license,
                             mod_version            : mod_version,
                             mod_authors            : mod_authors,
                             mod_description        : mod_description]
    inputs.properties replaceProperties
    expand replaceProperties
    from "src/main/templates"
    into "build/generated/sources/modMetadata"
}

processResources {
    duplicatesStrategy(DuplicatesStrategy.EXCLUDE)
}

sourceSets.main.resources {
    srcDirs('src/generated/resources', generateModMetadata)
}

neoForge.ideSyncTask generateModMetadata

idea {
    module {
        downloadSources = true
        downloadJavadoc = true
    }
}