-
Notifications
You must be signed in to change notification settings - Fork 8
/
CMakeLists.txt
1266 lines (1087 loc) · 45.5 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# Top level CMakeLists.txt for CGAL
# The name of our project is "CGAL". CMakeLists files in this project can
# refer to the root source directory of the project as ${CGAL_SOURCE_DIR} or
# ${CGAL_SOURCE_DIR} and to the root binary directory of the project as
# ${CGAL_BINARY_DIR} or ${CGAL_BINARY_DIR}.
if(NOT PROJECT_NAME)
cmake_minimum_required(VERSION 3.12...3.29)
project(CGAL CXX C)
endif()
# Fix a bug: `try_compile` should use `CMAKE_EXE_LINKER_FLAGS`.
# That variable can contain important flags like
#
# -static-libstdc++ -static-libgcc
#
# Use GNUInstallDirs to get canonical paths
include(GNUInstallDirs)
#--------------------------------------------------------------------------------------------------
#--------------------------------------------------------------------------------------------------
#
# -= PACKAGE SETUP =-
#
#--------------------------------------------------------------------------------------------------
if(CGAL_BRANCH_BUILD)
message(STATUS "Build CGAL from ${CGAL_SCM_NAME}-branch: ${CGAL_SCM_BRANCH_NAME}")
# list packages
file(
GLOB CGAL_CONFIGURED_PACKAGES
RELATIVE ${CGAL_SOURCE_DIR}
"${CGAL_SOURCE_DIR}/*")
list(SORT CGAL_CONFIGURED_PACKAGES)
list(REMOVE_ITEM CGAL_CONFIGURED_PACKAGES copyright CMakeLists.txt .svn .git)
# detect and remove not existing package-directories
foreach(package ${CGAL_CONFIGURED_PACKAGES})
if(NOT IS_DIRECTORY "${CGAL_SOURCE_DIR}/${package}")
list(APPEND CGAL_WRONG_PACKAGES ${package})
elseif(NOT EXISTS
"${CGAL_SOURCE_DIR}/${package}/package_info/${package}/maintainer")
list(APPEND CGAL_WRONG_PACKAGES ${package})
endif()
endforeach()
find_program(
CGAL_CREATE_CMAKE_SCRIPT cgal_create_cmake_script HINT
${CGAL_SOURCE_DIR}/Scripts/scripts
DOC "Script cgal_create_cmake_script, that creates CMakeLists.txt files"
NO_DEFAULT_PATH NO_CMAKE_ENVIRONMENT_PATH)
if(DEFINED CGAL_WRONG_PACKAGES)
message(STATUS "Removed not-a-package: ${CGAL_WRONG_PACKAGES}")
list(REMOVE_ITEM CGAL_CONFIGURED_PACKAGES ${CGAL_WRONG_PACKAGES})
endif()
set(CGAL_CONFIGURED_PACKAGES_NAMES ${CGAL_CONFIGURED_PACKAGES})
set(CGAL_CONFIGURED_PACKAGES)
foreach(package ${CGAL_CONFIGURED_PACKAGES_NAMES})
list(APPEND CGAL_CONFIGURED_PACKAGES "${CGAL_SOURCE_DIR}/${package}")
endforeach()
set(CGAL_INSTALLATION_PACKAGE_DIR
"${CGAL_SOURCE_DIR}/Installation"
CACHE INTERNAL "Directory containing the Installation package")
set(CGAL_MAINTENANCE_PACKAGE_DIR
"${CGAL_SOURCE_DIR}/Maintenance"
CACHE INTERNAL "Directory containing the Maintenance package")
set(CGAL_CORE_PACKAGE_DIR
"${CGAL_SOURCE_DIR}/Core"
CACHE INTERNAL "Directory containing the Core package")
set(CGAL_GRAPHICSVIEW_PACKAGE_DIR
"${CGAL_SOURCE_DIR}/GraphicsView"
CACHE INTERNAL "Directory containing the GraphicsView package")
file(GLOB INCLUDE_CGAL_QT_DIRECTORIES "${CGAL_SOURCE_DIR}/*/include/CGAL/Qt")
message(STATUS "Include CGAL/Qt directories: ${INCLUDE_CGAL_QT_DIRECTORIES}")
message(STATUS "Installation package directory: ${CGAL_INSTALLATION_PACKAGE_DIR}")
message(STATUS "Maintenance package directory: ${CGAL_MAINTENANCE_PACKAGE_DIR}")
message(STATUS "Core package directory: ${CGAL_CORE_PACKAGE_DIR}")
else(CGAL_BRANCH_BUILD)
# get release name
file(TO_CMAKE_PATH ${CGAL_SOURCE_DIR} CMAKE_SOURCE_CDIR)
string(REGEX REPLACE "^/" "" CMAKE_SOURCE_DDIR ${CMAKE_SOURCE_CDIR})
string(REPLACE "/" ";" CMAKE_SOURCE_PDIR ${CMAKE_SOURCE_DDIR})
list(GET CMAKE_SOURCE_PDIR -1 CGAL_RELEASE_NAME)
message(STATUS "Build CGAL from release in directory ${CGAL_RELEASE_NAME}")
set(CGAL_CONFIGURED_PACKAGES_NAMES ${CGAL_RELEASE_NAME})
# list packages
set(CGAL_CONFIGURED_PACKAGES "${CGAL_SOURCE_DIR}")
set(CGAL_INSTALLATION_PACKAGE_DIR
"${CGAL_SOURCE_DIR}"
CACHE INTERNAL "Directory containing the Installation package")
set(CGAL_MAINTENANCE_PACKAGE_DIR
"${CGAL_SOURCE_DIR}"
CACHE INTERNAL "Directory containing the Maintenance package")
set(CGAL_CORE_PACKAGE_DIR
"${CGAL_SOURCE_DIR}"
CACHE INTERNAL "Directory containing the Core package")
set(CGAL_GRAPHICSVIEW_PACKAGE_DIR
"${CGAL_SOURCE_DIR}"
CACHE INTERNAL "Directory containing the GraphicsView package")
set(INCLUDE_CGAL_QT_DIRECTORIES "${CGAL_SOURCE_DIR}/include/CGAL/Qt")
# Enable testing with CGAL_ENABLE_TESTING. Before CGAL-6.0, users would enable
# the tests by specifying BUILD_TESTING. For compatibility, If BUILD_TESTING is
# set, that is the default value for CGAL_ENABLE_TESTING. Otherwise, the default
# value is OFF.
option(CGAL_ENABLE_TESTING "Build the testing tree." ${BUILD_TESTING})
if(CGAL_ENABLE_TESTING)
enable_testing()
endif()
endif(CGAL_BRANCH_BUILD)
#allow to force disabling boost multiprecision support
option(CGAL_DO_NOT_USE_BOOST_MP "Disable the support of boost multiprecision library" FALSE)
#message(STATUS "Packages found: ${CGAL_CONFIGURED_PACKAGES}")
list(SORT CGAL_CONFIGURED_PACKAGES_NAMES)
if(IS_DIRECTORY "${CGAL_SOURCE_DIR}/Documentation")
# Rescope CGAL_CONFIGURED_PACKAGES_NAMES
# We need this variable in the Doxygen configuration process. Reset it
# and change the scope to the parent scope.
# Philipp Moeller, 2013-05-302013-05-302013-05-30
set(CGAL_CONFIGURED_PACKAGES_NAMES
${CGAL_CONFIGURED_PACKAGES_NAMES}
PARENT_SCOPE)
endif()
message(STATUS "Packagenames: ${CGAL_CONFIGURED_PACKAGES_NAMES}")
message("== Setting paths (DONE) ==\n")
message("== Generate version files ==")
if(CGAL_BRANCH_BUILD)
#
# Create version files
#
file(REMOVE ${CGAL_BINARY_DIR}/VERSION)
if(CGAL_BUGFIX_VERSION AND CGAL_BUGFIX_VERSION GREATER 0)
set(CGAL_CREATED_VERSION_NUM
"${CGAL_MAJOR_VERSION}.${CGAL_MINOR_VERSION}.${CGAL_BUGFIX_VERSION}")
else()
set(CGAL_CREATED_VERSION_NUM "${CGAL_MAJOR_VERSION}.${CGAL_MINOR_VERSION}")
endif()
# Accessed in the documentation.
set(CGAL_CREATED_VERSION_NUM
${CGAL_CREATED_VERSION_NUM}
PARENT_SCOPE)
# TODO EBEB set number of internal release (replace "900")
set(CGAL_BUILD_VERSION 900)
set(CGAL_CREATED_VERSION
"${CGAL_CREATED_VERSION_NUM}-I-${CGAL_BUILD_VERSION}")
set(CGAL_VERSION "${CGAL_CREATED_VERSION_NUM}-I-${CGAL_BUILD_VERSION}")
file(WRITE "${CGAL_BINARY_DIR}/VERSION" "${CGAL_CREATED_VERSION_NUM}")
message(STATUS "CGAL_VERSION is ${CGAL_CREATED_VERSION}")
set(CGAL_FULL_VERSION
${CGAL_CREATED_VERSION}
CACHE INTERNAL "CGAL version")
#define CGAL_VERSION_NR 1030500135
string(LENGTH "${CGAL_MAJOR_VERSION}" CGAL_MAJOR_LEN)
if("${CGAL_MAJOR_LEN}" EQUAL 1)
set(CGAL_TMP_MAJOR "0${CGAL_MAJOR_VERSION}")
endif()
string(LENGTH "${CGAL_MINOR_VERSION}" CGAL_MINOR_LEN)
if("${CGAL_MINOR_LEN}" EQUAL 1)
set(CGAL_TMP_MINOR "0${CGAL_MINOR_VERSION}")
else()
set(CGAL_TMP_MINOR "${CGAL_MINOR_VERSION}")
endif()
set(CGAL_TMP_BUILD "${CGAL_BUILD_VERSION}")
string(LENGTH "${CGAL_TMP_BUILD}" CGAL_BUILD_LEN)
while(CGAL_BUILD_LEN LESS 4)
set(CGAL_TMP_BUILD "0${CGAL_TMP_BUILD}")
string(LENGTH "${CGAL_TMP_BUILD}" CGAL_BUILD_LEN)
endwhile()
set(CGAL_CREATED_VERSION_NR
"1${CGAL_TMP_MAJOR}${CGAL_TMP_MINOR}${CGAL_BUGFIX_VERSION}${CGAL_TMP_BUILD}"
)
message(STATUS "CGAL_VERSION_NR is ${CGAL_CREATED_VERSION_NR}")
message(STATUS "CGAL_GIT_HASH is ${CGAL_GIT_HASH}")
message(
STATUS "CGAL_CREATED_SVN_REVISION is ${CGAL_CREATED_SVN_REVISION} (dummy)")
file(REMOVE ${CGAL_BINARY_DIR}/include/CGAL/version.h)
string(TIMESTAMP CGAL_CREATED_RELEASE_DATE "%Y%m%d")
configure_file(
${CGAL_INSTALLATION_PACKAGE_DIR}/cmake/modules/config/version.h.in
${CGAL_BINARY_DIR}/include/CGAL/version.h @ONLY)
#
# Duplicate files
#
if(CGAL_REPORT_DUPLICATE_FILES)
message("== Searching for duplicate files ==")
foreach(package ${CGAL_CONFIGURED_PACKAGES})
file(GLOB_RECURSE CGAL_PACKAGE_HEADER_FILES FOLLOW_SYMLINKS
${package}/*.h)
list(SORT CGAL_PACKAGE_HEADER_FILES)
foreach(file ${CGAL_PACKAGE_HEADER_FILES})
string(REPLACE "${package}/" "" pure_file ${file})
if(NOT ${pure_file} MATCHES ".*CMakeFiles.*")
list(APPEND CGAL_HEADER_FILES ${pure_file})
endif()
endforeach()
file(GLOB_RECURSE CGAL_PACKAGE_CPP_FILES FOLLOW_SYMLINKS ${package}/*.cpp)
list(SORT CGAL_PACKAGE_CPP_FILES)
foreach(file ${CGAL_PACKAGE_CPP_FILES})
string(REPLACE "${package}/" "" pure_file ${file})
if(NOT ${pure_file} MATCHES ".*CMakeFiles.*")
list(APPEND CGAL_CPP_FILES ${pure_file})
endif()
endforeach()
endforeach()
list(SORT CGAL_HEADER_FILES)
set(CGAL_UNIQUE_HEADER_FILES ${CGAL_HEADER_FILES})
set(CGAL_DUPLICATE_HEADER_FILES ${CGAL_HEADER_FILES})
list(REMOVE_DUPLICATES CGAL_UNIQUE_HEADER_FILES)
#message(STATUS "Headers: ${CGAL_HEADER_FILES}")
foreach(file ${CGAL_UNIQUE_HEADER_FILES})
list(FIND CGAL_DUPLICATE_HEADER_FILES "${file}" CGAL_FILE_IDX)
list(REMOVE_AT CGAL_DUPLICATE_HEADER_FILES ${CGAL_FILE_IDX})
endforeach()
message(
STATUS
"Duplicate header files (will be repeated at end): ${CGAL_DUPLICATE_HEADER_FILES}"
)
list(SORT CGAL_CPP_FILES)
set(CGAL_UNIQUE_CPP_FILES ${CGAL_CPP_FILES})
set(CGAL_DUPLICATE_CPP_FILES ${CGAL_CPP_FILES})
list(REMOVE_DUPLICATES CGAL_UNIQUE_CPP_FILES)
#message(STATUS "CPPs: ${CGAL_CPP_FILES}")
foreach(file ${CGAL_UNIQUE_CPP_FILES})
list(FIND CGAL_DUPLICATE_CPP_FILES "${file}" CGAL_FILE_IDX)
list(REMOVE_AT CGAL_DUPLICATE_CPP_FILES ${CGAL_FILE_IDX})
endforeach()
message(
STATUS
"Duplicate cpp files (will be repeated at end): ${CGAL_DUPLICATE_CPP_FILES}"
)
endif(CGAL_REPORT_DUPLICATE_FILES)
else()
if(NOT EXISTS "${CGAL_SOURCE_DIR}/VERSION"
OR NOT EXISTS "${CGAL_SOURCE_DIR}/include/CGAL/version.h")
message(
FATAL_ERROR
"File VERSION or include/CGAL/version.h are missing, required by release-build."
)
endif()
#
# Read and parse CGAL version number from VERSION file
#
file(READ "${CGAL_SOURCE_DIR}/VERSION" CGAL_VERSION)
# Comment from Laurent Rineau, 2012/06/28:
# file(READ ..) should be replace by file(STRINGS ..), and then we take
# the first line. That would avoid parsing errors when the VERSION file
# contains a CR character!
set(CGAL_FULL_VERSION ${CGAL_VERSION})
string(REPLACE "-" "." CGAL_VERSION_TOKENS1 ${CGAL_VERSION})
string(REPLACE "." ";" CGAL_VERSION_TOKENS ${CGAL_VERSION_TOKENS1})
list(LENGTH CGAL_VERSION_TOKENS CGAL_VERSION_TOKENS_LEN)
list(GET CGAL_VERSION_TOKENS 0 CGAL_MAJOR_VERSION)
set(CGAL_MINOR_VERSION)
set(CGAL_BUGFIX_VERSION)
set(CGAL_BUILD_VERSION 1000)
if(CGAL_VERSION_TOKENS_LEN GREATER 1)
list(GET CGAL_VERSION_TOKENS 1 CGAL_MINOR_VERSION)
endif()
if(CGAL_VERSION_TOKENS_LEN GREATER 2)
list(GET CGAL_VERSION_TOKENS 2 CGAL_BUGFIX_VERSION)
# The following condition will be true the token #2 is not a number (if
# it is for example "I" or "Ic"):
if(NOT CGAL_BUGFIX_VERSION GREATER 0 AND NOT CGAL_BUGFIX_VERSION EQUAL 0)
set(CGAL_BUGFIX_VERSION 0)
if(CGAL_VERSION_TOKENS_LEN GREATER 3)
list(GET CGAL_VERSION_TOKENS 3 CGAL_BUILD_VERSION)
endif()
else()
if(CGAL_VERSION_TOKENS_LEN GREATER 4)
list(GET CGAL_VERSION_TOKENS 4 CGAL_BUILD_VERSION)
endif()
endif()
# If CGAL_BUILD_VERSION is not a strictly positive number, error
if(NOT CGAL_BUILD_VERSION GREATER 0)
message(
WARNING
"Error parsing VERSION file: CGAL_BUILD_VERSION is not a number.\n"
"The content of the VERSION file is:\n${CGAL_VERSION}\n"
"CGAL_BUILD_VERSION was set to:\n${CGAL_BUILD_VERSION}")
set(CGAL_BUILD_VERSION 1000)
endif()
endif()
if(NOT CGAL_BUGFIX_VERSION)
set(CGAL_BUGFIX_VERSION 0)
endif()
if(CGAL_BUGFIX_VERSION AND CGAL_BUGFIX_VERSION GREATER 0)
set(CGAL_CREATED_VERSION_NUM
"${CGAL_MAJOR_VERSION}.${CGAL_MINOR_VERSION}.${CGAL_BUGFIX_VERSION}")
else()
set(CGAL_CREATED_VERSION_NUM "${CGAL_MAJOR_VERSION}.${CGAL_MINOR_VERSION}")
endif()
endif()
#--------------------------------------------------------------------------------------------------
#
# -= BASIC SETUP =-
#
#--------------------------------------------------------------------------------------------------
message(STATUS "CGAL_MAJOR_VERSION=${CGAL_MAJOR_VERSION}")
message(STATUS "CGAL_MINOR_VERSION=${CGAL_MINOR_VERSION}")
message(STATUS "CGAL_BUGFIX_VERSION=${CGAL_BUGFIX_VERSION}")
if(CGAL_BUILD_VERSION LESS 1000)
message(STATUS "CGAL_BUILD_VERSION=${CGAL_BUILD_VERSION}")
endif()
set(CGAL_VERSION_DIR CGAL-${CGAL_VERSION})
set(CGAL_MODULES_REL_DIR cmake/modules)
set(CGAL_MODULES_DIR ${CGAL_INSTALLATION_PACKAGE_DIR}/${CGAL_MODULES_REL_DIR})
include(${CGAL_MODULES_DIR}/CGAL_Macros.cmake)
include(${CGAL_MODULES_DIR}/CGAL_enable_end_of_configuration_hook.cmake)
cgal_setup_module_path()
if(RUNNING_CGAL_AUTO_TEST OR CGAL_TEST_SUITE)
message(STATUS "Operating system:")
execute_process(
COMMAND uname -a
TIMEOUT 5
OUTPUT_VARIABLE uname_a
ERROR_VARIABLE uname_a)
message(STATUS "${uname_a}")
cgal_display_compiler_version()
endif()
include(CGAL_Common)
include(CGAL_GeneratorSpecificSettings)
include(CGAL_CheckCXXFileRuns)
include(CGAL_add_test)
mark_as_advanced(CMAKE_BACKWARDS_COMPATIBILITY)
message(
STATUS
"USING CMake version: ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION}"
)
message(STATUS "System: ${CMAKE_SYSTEM_NAME}")
#--------------------------------------------------------------------------------------------------
#
# -= FLAGS =-
#
#--------------------------------------------------------------------------------------------------
if(MSVC)
uniquely_add_flags(CGAL_CXX_FLAGS
"-D_SCL_SECURE_NO_DEPRECATE;-D_SCL_SECURE_NO_WARNINGS")
uniquely_add_flags(CGAL_CXX_FLAGS "/fp:strict")
uniquely_add_flags(CGAL_CXX_FLAGS "/fp:except-")
uniquely_add_flags(CGAL_CXX_FLAGS "/bigobj") # Use /bigobj by default
if(RUNNING_CGAL_AUTO_TEST OR CGAL_TEST_SUITE)
set(CMAKE_CXX_WARNING_LEVEL
2
CACHE STRING "MSVC C++ compiler warning level" FORCE)
mark_as_advanced(CMAKE_CXX_WARNING_LEVEL)
endif()
endif()
if("\"${CMAKE_CXX_COMPILER_ID}\"" MATCHES "SunPro")
message(STATUS "Using SunPro compiler, using STLPort 4.")
uniquely_add_flags(CGAL_CXX_FLAGS
"-features=extensions;-library=stlport4;-D_GNU_SOURCE")
uniquely_add_flags(CGAL_SHARED_LINKER_FLAGS "-library=stlport4")
uniquely_add_flags(CGAL_EXE_LINKER_FLAGS "-library=stlport4")
endif()
if("${CMAKE_CXX_COMPILER}" MATCHES "icl" OR "${CMAKE_CXX_COMPILER}" MATCHES
"icpc")
message(STATUS "Intel compiler is detected.")
set(IntelCompiler_FOUND TRUE)
get_dependency_version(IntelCompiler)
if("${IntelCompiler_VERSION}" LESS "1100")
message(
"Intel Compiler version ${IntelCompiler_VERSION} is not supported by CGAL-${CGAL_MAJOR_VERSION}.${CGAL_MINOR_VERSION}! (too old, must be 11.0 or after)"
)
else()
message(
STATUS "Using Intel Compiler version 11 or later. Adding -fp-model strict"
)
if(WIN32)
uniquely_add_flags(CGAL_CXX_FLAGS "/fp:strict")
else()
uniquely_add_flags(CGAL_CXX_FLAGS "-fp-model strict")
endif()
endif()
endif()
if(CMAKE_COMPILER_IS_GNUCXX)
set(GCC_FOUND TRUE)
get_dependency_version(GCC)
if("${GCC_VERSION}" MATCHES "Not" OR "${GCC_VERSION}" MATCHES "Unknown")
set(GCC_FOUND FALSE)
endif()
if(GCC_FOUND)
if(RUNNING_CGAL_AUTO_TEST OR CGAL_TEST_SUITE)
uniquely_add_flags(CGAL_CXX_FLAGS "-Wall")
# Remove -g from the relevant CMAKE_CXX_FLAGS. This will also
# propagate to the rest of the tests, since we overwrite those
# flags with the ones used to build CGAL.
string(REGEX REPLACE "-g( |$)" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
# We only allow the release types DEBUG and RELEASE, but handle
# all possible values just to be sure.
foreach(release_type DEBUG RELEASE MINSIZEREL RELWITHDEBINFO)
string(REGEX REPLACE "-g( |$)" "" CMAKE_CXX_FLAGS_${release_type}
"${CMAKE_CXX_FLAGS_${release_type}}")
endforeach()
endif()
if("${GCC_VERSION}" MATCHES "^[4-9].")
message(STATUS "Using gcc version 4 or later. Adding -frounding-math")
uniquely_add_flags(CGAL_CXX_FLAGS "-frounding-math")
endif()
if("${CMAKE_SYSTEM_PROCESSOR}" MATCHES "alpha")
message(STATUS "Using gcc on alpha. Adding -mieee -mfp-rounding-mode=d")
uniquely_add_flags(CGAL_CXX_FLAGS "-mieee -mfp-rounding-mode=d")
endif()
endif()
endif()
if(CGAL_TEST_SUITE)
include(display-third-party-libs-versions)
endif()
message("== Generate version files (DONE) ==\n")
#--------------------------------------------------------------------------------------------------
#
# -= External libraries =-
#
#--------------------------------------------------------------------------------------------------
if(CGAL_DEV_MODE OR RUNNING_CGAL_AUTO_TEST OR CGAL_TEST_SUITE)
message("== Set up flags ==")
# Ugly hack to be compatible with current CGAL testsuite process (as of
# Nov. 2017). -- Laurent Rineau
include(CGAL_SetupFlags)
message("== Set up flags (DONE) ==\n")
else()
include(CGAL_display_flags)
endif()
message("== Detect external libraries ==")
# set some to have special prefix
macro(set_special_prefix library prefix)
set(SPECIAL_PREFIXES
"${SPECIAL_PREFIXES}set(CGAL_EXT_LIB_${library}_PREFIX \"${prefix}\")\n")
set(CGAL_EXT_LIB_${library}_PREFIX ${prefix})
endmacro()
set_special_prefix(Qt6 QT)
set_special_prefix(Eigen3 EIGEN3)
set_special_prefix(Coin3D COIN3D)
# some libraries are essential (stl and Boost.Thread are treated in another way)
if($ENV{CGAL_DISABLE_GMP})
set(CGAL_DISABLE_GMP
ON
CACHE INTERNAL "")
endif()
if(CGAL_DISABLE_GMP)
message("Disable the GMP support")
list(LENGTH CGAL_ESSENTIAL_3RD_PARTY_LIBRARIES CGAL_ESSENTIAL_LENGTH)
if(NOT CGAL_ESSENTIAL_LENGTH EQUAL 0)
list(REMOVE_ITEM CGAL_ESSENTIAL_3RD_PARTY_LIBRARIES GMP MPFR)
endif()
unset(CGAL_CONFIGURED_LIBRARIES)
unset(CGAL_CONFIGURED_LIBRARIES CACHE)
unset(GMP_FOUND)
unset(GMP_FOUND CACHE)
unset(GMPXX_FOUND)
unset(GMPXX_FOUND CACHE)
unset(MPFR_FOUND)
unset(MPFR_FOUND CACHE)
unset(WITH_CGAL_Core)
unset(WITH_CGAL_Core CACHE)
unset(CGAL_USE_GMP)
unset(CGAL_USE_GMP CACHE)
# Nasty trick to make sure <gmp.h> is not used when CGAL_DISABLE_GMP is TRUE
file(WRITE "${CGAL_BINARY_DIR}/include/gmp.h"
"#error GMP is disabled by the CMake option CGAL_DISABLE_GMP")
else()
list(APPEND CGAL_ESSENTIAL_3RD_PARTY_LIBRARIES GMP MPFR)
# When CMake is run several times, to avoid duplicates
list(REMOVE_DUPLICATES CGAL_ESSENTIAL_3RD_PARTY_LIBRARIES)
file(REMOVE "${CGAL_BINARY_DIR}/include/gmp.h")
endif()
hide_variable(CGAL_ESSENTIAL_3RD_PARTY_LIBRARIES)
#--------------------------------------------------------------------------------------------------
#
# -= DEPENDENCIES =-
#
#--------------------------------------------------------------------------------------------------
#
# The following variables are in the cache just so subdirectories can set them persistently.
# But they are not intended to persist from run to run as normal cache variables.
# Similar variables are created when a library is detected.
cache_set(CGAL_3RD_PARTY_DEFINITIONS "")
cache_set(CGAL_3RD_PARTY_INCLUDE_DIRS "")
cache_set(CGAL_3RD_PARTY_LIBRARIES "")
cache_set(CGAL_3RD_PARTY_LIBRARIES_DIRS "")
# additional info: some header files in CGAL add additional code if
# certain optional libs are installed, and some examples/tests rely on
# this; e.g. in MPFI/RS in Algebraic_kernel_d. For these cases CGAL
# and the example/test must be configured with MPFI (just one is not sufficient)
message("== Detect external libraries (DONE) ==\n")
#--------------------------------------------------------------------------------------------------
#
# -= Generation of compiler_config.h =-
#
#--------------------------------------------------------------------------------------------------
#--------------------------------------------------------------------------------------------------
#
# -= Installation Setup =-
#
#--------------------------------------------------------------------------------------------------
set(CGAL_INSTALL_INC_DIR
"${CMAKE_INSTALL_INCLUDEDIR}"
CACHE
STRING
"The folder where CGAL header files will be installed, relative to CMAKE_INSTALL_PREFIX"
)
set(CGAL_INSTALL_LIB_DIR
"${CMAKE_INSTALL_LIBDIR}"
CACHE
STRING
"The folder where CGAL libraries will be installed, relative to CMAKE_INSTALL_PREFIX"
)
if(CGAL_WIN32_CMAKE_ON_CYGWIN)
execute_process(COMMAND cygpath -w ${CMAKE_INSTALL_PREFIX}
OUTPUT_STRIP_TRAILING_WHITESPACE
OUTPUT_VARIABLE CMAKE_INSTALL_PREFIX2)
file(TO_CMAKE_PATH ${CMAKE_INSTALL_PREFIX2} CMAKE_INSTALL_PREFIX)
endif()
set(CGAL_INSTALL_BIN_DIR
"${CMAKE_INSTALL_BINDIR}"
CACHE
STRING
"The folder where CGAL user-side scripts will be installed, relative to CMAKE_INSTALL_PREFIX"
)
set(CGAL_INSTALL_CMAKE_DIR
"${CGAL_INSTALL_LIB_DIR}/cmake/CGAL"
CACHE
STRING
"The folder where CGAL CMake modules will be installed, relative to CMAKE_INSTALL_PREFIX"
)
set(CGAL_INSTALL_DOC_DIR
"${CMAKE_INSTALL_DOCDIR}"
CACHE
STRING
"The folder where CGAL documentation and license files will be installed, relative to CMAKE_INSTALL_PREFIX"
)
set(CGAL_INSTALL_MAN_DIR
"${CMAKE_INSTALL_MANDIR}/man1"
CACHE
STRING
"The folder where manual pages for CGAL scripts will be installed, relative to CMAKE_INSTALL_PREFIX"
)
#--------------------------------------------------------------------------------------------------
#
# -= Build =-
#
#--------------------------------------------------------------------------------------------------
message("== Generating build files ==")
set(CGAL_INCLUDE_DIRS ${CGAL_BINARY_DIR}/include)
foreach(package ${CGAL_CONFIGURED_PACKAGES})
if(EXISTS ${package}/include)
set(CGAL_INCLUDE_DIRS ${CGAL_INCLUDE_DIRS} ${package}/include)
endif()
endforeach()
include_directories(${CGAL_INCLUDE_DIRS})
cache_get(CGAL_3RD_PARTY_DEFINITIONS )
cache_get(CGAL_3RD_PARTY_INCLUDE_DIRS )
cache_get(CGAL_3RD_PARTY_LIBRARIES )
cache_get(CGAL_3RD_PARTY_LIBRARIES_DIRS)
install(DIRECTORY ${INCLUDE_CGAL_QT_DIRECTORIES} DESTINATION "${CGAL_INSTALL_INC_DIR}/CGAL/" COMPONENT CGAL_Qt6)
if(CGAL_BRANCH_BUILD)
install(DIRECTORY "${CGAL_GRAPHICSVIEW_PACKAGE_DIR}/demo/resources/" DESTINATION "${CGAL_INSTALL_CMAKE_DIR}/demo/resources" COMPONENT CGAL_Qt6)
install(DIRECTORY "${CGAL_GRAPHICSVIEW_PACKAGE_DIR}/demo/icons/" DESTINATION "${CGAL_INSTALL_CMAKE_DIR}/demo/icons" COMPONENT CGAL_Qt6)
endif()
#
# Variables used when WITH_{demos|examples|tests} are TRUE
#
get_property(CGAL_FOUND GLOBAL PROPERTY CGAL_FOUND)
get_property(CGAL_Core_FOUND GLOBAL PROPERTY CGAL_Core_FOUND)
get_property(CGAL_ImageIO_FOUND GLOBAL PROPERTY CGAL_ImageIO_FOUND)
get_property(CGAL_Qt6_FOUND GLOBAL PROPERTY CGAL_Qt6_FOUND)
#
# Repeat some problems
#
message("== Generating build files (DONE) ==\n")
if(CGAL_BRANCH_BUILD AND CGAL_REPORT_DUPLICATE_FILES)
message(STATUS "Problems: ")
if(CGAL_DUPLICATE_HEADER_FILES)
message(WARNING "WARNING: Duplicate header files")
foreach(hfile ${CGAL_DUPLICATE_HEADER_FILES})
message(STATUS " File '${hfile}' multiply found in ")
foreach(package ${CGAL_CONFIGURED_PACKAGES})
file(GLOB_RECURSE CGAL_PACKAGE_HEADER_FILES FOLLOW_SYMLINKS
${package}/*.h)
list(SORT CGAL_PACKAGE_HEADER_FILES)
foreach(file ${CGAL_PACKAGE_HEADER_FILES})
string(REPLACE "${package}/" "" pure_file ${file})
if("${pure_file}" STREQUAL "${hfile}")
message(STATUS " ${package}")
endif()
endforeach()
endforeach()
endforeach()
endif()
if(CGAL_DUPLICATE_CPP_FILES)
message(WARNING "WARNING: Duplicate cpp files")
foreach(cfile ${CGAL_DUPLICATE_CPP_FILES})
message(STATUS " File '${cfile}' multiply found in ")
foreach(package ${CGAL_CONFIGURED_PACKAGES})
file(GLOB_RECURSE CGAL_PACKAGE_CPP_FILES FOLLOW_SYMLINKS
${package}/*.cpp)
list(SORT CGAL_PACKAGE_CPP_FILES)
foreach(file ${CGAL_PACKAGE_CPP_FILES})
string(REPLACE "${package}/" "" pure_file ${file})
if("${pure_file}" STREQUAL "${cfile}")
message(STATUS " ${package}")
endif()
endforeach()
endforeach()
endforeach()
endif()
endif()
configure_file("${CGAL_MODULES_DIR}/CGALConfig_binary_header_only.cmake.in"
"${CGAL_BINARY_DIR}/CGALConfig.cmake" @ONLY)
configure_file("${CGAL_MODULES_DIR}/CGALConfigVersion_binary_header_only.cmake.in"
"${CGAL_BINARY_DIR}/CGALConfigVersion.cmake" @ONLY)
#--------------------------------------------------------------------------------------------------
#
# -= Installation Commands =-
#
#--------------------------------------------------------------------------------------------------
# DESTINATION option is mandatory; skipping it breaks CPack!
if(CGAL_INSTALL_DOC_DIR)
install(FILES AUTHORS CHANGES.md LICENSE LICENSE.GPL
LICENSE.LGPL DESTINATION ${CGAL_INSTALL_DOC_DIR})
endif()
#install all includes collected in trunk et cetera
foreach(dir ${CGAL_CONFIGURED_PACKAGES})
if(EXISTS ${dir}/include/CGAL)
install(
DIRECTORY ${dir}/include/CGAL
DESTINATION ${CGAL_INSTALL_INC_DIR}
PATTERN ".svn" EXCLUDE
PATTERN "Qt" EXCLUDE)
endif()
endforeach()
if(EXISTS ${CGAL_BINARY_DIR}/include/CGAL)
install(
DIRECTORY ${CGAL_BINARY_DIR}/include/CGAL
DESTINATION ${CGAL_INSTALL_INC_DIR}
PATTERN ".svn" EXCLUDE
PATTERN "Qt" EXCLUDE)
endif()
file(GLOB scripts "scripts/*")
list(SORT scripts)
list(REMOVE_ITEM scripts
${CMAKE_CURRENT_SOURCE_DIR}/scripts/cgal_create_assertions.sh
${CMAKE_CURRENT_SOURCE_DIR}/scripts/cgal_create_cmake_script_with_options)
install(PROGRAMS ${scripts} DESTINATION ${CGAL_INSTALL_BIN_DIR})
install(DIRECTORY ${CGAL_MODULES_REL_DIR}/
DESTINATION ${CGAL_INSTALL_CMAKE_DIR})
if(IS_DIRECTORY auxiliary/gmp/include AND IS_DIRECTORY auxiliary/gmp/lib)
install(DIRECTORY auxiliary/gmp/include/ DESTINATION ${CGAL_INSTALL_INC_DIR})
install(DIRECTORY auxiliary/gmp/lib/ DESTINATION ${CGAL_INSTALL_LIB_DIR})
endif()
if(ZLIB_IN_AUXILIARY)
install(DIRECTORY auxiliary/zlib/include/ DESTINATION ${CGAL_INSTALL_INC_DIR})
install(DIRECTORY auxiliary/zlib/lib/ DESTINATION ${CGAL_INSTALL_LIB_DIR})
endif()
install(FILES
${CMAKE_CURRENT_LIST_DIR}/lib/cmake/CGAL/CGALConfig.cmake
${CMAKE_CURRENT_LIST_DIR}/lib/cmake/CGAL/CGALConfigBuildVersion.cmake
${CMAKE_CURRENT_LIST_DIR}/lib/cmake/CGAL/CGALConfigVersion.cmake
DESTINATION ${CGAL_INSTALL_CMAKE_DIR})
if(NOT CGAL_INSTALL_CMAKE_DIR STREQUAL "${CGAL_INSTALL_LIB_DIR}/cmake/CGAL")
configure_file(${CMAKE_CURRENT_LIST_DIR}/lib/cmake/CGAL/CGALConfig-installation-dirs.cmake.in
${CGAL_BINARY_DIR}/config/CGALConfig-installation-dirs.cmake)
install(FILES
${CGAL_BINARY_DIR}/config/CGALConfig-installation-dirs.cmake
DESTINATION ${CGAL_INSTALL_CMAKE_DIR})
endif()
if(CGAL_INSTALL_MAN_DIR)
install(FILES auxiliary/cgal_create_cmake_script.1
DESTINATION ${CGAL_INSTALL_MAN_DIR})
endif()
#--------------------------------------------------------------------------------------------------
#
# -= Special installation commands to copy FindCGAL to the cmake directory =-
#
#--------------------------------------------------------------------------------------------------
# Installing FindCGAL into cmake itself is implemented as a custom target
# because it requires superuser privileges
if(NOT "${CMAKE_ROOT}" STREQUAL "")
if(EXISTS ${CMAKE_ROOT}/Modules)
add_custom_target(
install_FindCGAL
COMMAND ${CMAKE_COMMAND} -E copy ${CGAL_MODULES_DIR}/FindCGAL.cmake
${CMAKE_ROOT}/Modules)
endif()
endif()
#--------------------------------------------------------------------------------------------------
#
# -= APPLICATIONS =-
#
#--------------------------------------------------------------------------------------------------
if(NOT TARGET ALL_CGAL_TARGETS)
add_custom_target(ALL_CGAL_TARGETS)
endif()
macro(add_programs subdir target ON_OFF)
cache_set(CGAL_EXECUTABLE_TARGETS "")
add_custom_target(${target})
add_dependencies(ALL_CGAL_TARGETS ${target})
option(WITH_${target} "Select ${target}" ${ON_OFF})
if(WITH_${target})
add_subdirectory(${subdir} EXCLUDE_FROM_ALL)
endif()
cache_get(CGAL_EXECUTABLE_TARGETS)
foreach(CGAL_EXECUTABLE_TARGET ${CGAL_EXECUTABLE_TARGETS})
add_dependencies(${target} ${CGAL_EXECUTABLE_TARGET})
endforeach()
endmacro()
# This allows programs to locate CGALConfig.cmake
set(CGAL_DIR ${CGAL_BINARY_DIR})
if(NOT RUNNING_CGAL_AUTO_TEST)
add_programs(examples examples OFF)
add_programs(demo demos OFF)
if(IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/test")
add_programs(test tests OFF)
endif()
endif()
message("== Setting paths ==")
#--------------------------------------------------------------------------------------------------
#
# -= CPack =-
#
#--------------------------------------------------------------------------------------------------
#option( WITH_CPACK "Create package generation rules")
if(WITH_CPACK AND EXISTS "${CMAKE_ROOT}/Modules/CPack.cmake")
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY
"CGAL - Computational Geometry Algorithms Library")
set(CPACK_PACKAGE_VENDOR "CGAL Open Source Project")
set(CPACK_PACKAGE_DESCRIPTION_FILE "${CGAL_INSTALLATION_PACKAGE_DIR}/README")
set(CPACK_RESOURCE_FILE_LICENSE "${CGAL_INSTALLATION_PACKAGE_DIR}/LICENSE")
set(CPACK_PACKAGE_VERSION_MAJOR "${CGAL_MAJOR_VERSION}")
set(CPACK_PACKAGE_VERSION_MINOR "${CGAL_MINOR_VERSION}")
set(CPACK_PACKAGE_VERSION_PATCH "${CGAL_BUGFIX_VERSION}")
set(CPACK_PACKAGE_INSTALL_DIRECTORY
"CGAL ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
set(CPACK_SOURCE_PACKAGE_FILE_NAME "CGAL-${CGAL_VERSION}")
set(CPACK_RESOURCE_FILE_LICENSE "${CGAL_INSTALLATION_PACKAGE_DIR}/LICENSE")
if(NOT DEFINED CPACK_SYSTEM_NAME)
set(CPACK_SYSTEM_NAME ${CMAKE_SYSTEM_NAME}-${CMAKE_SYSTEM_PROCESSOR})
endif()
if(${CPACK_SYSTEM_NAME} MATCHES "Windows")
if(CMAKE_CL_64)
set(CPACK_SYSTEM_NAME win64-${CMAKE_SYSTEM_PROCESSOR})
else()
set(CPACK_SYSTEM_NAME win32-${CMAKE_SYSTEM_PROCESSOR})
endif()
endif()
if(NOT DEFINED CPACK_PACKAGE_FILE_NAME)
set(CPACK_PACKAGE_FILE_NAME
"${CPACK_SOURCE_PACKAGE_FILE_NAME}-${CPACK_SYSTEM_NAME}")
endif()
set(CPACK_PACKAGE_EXECUTABLES "CGAL" "CGAL")
if(WIN32 AND NOT UNIX)
set(CPACK_GENERATOR "NSIS")
# There is a bug in NSI that does not handle full unix paths properly. Make
# sure there is at least one set of four (4) backlasshes.
#set(CPACK_PACKAGE_ICON "${CGAL_INSTALLATION_PACKAGE_DIR}\\\\cgal_install.gif")
#set(CPACK_NSIS_INSTALLED_ICON_NAME "bin\\\\CGAL.exe")
set(CPACK_NSIS_DISPLAY_NAME
"${CPACK_PACKAGE_INSTALL_DIRECTORY} Computational Geometry Algorithms Library"
)
set(CPACK_NSIS_HELP_LINK "http:\\\\\\\\www.cgal.org")
set(CPACK_NSIS_URL_INFO_ABOUT "http:\\\\\\\\www.cgal.org")
set(CPACK_NSIS_CONTACT "[email protected]")
set(CPACK_NSIS_MODIfY_PATH ON)
else()
set(CPACK_STRIP_FILES "")
set(CPACK_SOURCE_STRIP_FILES "")
endif()
include(CPack)
endif()
if(CGAL_BRANCH_BUILD)
option(
CGAL_ENABLE_CHECK_HEADERS
"Enable the special targets \"check_pkg_headers\", \"packages_dependencies\", and \"check_pkg_<package>_headers\" and \"pkg_<package>_deps\" for each package"
FALSE)
unset(CGAL_COMPUTE_DEPENDENCIES CACHE) # remove that variable, no longer used
if(CGAL_ENABLE_CHECK_HEADERS)
option(CGAL_COPY_DEPENDENCIES
"Copy package dependencies in source directories.
Note that this option will modify the source directory!" FALSE)
message("== Setting header checking ==")
find_package(GMP REQUIRED)
find_package(Doxygen REQUIRED)
find_package(Eigen3 REQUIRED)
find_package(Qt6 COMPONENTS Core Widgets OpenGL Gui REQUIRED)
find_package(VTK COMPONENTS ImagingGeneral IOImage NO_MODULE)
if(VTK_FOUND)
get_target_property(VTK_INCLUDE_DIRS VTK::IOImage INTERFACE_INCLUDE_DIRECTORIES)
endif()
find_package(IPE)
find_package(RS3)
find_package(LEDA)
find_package(OpenMesh)
find_package(OpenCV QUIET)
set(compile_options
"\
${CMAKE_CXX_FLAGS} -DCGAL_EIGEN3_ENABLED -DCGAL_PROFILE \
${Qt6Widgets_DEFINITIONS} ${Qt6OpenGL_DEFINITIONS} ${Qt6Gui_DEFINITIONS} \
${Qt6OpenGL_EXECUTABLE_COMPILE_FLAGS} -fPIC \
${Qt6Gui_EXECUTABLE_COMPILE_FLAGS} \
${CGAL_3RD_PARTY_DEFINITIONS} ${CGAL_Qt6_3RD_PARTY_DEFINITIONS} \
${CGAL_DEFINITIONS}" -std=c++17)
message("COMPILATION OPTIONS ARE : ${compile_options}")
if(NOT RS_FOUND AND NOT RS3_FOUND)
set(compile_options
"${compile_options} \
-DCGAL_ALGEBRAIC_KERNEL_RS_GMPZ_D_1=1 \
-DCGAL_ALGEBRAIC_KERNEL_RS_GMPQ_D_1=1")
message(STATUS "Skip RS headers \"CGAL/Algebraic_kernel_rs_gmpq_d_1.h\" \
and \"CGAL/Algebraic_kernel_rs_gmpz_d_1.h\" because RS_FOUND is false.")
else()
set(compile_options
"${compile_options} \
-DCGAL_USE_MPFI=1 \
-DCGAL_USE_RS=1")
endif()
if(NOT OpenMesh_FOUND)
set(compile_options
"${compile_options} \
-DCGAL_BOOST_GRAPH_GRAPH_TRAITS_POLYMESH_ARRAYKERNELT_H \
-DCGAL_BOOST_GRAPH_GRAPH_TRAITS_TRIMESH_ARRAYKERNELT_H \
-DCGAL_PROPERTIES_POLYMESH_ARRAYKERNELT_H \
-DCGAL_PROPERTIES_TRIMESH_ARRAYKERNELT_H")
message(
STATUS
"Skip headers \
\"CGAL/boost/graph/graph_traits_PolyMesh_ArrayKernelT.h\", \
\"CGAL/boost/graph/graph_traits_TriMesh_ArrayKernelT.h\", \
\"CGAL/boost/graph/properties_PolyMesh_ArrayKernelT.h\", and \
\"CGAL/boost/graph/properties_TriMesh_ArrayKernelT.h\", \
because OpenMesh_FOUND is false.")
endif()
if(NOT OpenCV_FOUND)
set(compile_options "${compile_options} \
-DCGAL_CLASSIFICATION_OPENCV_RANDOM_FOREST_CLASSIFIER_H")
message(STATUS "Skip header \
\"CGAL/Classification/OpenCV_random_forest_classifier.h\" \
because OpenCV_FOUND is false")
endif()
if(LEDA_FOUND)
set(compile_options "${compile_options} -DCGAL_USE_LEDA")
endif()
if(NOT IPE_FOUND)
set(compile_options "${compile_options} -DCGAL_IPELET_BASE_H=1")