build.gradle

buildscript {
    repositories {
        maven { url = 'https://files.minecraftforge.net/maven' }
        maven { url = 'https://repo.spongepowered.org/repository/maven-public/' }
        mavenCentral()
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
        classpath 'org.spongepowered:mixingradle:0.7.+'
    }
}

plugins {
    id 'com.matthewprenger.cursegradle' version '1.4.0'
}

apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'eclipse'
apply plugin: 'maven-publish'
apply plugin: 'org.spongepowered.mixin'

version = "${MC_VERSION}-${VERSION}"
group = "com.ewyboy.${MODID}"
archivesBaseName = MODNAME

java.toolchain.languageVersion = JavaLanguageVersion.of(17)

minecraft {
    apply plugin: 'idea'
    mappings channel: MCP_CHANNEL, version: MCP_MAPPINGS

    runs {
        client {
            workingDirectory project.file('run')
            property 'forge.logging.console.level', 'debug'
            mods {
                oretweaker {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run')
            mods {
                oretweaker {
                    source sourceSets.main
                }
            }
        }

        data {
            workingDirectory project.file('run')
            mods {
                oretweaker {
                    source sourceSets.main
                }
            }
        }
    }
}

repositories {
    maven {
        url "https://www.cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
    mavenCentral()
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

dependencies {
    minecraft "net.minecraftforge:forge:${MC_VERSION}-${FORGE_VERSION}"
    annotationProcessor 'org.spongepowered:mixin:0.8.5:processor'
    implementation fg.deobf("curse.maven:worldstripper-250603:${WORLD_STRIPPER}")
}

mixin {
    add sourceSets.main, 'mixins.oretweaker.refmap.json'
    config 'mixins.oretweaker.json'
}

jar {
    manifest {
        attributes([
                "Specification-Title"     : MODNAME,
                "Specification-Vendor"    : AUTHOR,
                "Specification-Version"   : "1",
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : VERSION,
                "Implementation-Vendor"   : AUTHOR,
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }
}

jar.finalizedBy('reobfJar')

curseforge {
    if (project.hasProperty('CF_API_KEY')){
        apiKey = project.getProperty('CF_API_KEY')
    }
    project {
        id = "${PROJECT_ID}"
        changelogType = 'markdown'
        changelog = file('CHANGELOG.md')
        releaseType = "${RELEASE_TYPE}"
        addGameVersion 'Forge'
        addGameVersion 'Java 17'
        addGameVersion '1.18.2'
        mainArtifact(jar) {
            displayName = "${MODNAME}-${MC_VERSION}-${VERSION}.jar"
        }
    }
}