3rdParty_sb_widget_helper.gradle

apply plugin: "de.undercouch.download"

repositories {
    mavenLocal()
    maven { url "https://raw.githubusercontent.com/snobotsim/maven_repo/master/release" }
}

configurations {
    custom_widgets
}

dependencies {
    // Helper for getting the coordinate gui from maven into the shuffleboard area
    custom_widgets 'org.snobot.coordinate_gui:CoordinateGuiShuffleboard2022:2022.1.0'
}

task deleteOldWidgets(type: Delete) {
    delete fileTree("${System.getProperty("user.home")}/Shuffleboard/plugins") {
        include '**/*.jar'
    }
    followSymlinks = true
}

task downloadMechanicalAdvantageAlerts(type: Download) {
    src 'https://github.com/Mechanical-Advantage/NetworkAlerts/releases/download/v1.0.0/NetworkAlerts.jar'
    dest "${System.getProperty("user.home")}/Shuffleboard/plugins"
    overwrite true
}

task install_shuffleboard_plugins(type: Copy, dependsOn: [deleteOldWidgets, downloadMechanicalAdvantageAlerts]) {
    group = "Girls of Steel"
    description = "Copies any Girls of Steel widgets from maven into the shuffleboard area"
    from configurations.custom_widgets
    into("${System.getProperty("user.home")}/Shuffleboard/plugins")
}