From 42a5e01057f3f79c904181378061c755339e184a Mon Sep 17 00:00:00 2001
From: Pavel Sobolev <contact@paveloom.dev>
Date: Sat, 26 Oct 2024 16:13:19 +0300
Subject: [PATCH] warp-plus: init at 1.2.4

---
 pkgs/by-name/wa/warp-plus/package.nix | 52 +++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix       |  4 +++
 2 files changed, 56 insertions(+)
 create mode 100644 pkgs/by-name/wa/warp-plus/package.nix

diff --git a/pkgs/by-name/wa/warp-plus/package.nix b/pkgs/by-name/wa/warp-plus/package.nix
new file mode 100644
index 0000000000000..ec80044aae4f4
--- /dev/null
+++ b/pkgs/by-name/wa/warp-plus/package.nix
@@ -0,0 +1,52 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+
+  nix-update-script,
+  testers,
+  warp-plus,
+}:
+
+buildGoModule rec {
+  pname = "warp-plus";
+  version = "1.2.4";
+
+  src = fetchFromGitHub {
+    owner = "bepass-org";
+    repo = "warp-plus";
+    rev = "v${version}";
+    hash = "sha256-fFyYch14JqXSmnplPJ8c3epOxromZmEJAdcuSgkKbcM=";
+  };
+
+  vendorHash = "sha256-/rBZqrX9xZT8yOZwynkOOQyPl0govNmvsEqWVxsuvB4=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${version}"
+  ];
+
+  checkFlags =
+    let
+      # Skip tests that require network access
+      skippedTests = [
+        "TestConcurrencySafety"
+        "TestTwoDevicePing"
+      ];
+    in
+    [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+    tests.version = testers.testVersion { package = warp-plus; };
+  };
+
+  meta = {
+    description = "Warp + Psiphon, an anti censorship utility for Iran";
+    homepage = "https://github.com/bepass-org/warp-plus";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ paveloom ];
+    mainProgram = "warp-plus";
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index dc47d2ca4b0f0..8d9ca1930806b 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -33284,6 +33284,10 @@ with pkgs;
     inherit (darwin.apple_sdk.frameworks) Security Foundation;
   };
 
+  warp-plus = callPackage ../by-name/wa/warp-plus/package.nix {
+    buildGoModule = buildGo122Module;
+  };
+
   warpd = callPackage ../applications/misc/warpd { };
 
   watershot = callPackage ../applications/misc/watershot { };