build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

plugins {
    id 'java'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'maven-publish'
    id 'distribution'
}

group 'com.octopus.teamcity'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
        vendor = JvmVendorSpec.ADOPTOPENJDK
    }
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'io.spring.dependency-management'

    // Provided configuration allows compile-time only dependencies to NOT
    // be included in the final distributions.
    configurations {
        provided
    }

    sourceSets {
        all {
            compileClasspath += configurations.provided
        }
    }

    task sourcesJar(type: Jar, dependsOn: classes) {
        archiveClassifier.set("sources")
        from sourceSets.main.allSource
    }

    version = rootProject.version
    sourceCompatibility = 17
    targetCompatibility = 17

    repositories {
        mavenCentral()
        maven { url "https://download.jetbrains.com/teamcity-repository" }
        maven { url "https://packages.jetbrains.team/maven/p/teamcity-rest-client/teamcity-rest-client" }
        maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
    }
}

apply plugin: "distribution"

distZip {
    archiveFileName = "Octopus.TeamCity.OpenTelemetry." + rootProject.version + ".zip"
}

distributions {
    all {
        contents {
            from file("teamcity-plugin.xml"), {
                filter ReplaceTokens, tokens: [version: rootProject.version]
            }
            into('server/') {
                from tasks.findByPath(":server:installDist")
            }
            into '/'
        }
    }
}