-
Notifications
You must be signed in to change notification settings - Fork 1
/
compil.mac
4746 lines (4737 loc) · 186 KB
/
compil.mac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
00100 TITLE COMPIL 22G(605) CCL CONTROL CUSP
00200 SUBTTL OWNER HISTORY
00300 ; WEIHER/CLEMENTS/RCC/PMH/NGP/DMN/HPW/JNG
00400 ; /SMM/JMT/WCL/BCM/GAT/RCB/MEM 9-SEP-87
00500 SUBTTL PROGRAM TO COMPILE LOAD EXECUTE AND DEBUG USER PROGRAMS
00600
00700
00800
00900 ;COPYRIGHT (c) DIGITAL EQUIPMENT CORPORATION 1968,1978,1983,1984,1985,1986,1987.
01000 ;ALL RIGHTS RESERVED.
01100 ;
01200 ;
01300 ;THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND COPIED
01400 ;ONLY IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE AND WITH THE
01500 ;INCLUSION OF THE ABOVE COPYRIGHT NOTICE. THIS SOFTWARE OR ANY OTHER
01600 ;COPIES THEREOF MAY NOT BE PROVIDED OR OTHERWISE MADE AVAILABLE TO ANY
01700 ;OTHER PERSON. NO TITLE TO AND OWNERSHIP OF THE SOFTWARE IS HEREBY
01800 ;TRANSFERRED.
01900 ;
02000 ;THE INFORMATION IN THIS SOFTWARE IS SUBJECT TO CHANGE WITHOUT NOTICE
02100 ;AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
02200 ;CORPORATION.
02300 ;
02400 ;DIGITAL ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY OF ITS
02500 ;SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DIGITAL.
02600
02700
02800 SEARCH UUOSYM
02900
03000
03100 VCOMPIL==22
03150 VLOCAL==1 ;ESSEX UPDATE LEVEL
03200 VUPDATE==7 ;DEC UPDATE LEVEL
03300 VEDIT==VLOCAL*1000+605 ;EDIT LEVEL
03400 VCUSTOM==2 ;NON-DEC UPDATE LEVEL
03500
03510 ;ESSEX UNIVERSITY REVISION HISTORY
03520 ;22C RE-DONE TO RESOLVE CONFLICTS / INCLUDE EDIT HISTORY
03530 ;1000 BCPL COMPILER
03600 ;THE ORIGINAL VERSION OF
03700 ;THIS PROGRAM WAS WRITTEN AT THE STANFORD UNIVERSITY
03800 ;ARTIFICIAL INTELLIGENCE LABORATORY BY WILLIAM F. WEIHER.
03900 ;MR. WEIHER'S COOPERATION, AND THAT OF THE A-I LABORATORY,
04000 ;ARE GRATEFULLY ACKNOWLEDGED.
04100 ;
04200 ;CONVERTED TO MACRO SOURCE LANGUAGE FROM FAIL ON
04300 ;1 NOVEMBER 68 BY R CLEMENTS
04400
04500
04600 INTERN VCOMPILE,.JBVER ;FOR LOADER MAP AND LIBRARY
04700
04800 LOC <.JBVER==137>
04900 <VCUSTOM>B2+<VCOMPIL>B11+<VUPDATE>B17+VEDIT
05000 RELOC 0
05100
05200 IFNDEF RUNSW,<RUNSW==1> ;NON-ZERO TO USE THE RUN UUO
05300 IFNDEF PURESW,<PURESW==1> ;NON-ZERO FOR A SHARED VERSION OF COMPIL
05400
05500 IFNDEF STANSW,<STANSW=0> ;NON-ZERO TO INCLUDE STANFORD FEATURES
05600 IFN STANSW,<FAIL==1>
05700 IFNDEF LSTRSW,<LSTRSW=0> ;NON-ZERO TO USE "LISTER" INSTEAD OF PIP
05800 ;FOR TYPE AND LIST COMMANDS
05900 IFNDEF FASTFS,<FASTFS=0> ;FASTEST FILE STRUCTURE
06000 ;IF ZERO COMPIL WILL FIND IT AT RUN TIME
06100 IFNDEF SIMULA,<SIMULA==1> ;[452] ACCEPT SIMULA AS A COMPILER
06200 IFNDEF PASCAL,<PASCAL==1> ;[463] ACCEPT PASCAL AS A COMPILER
06250 IFNDEF BCPL,<BCPL==1> ;[1000] ACCEPT BCPL COMPILER
06300 IFNDEF SNOBOL,<SNOBOL==1> ;ACCEPT SNOBOL AS A COMPILER
06400 IFNDEF MACY11,<MACY11==1> ;[203] ACCEPT MACY11 (PDP-11) ASSEMBLER
06500 IFNDEF BLISS,<BLISS==1> ;ACCEPT BLISS COMPILER
06600 IFNDEF FAIL,<FAIL==1> ;[202] FAIL ASSEMBLER
06700 IFNDEF SAIL,<SAIL==1> ;SAIL COMPILER
06800 IFNDEF PAL10,<PAL10==0> ;PAL10 ASSEMBLER (NO CCL INTERFACE YET)
06900
07000 IFNDEF DEBSW,<DEBSW==0> ;DEBUGGING AIDS IF NON-ZERO
07100 IFNDEF SFDSW,<SFDSW==1> ;ENABLED FOR SUB-FILE DIRECTORY
07200 IFN SFDSW,<IFNDEF SFDLEN,<SFDLEN==5>> ;LENGTH ALLOWED
07300 IFDEF SFDLEN,<IFLE SFDLEN,<SFDSW==0>> ;NO SFD'S IF LENGTH.LE.0
07400 IFNDEF SFDLEN,<SFDLEN==0> ;[601] MAKE SURE SYMBOL ALWAYS DEFINED
07500 IFNDEF FORTRAN,<FORTRAN==1> ;NON-ZERO IF BOTH F40 AND FORTRAN-10 ALLOWED
07600 IFNDEF DFORTRAN,<DFORTRAN==1> ;DEFAULT VALUE 0=F40, 1=FORTRAN-10
07700 IFNDEF DCOBOL,<DCOBOL==1> ;[324] DEFAULT VALUE 0=COBOL-68, 1=COBOL-74
07800 ;[451] MAKE COBOL-74 DEFAULT COBOL COMPILER
07900 IFNDEF EDITOR,<EDITOR=='DTECO '>;EITHER LINED OR EDITS [442] DEF IS DTECO
00100 SUBTTL REVISION HISTORY
00200
00300 ;START OF VERSION 22A
00400 ;144 PASS FORTRAN-10 SWITCHES IN () CORRECTLY
00500 ;145 (10405) CLEAR .JBSA & JOB NAME SO START, RUN, GET FAIL
00600 ;146 MAKE ERROR MESSAGES CONFORM TO STANDARD CMLxxx
00700 ;147 (9096) MAKE TECO COMMAND ACCEPT SWITCHES IN ()
00800 ;150 TEST FOR LINK/LOADER CONFLICT AND WARN USER
00900 ;151 (9949) FIX TO RECOMPILE LIBRARY FILE WITH NULL EXT
01000 ;152 FIX TO RECOMPILE FILE IF TEMP /COM BUT PERMANENT /REL
01100 ;153 MAKE LINK-10 & FORTRAN-10 THE DEFAULT
01200 ;154 (11535) FIX COPY WITH TAPEID AND SWITCH BEFORE =
01300 ;155 (10817) FIX TYPO IN SFDPPN ROUTINE
01400 ;156 ADD DATE75 HACK
01500 ;157 READ SVC FILE IF ONLY SWITCHES HAVE BEEN SEEN (NO FILE NAME)
01600 ;160 FIX ILL MEM REF FROM ZERO COMMAND WITH NO ARGS
01700 ;161 (11209) ?COMMAND ERROR: .Y WITH DEL X.,*.Y; DON'T SCAN OFF COMMA AT GETN1+5
01800 ;162 FIX PC OUT OF BOUNDS
01900 ;163 REVERSE ORDER OF LOOKUPS SO FORTRAN IS FIRST
02000 ;164 LOAD CORRECT REL FILE IN LOAD FOO.BIN=FOO[PPN] WHERE BOTH FILES ON [PPN]
02100 ;165 GET STACK CORRECT ON DEBUG /LINK A+<B,C>
02200 ;166 (11466) CORRECT TECO COMMAND STRING IF [PPN] PRESENT
02300 ;167 (11643) ACCEPT "_" FOR "=" IN RENAME AND COPY
02400 ;170 TYPE RUN UUO ERROR CODES IN OCTAL
02500 ;171 MAKE CODE MORE READABLE
02600 ;172 FIX TYPO AT NOCOM3 + 3
02700 ;173 (11377) PASS ()'D SWITCHES TO COMPILERS IN ()'S (EXCEPT F10)
02800 ;174 (10945) LOADER NEEDS /N OR /L ON EACH FILE
02900 ;175 (11831) DO NOT TEST FOR .REL ON /COMP
03000 ;176 (11620) FIX ADDRESS CHECK ON EX DSKC:A,B (A.F4)
03100 ;177 FIX EDIT 173
03200 ;200 EXTEND EDIT 153
03300 ;201 EDIT 161 KILLED <progname> . / <switch>
03400 ; REDO EDIT 161 AND ALLOW [P,PN] IN <progname>.[P,PN]
03500 ; AS A SIDE EFFECT
03600 ;202 TURN FAIL ON
03700 ;203 CHANGE MACX11 TO MACY11 AND TURN MACY11 ON
03800
03900 ;START OF VERSION 22B
04000 ;204 (12705) IMPLEMENT NEW ERROR MESSAGE IF NO PREVIOUS COMMAND
04100 ;205 (12994) GIVE ERROR MESSAGE IF NO COMMAND TO RESCAN
04200 ;206 (12705) EXTEND EDIT #145 TO ALL POSSIBLE "EXIT"S
04300 ;207 (13072) ALLOW COMPILATION OF FILE WITH NULL EXTENSION
04400 ;210 (12259) FIX SO THAT TECO COMMAND CAN BE TERMINATED WITH ALTMODE
04500 ;211 (13801) FIX BUG IN #205 WHICH MAKES DEBUGGING HARD
04600 ;212 (13036) PUT OUTPUT EXTENSION IN A TABLE
04700 ;213 GIVE EDR ERROR ON MTA OPERATION WITH NO DEVICE SPECIFIED
04800 ;214 (12998) OUTPUT /C RATHER THAN /T ON TYPE COMMAND
04900 ;215 (12993) DELETE CODE TO RUN RANDOM CUSPS, ITS NEVER USED
05000 ;216 (13000) ALLOW MAKE AND TECO WITH NO PREVIOUS COMMAND RUN TECO
05100 ;217 TURN SAIL ON AND ADD SDDT FOR FAIL AND SAIL
05200 ;220 fix /debug switch for link-10 to contain the process name
05300 ;221 ADD SUPPORT FOR FORDDT, /DEBUG, /FORDDT
05400 ;222 (11911) ADD ERROR MESSAGE IF USER TRIES TO USE F40 AND F10 IN SAME COMMAND
05500 ;223 (12374) REMOVE UNNECESSARY CORE UUO
05600 ;224 (12162) FIX BUG IN MAKE [1,3] WHICH CAUSES COMPIL TO GROW WITHOUT LIMIT
05700 ;225 (12992) TRY NULL EXTENSION AFTER CMD EXTENSION
05800 ;226 (11977) GIVE BETTER MESSAGE IF @DEV DOES NOT EXIST
05900 ;227 (12051) FIX VARIOUS COPY BUGS
06000 ;230 (13351) FIX ILL MEM REF IF /MAP SPECIFIED AND NOT LOADING
06100 ;231 (13881) GIVE ERROR IF PROTECTION CODE GREATER THAN 3 CHARACTERS
06200 ;232 (12269) BACKUP CHAR COUNT AS WELL AS BYTE PTR IN SCANS
06300 ;233 (12273) USE "=" RATHER THAN "-" WHERE EVER POSSIBLE FOR .TMP FILES
06400 ;234 (11937) IMPLEMENT /SAVE SWITCH TO PASS COMMAND TO LINK-10
06500 ;235 MAKE /FOR AND /MAC UNIQUE
06600 ;236 (13963) FIX EDIT #174 TO PUT OUT /L OR /N ONLY IF NEEDED
06700
06800 ;START OF VERSION 22C
06900
07000 ;237 (14041) THE COMMAND "PROT DSKA:UFD[,]<765>" WORKED DUE
07100 ; TO A PIP BUG. IMPLEMENT UFD'S CORRECTLY. (JNG)
07200 ;240 (14125) ON A TECO, COMPILE, LOAD SEQUENCE, COMPIL OFTEN
07300 ; RECOMPILES AT THE LOAD. DIAGNOSIS: CREATION DATE IS ACCURATE
07400 ; ONLY TO THE NEAREST MINUTE. FIX: DO EXTENDED LOOKUPS FOR
07500 ; .RBTIM (1/3 SEC.) IF DEVICE IS A DISK. (JNG)
07600 ;241 (14082) FIX MEMORY MANAGEMENT PROBLEM WITH REL FILE I/O BUFFERS
07700 ; OVERWRITING TMPCOR BUFFERS. (JNG)
07800 ;242 (14087) DELAY DECIDING FORMAT OF FOROTS/FORSE SWITCH TO ALLOW
07900 ; "COMP/FOROTS/LINK" TO WORK. (JNG)
08000 ;243 (14732) ALLOW A DEVICE TO BE SPECIFIED FOR TMP FILES. THIS
08100 ; WAS BROKEN BY EDIT 226. (JNG)
08200 ;244 (14663) USE USER'S DEVICE FOR REL FILE IF HE GAVE ONE.
08300 ;245 (14409) ADD SOME SYNTAX CHECKING TO THE PROTECT COMMAND.
08400 ;246 (14678) IGNORE FILES IN USER'S LIBRARY IN PREFERENCE TO
08500 ; THOSE IN HIS DEFAULT PATH.
08600 ;247 DON'T TRY TO COMPILE REL FILES WITH NO ACCOMPANYING SOURCES.
08700 ; THIS WAS BROKEN BY EDIT 240.
08800 ;250 TRY LIBRARY IF USER GAVE AN EXTENSION AND FILE IS NOT IN THE
08900 ; DEFAULT PATH. THIS WENT DOWN WITH EDIT 246.
09000 ;251 IMPLEMENT DLIST SWITCH TO SPECIFY LIST FILE SPECIFICALLY
09100 ; ON DISK, LIST WILL NOW SPECIFY TO INIT DEVICE LPT: WHETHER
09200 ; SPOOLED OR UNSPOOLED
09300 ; AREAS AFFECTED: STABLE MACRO DEFINITION, ATABLE MACRO DEFINITION
09400 ; DOCOM2
09500 ; LABELS ADDED: SETDSK,SETLPT
09600 ;252 (14995) ALLOW SLASH FOR MULTIPLE CHARACTER SWITCHES TO ALGOL
09700 ; AREAS AFFECTED: PROCS1
09800 ;253 COMPLETE EDIT 243
09900 ; AREAS AFFECTED: NEST
10000 ;254 MAKE DEVICE SPECIFICATIONS "STICKY"
10100 ; AREAS AFFECTED: GETDEV,NODEV
10200 ; LABELS ADDED: SVDEVV
10300 ;255 (15503) FIX MANTIS FEATURE SO THAT WHEN MORE THAN ONE
10400 ; PROGRAM IS COMPILED, ALL PROGRAMS GET THE /D SWITCH SET.
10500 ; NOTE THAT MANTIS IS UNSUPPORTED. AREA AFFECTED - ONSET
10600 ;256 (15575) MAKE /SAVE AND /SSAVE PRODUCE THE CORRECT
10700 ; COMMAND FILE TO LINK.
10800 ; AREAS AFFECTED - SSAVE & NOCOMP & LODR1
10900 ;257 (15711) MAKE LINK LOAD LOCAL SYMBOLS FOR /LMAP SWITCH
11000 ; AREAS AFFECTED: SETMPL
11100 ;260 (16101,16201) BANDAGE COMPIL AFTER MAULING BY EDIT 254
11200 ; AREAS AFFECTED: GETDEV, NOTCPY
11300 ;261 (16120)MAKE COMPIL RESPECT ALL DOCUMENTED BREAK CHARACTERS
11400 ; AREAS AFFECTED: CTBL
11500 ;262 (16412)EDIT 241 CAN CAUSE COMPIL TO GROW BY 1K NEEDLESSLY
11600 ; AREAS AFFECTED: RPGRET
11700 ;263 (16558)INVALID LOGIC IS USED FOR CONVERTING UFD PROTECTION.
11800 ; IT CAN STOP TOO EARLY.
11900 ; AREAS AFFECTED: UFDSET
12000 ;264 (16648)COPY A.=A1,A2 DOESN'T WORK LIKE COPY A=A1,A2
12100 ; AREAS AFFECTED: NXTNM2,NOTCPY
12200 ; LABELS ADDED: NXTNOX
12300 ;265 (16774)EDIT 212 HAD ERROR - JFFO WON'T WORK PROPERLY
12400 ; IF AN UNRECOGNIZED PROCESSOR IS SPECIFIED BY EXTENSION
12500 ; AREAS AFFECTED: REREL0
12600 ;266 (16808) COMPIL LOSES ACTUAL REASON FOR LOOKUP ERROR
12700 ; AREAS AFFECTED: NOFIL, NOTYT2, LOSE1
12800 ;267 (16937)"STICKY" DEVICE NAMES ARE STILL TOO STICKY WITH EDIT 244
12900 ; AREAS AFFECTED: SETONM
13000 ;270 (17022) MAKE ".PROT <777>[,].UFD" WORK, & CLEAN UP DEFAULTING.
13100 ; AREAS: DOPROT
13200 ;271 (17329) ALLOW TRAILING ASTERISK WILDCARDS IN PIP COMMANDS.
13300 ; AREAS: SCAN
13400 ;272 (18957) ALLOW THREE AND ONLY THREE #'S IN RENAMES
13500 ; PROTECTION SPECIFICATION.
13600 ; AREAS: NXTNM0
13700 ;273 (18542) REMOVE EDIT #216, TECO,MAKE, ETC. SHOULD
13800 ; GIVE "NO PREVIOUS COMMAND" ERROR AS DOES LOAD , ETC.
13900 ; AREAS: NOFIL
14000 ;274 (18807) A PPN OF LEFT SIDE OF AN "=" IN A COMPILE-CLASS
14100 ; COMMAND CAN BE IGNORED !
14200 ; AREAS: DOCOMP, DOCOM3, ELOD3, ENTC2
14300 ;275 (17540) PPN NOT PASSED TO LINK TMP FILE CORRECTLY ON
14400 ; "+" CONSTRUCTIONS.
14500 ; AREAS AFFECTED: LODR2
14600 ;276 IF ENTER ON TMP FILE FAILS, TRY GENERIC DEVICE DSK
14700 ; AREAS AFFECTED: NOFIT, TMPDS0
14800 ;277 SETZ SHOULD BE A SETZM WHICH CAN CAUSE A RUN
14900 ; UUO FAILURE BECAUSE PPN WORD IS -1. COULD CAUSE
15000 ; OTHER UNPREDICTABLE RESULTS SINCE AC 0 IS CLEARED. ?
15100 ; AREA AFFECTED: RUNIT
15200 ;300 (19716) BLANK LINES AT THE BEGGINING OF A COMMAND FILE
15300 ; CAN CAUSE UNWARRANTED COMMAND ERRORS.
15400 ; AREAS AFFECTED: SYNERP, SCNAGN
15500 ;301 EDIT #300 FIXED AN AGE OLD BUG WHICH WAS PARTIALLY
15600 ; FIXED BY A TEMPORAY PATCH AT LOCATION POPFIL.
15700 ; WITH EDIT #300 AND THIS PATCH IN, AN ILL MEM REF
15800 ; WILL OCCUR WHEN ANY PIP COMMAND IS TYPED WITH NO
15900 ; ARGUMENT, THEREFORE REMOVE THIS PATCH !
16000 ; AREA AFFECTED: POPFIL
16100 ;302 IN ANSWER TO SPR# 17024, AN EDIT #272 WAS MADE
16200 ; AND UNFORTUNATLY WAS LOST. THIS EDIT REPLACES
16300 ; THAT EDIT AND ONCE AGAIN FIXES A STICKY DEVICE/PPN
16400 ; PROBLEM. DEVICES AND PPN'S AS SWITCH ARGUMENTS
16500 ; SHOULD NOT STICK.
16600 ;303 IN ANSWER TO SPR# 17989, ANOTHER EDIT #272 WAS
16700 ; GENERATED AND ALSO UNFORTUNATELY LOST. THIS
16800 ; EDIT REPLACES THAT ONE AND MAKES THE DEFAULT
16900 ; DEBUGGING AIDE FOR FORTRAN TO BE FORDDT WITH
17000 ; REGULAR DDT ALSO LOADED.
17100 ;304 AS A SIDE AFFECT OF EDIT #301, LABEL DEV:/ABC/
17200 ; WAS BROKEN. REMOVE EXTRA CALL TO SCAN GENERATED
17300 ; BY EDIT #154.
17400 ; AREA AFFECTED: IDENT3
17500 ;305 EDIT #300 IS INCOMPLETE AND CAUSED MANY SIDE AFFECTS.
17600 ; EDIT #301 ATTEMPTED TO FIX ONLY ONE OF THESE EFFECTS
17700 ; AND DID NOT FIX THE FULL SCOPE OF RELATED PROBLEMS.
17800 ; THIS EDIT COMPLETES THE FIX EDIT #300 ATTEMPTED,
17900 ; SUPERCEDES EDIT #301 (PUT TEMP. PATCH BACK),
18000 ; AND ELIMINATES THE SUBTLE SIDE AFFECTS
18100 ;306 IF NO DEVICE IS SPECIFIED FOR A REWIND OR UNLOAD
18200 ; COMMAND, THE ERROR MESSAGE SHOULD INDICATE
18300 ; "? EXPLICITE DEVICE REQUIRED" RATHER THAN
18400 ; "? COMMAND ERROR"
18500 ; AREA AFFECTED: NOMTPD
18600 ;307 (QAR#484)SPACES AFTER A DEVICE SPECIFICATION ARE
18700 ; IGNORED AND DO NOT TERMINATE THE FILE SPECIFICATION.
18800 ; THEY SHOULD !
18900 ; AREA AFFECTED:GETDEV
19000
19100 ;START OF VERSION 22D
19200
19300 ;310 (SPR 10-21464)PASSES INVALID TMP FILE TO LINK IF
19400 ; A PREVIOUS COMMAND ALSO CONTAINED A MAP OR LMAP
19500 ; SWITCH AREAS AFFECTED: SETMAP,SETMPL
19600
19700 ;311 (SPR 10-21882) SKIP MTA: NUM FILES DOESN'T WORK
19800 ; AREA AFFECTED: TAPESP
19900
20000 ;312 (SPR 10-22043) WRONG AND INVALID DEBUG AID SWITCH BEING
20100 ; PASSED TO LINK FOR FORTRAN. IF F40 USE DDT AND IF
20200 ; FORTRAN-10 USE FORDDT. AREAS AFFECTED: PROCESS MACRO,
20300 ; GETDD1, FOR
20400
20500 ;313 (SPR 10-21981) IF SFDSW=0 THEN GOTSTK UNDEFINED.
20600 ; MOVED LABEL OUTSIDE OF CONDITIONAL. AREA AFFECTED:GOTSTK
20700
20800 ;314 (SPR 10-22084) COBOL PROGRAMS CANNOT BE LISTED TO LPT:
20900 ; WITH /LIST. BUG INTRODUCED WITH EDIT 251. AREA
21000 ; AFFECTED: DOCOM2+5
21100
21200 ;315 (SPR 10-22658) STOP TRYING TO FIND FILES IN USER'S AREA
21300 ; IF EXPLICIT DEVICE OR PPN IS GIVEN. ONLY LOOK ON USER'S
21400 ; AREA FOR .REL FILES IF SOURCE FILE IS FOUND ON THE SPECIFIED
21500 ; AREA. AREA AFFECTED: OKREL
21600
21700 ;316 (SPR 10-22369) CORRECT RECOMPILATION LOGIC WHERE
21800 ; STRUCTURE NAME IS SPECIFIED. CORRECTS EDIT 240.
21900 ; AREAS AFFECTED: OKLOOK, ELOOK, ALTDAT
22000
22100 ;317 (SPR 10-22181) PREVENT UNNECESSARY RECOMPILE WHICH OCCURS
22200 ; IF A SOURCE FILE IS MOVED.
22300 ; AREAS AFFECTED: ONSET,REREL2,EREL,DNLOK1,SETDT
22400
22500 ;320 CLEAN UP CODE AND COMMENTS
22600
22700 ;321 PROVIDE PROPER OUTPUT IF LISTING SWITCHES FOR A PROCESSOR
22800 ; ARE SPECIFIED WITHOUT A COMPIL LISTING SWITCH.
22900 ; AREAS AFFECTED: DOCOM2
23000
23100 ;322 (SPR 10-24292) DON'T PASS PPN OF SOURCE TO LINK IF
23200 ; RECOMPILE IS NECESSARY AND /SEARCH OR /LIBRARY IS GIVEN
23300 ; AREA AFFECTED: LODR2
23400
23500 ;323 (SPR 10-24597) WHEN SCANNING TAPE OPTIONS (...), CHECK
23600 ; FOR VALID BREAK CHARACTER. IF FOUND BEFORE ")" THEN ERROR.
23700 ; AREAS AFFECTED: COPYSW
23800
23900 ;324 REMOVE MANTIS CODE (NEED TO REUSE THE FLAG BITS)
24000 ; ADD SUPPORT FOR COBOL-74
24100 ; MAKE /OPT PASS /O TO COBOL
24200
24300
24400 ;START OF VERSION 22(E)
24500 ;424 SAVE 100 EDITS FOR DEVELOPMENT
24600 ;425 SPR # 10-26362 WCL 10-0CT-78
24700 ; FIX CHARACTER COUNTING WHEN FILLING BLOCK; HAS BEEN PUTTING NULL
24800 ; AS FINAL CHARACTER
24900 ; AREAS AFFECTED: TMPOUT
25000 ;426 (SPR 10-25452) COMPIL HANGS ON COMMAND SPECIFYING
25100 ; A DEVICE WHEN ASSEMBLED WITH SFDLEN=1
25200 ; AREA AFFECT: NODEV
25300 ;427 SPR # 10-26000 WKV 11-JAN-79
25400 ; KEEP COMPIL FROM LEAVING CREF TEMP FILE ON DSK AFTER TMPCOR
25500 ; OPENS UP. AREA AFFECTED: POPFIL
25600 ;430 NO SPR # WCL 05-MAR-79
25700 ; REMOVE CORE REQUIREMENT IN RUN UUO FOR COPY/RENAME TO ALLOW
25800 ; DEBUGGING
25900 ; AREA AFFECTED: DOCOPY
26000 ;431 SPR # 27558 WCL 05-MAR-79
26100 ; IGNORE EXTRA VERBIAGE IN COPY SWITCHES; STOP SCAN AFTER ONE CHARACTER
26200 ; (WAS INTERPRETING FOLLOWING CHARACTERS AS FILE NAME)
26300 ; AREA AFFECTED: NXTNM0
26400 ;432 SPR # 26360 + 27526
26500 ; SETNAM UUO CAUSES CLEARING OF JB.LSY; BATCON CHECKS THIS TO
26600 ; SEE IF IT SHOULD SEARCH FOR %ERR OR %CERR; SINCE IT'S CLEAR,
26700 ; BATCON INCORRECTLY SEARCHES FOR %ERR; FIX: REMOVE SETNAM
26800 ; AREA AFFECTED: DOEND
26900 ;433 SPR #29039 TARL 22-MAR-80
27000 ; FIX EDIT 322 - REMEMBER WHEN WE HAVE DECIDED THAT THIS IS A REL FILE
27100 ; AREA AFFECTED : LBCOMP+13.4
27200 ;434 SPR #29593 RKB 23-MAY-80
27300 ; FIX COMMAND SCANNER SO IT WILL ACCEPT EXTRANEOUS SPACES
27400 ; AREA AFFECTED : SCNS2+2
27500 ;435 SPR #29887 RKB 5-AUG-80
27600 ; GET RID OF BIZARRE EXTRA CHARACTER SEEN AFTER SOME ERROR MESSAGES
27700 ; AREA AFFECTED : ERRCOM
27800 ;436 NO SPR RKB 5-AUG-80
27900 ; CLEAN UP SOME ERROR MESSAGES AT ERRCOM
28000 ;437 SPR #29807 BCM 22-JUL-80
28100 ; FIX PROTECT COMMAND LINE PARSER FOR DOUBLE EXTENSION
28200 ; AREA AFFECTED: PROT1+16
28300 ;440 SPR #29975 BCM 16-SEP-80
28400 ; PASS LINK "COBOL" AS THE COBOL-74 DEBUGGING AID
28500 ;441 NO SPR BCM 19-SEP-80
28600 ; EXTENSIVE EDITS TO FEATURE TEST MOST OF OLD CODE
28700 ; ALSO MAKE USEFUL MODS
28800 ;442 NO SPR TARL 11-DEC-80
28900 ; MAKE THE EDIT COMMAND RETAIN THE DEVICE NAME - THIS WAY IT CAN
29000 ; RUN DTECO INSTEAD OF LINED.
29100 ;443 NO SPR BCM 19-FEB-81
29200 ; FIX PROCESSOR vs. SWITCH PROBLEM INTRODUCED BY EDIT 441
29300 ;444 10-30513 BCM 24-Mar-81
29400 ; MAKE /SAVE AND /SSAVE WORK RIGHT
29500 ;445 10-05955 BCM 28-Apr-81
29600 ; FIX /NOCOMP SWITCH FOR "DEBUG A.MAC/NOCOMP"
29700 ;446 10-30567 BCM 16-Jun-81
29800 ; INCREASE BUFFER SIZE FOR NUMBER OF LINK SWITCHES
29900 ;447 QAR 10-05958 BCM 8-Aug-81
30000 ; implement global processor switches
30100 ;450 NO SPR BCM 11-Aug-81
30200 ; Fix an assumption that processors can still parse parenthesis.
30300 ;451 QAR 10-05959 BCM 12-Aug-81
30400 ; make COBOL-74 the default COBOL compiler
30500 ;452 QAR 10-05957 BCM 25-Aug-81
30600 ; add code to support SIMULA compiler
30700 ;453 SPR 10-31944 BCM 5-Jan-82
30800 ; Fix edit 444 to not overlay the extension as the output extension.
30900 ;
31000 ;454 SPR #32066 BCM 2-JAN-82
31100 ; Reinsert the code at IDENT which was removed incorrectly
31200 ; by a zealous edit 441.
31300 ;455 SPR #30256 BCM 15-Mar-82
31400 ; We output an "S" as the first chacracter in the TMPCOR file
31500 ; that is passed to LINED or TECO. Since we removed the LINED
31600 ; support we will gradually remove this from crock from COMPIL.
31700 ; Change the "S" to "<space>" since TECO skips it anyway.
31800 ;456 SPR #31279 BCM 15-Mar-82
31900 ; Replace code removed by edit 430. Makes PIP run faster
32000 ; on copies.
32100 ;457 SPR #31693 BCM 16-Mar-82
32200 ; Allow compiler selection switches (/C74,/C68,/F10,/F40) to
32300 ; imply compiler type. A long overdue correction.
32400 ;460 SPR #32659 BCM 28-Sep-82
32500 ; Edit 454 incomplete. Add LABEL to command table.
32600 ;461 SPR #32416 BCM 22-Apr-82
32700 ; Increase the core argument to optimal size.
32800 ;462 SPR #31449 BCM 29-Sep-82
32900 ; Always LOOKUP the REL file if the processor is unknown. This
33000 ; avoids debugging with DDT, when the link block type is Fortran.
33100 ; Made new routine SETPTH which should always be called to set
33200 ; up path for DOLOOK. Changed all LOOKUP's to call DOLOOK.
33300 ;463 NO SPR BCM 19-Apr-83
33400 ; Add the PASCAL compiler to compiler list and add new compiler
33500 ; attribute flag word.
33600 ;
33700 ;START OF VERSION 22(F)
33800 ;
33900 ;564 SPR 10-32178/32177 GAT 4-JAN-84
34000 ; Fix ADDRESS CHECKS/ILL MEM REFS which were not thoroughly
34100 ; eliminated by edits 176/241.
34200 ;
34300 ;565 10-32625 GAT 19-JAN-84
34400 ; GIVE APPROPRIATE ERROR MESSAGE IF SOURCE FILES ARE NOT FOUND OR
34500 ; .REL FILES ARE SPECIFIED IN THE "+" CONSTRUCTION.
34600 ;566 10-31613 GAT 14-FEB-84
34700 ; DELETE TMPCOR FILE IF WRITING .TMP FILE ONTO DISK.
34800 ;567 SPR 10-32007 GAT 10-FEB-84
34900 ; CORRECT PARSING OF COMMAND FILES THAT START WITH A COMMENT LINE(S).
35000 ;570 10-34129 GAT 22-MAR-84
35100 ; ALLOW "MINUS SIGN" IN PROCESSOR SWITCHES NEEDED FOR COBOL-74.
35200 ;571 33631 GAT 21-MAR-84
35300 ; USE ALGDDT AS DEFAULT DEBUGGER INSTEAD OF DDT FOR ALGOL
35400 ;572 10-32034 GAT 8-MAY-84
35500 ; GIVE ERROR IF TRYING TO DEFAULT SFD(S).
35600 ;573 SPR 10-31549 GAT 14-MAY-84
35700 ; DON'T PASS EXPLICIT SOURCE DEVICE TO LINK IF A /LIB FILE NEEDS
35800 ; TO BE RECOMPILED (INTO OUR DIRECTORY).
35900 ;574 10-34735 GAT 9-AUG-84
36000 ; MAKE GFLOAT AND F66 SWITCHES KNOWN TO COMPIL.
36100 ;575 10-34994 GAT 10-DEC-84
36200 ; INCREASE SIZE OF SWITCH BLOCK (SWBK) TO ALLOW LONGER
36300 ; PROCESSOR SWITCH STRINGS. THIS NOW ALLOWS UP TO 150
36400 ; CHARS TO BE PASSED INSTEAD OF JUST 25 CHARS.
36500 ;576 None LEO 9-AUG-85
36600 ; CHANGE COPYRIGHT STATEMENTS
36700 ;577 QAR 868774 DRB 3-FEB-86
36800 ; NEST IS DESTROYING T1 WHEN IT SHOULDN'T. PUSH IT SOONER AND POP IT
36900 ; LATER.
37000 ;
37100 ;START OF VERSION 22(G)
37200 ;
37300 ;600 NO SPR RCB 6-FEB-86
37400 ; EXTEND 442 TO ALLOW THE PATHOLOGICAL DEVICE EDITOR: TO BE WHAT
37500 ; THE CREATE AND EDIT COMMANDS WILL RUN. IF EDITOR: IS NOT DEFINED,
37600 ; THEN DEFAULT TO THE EDITOR SYMBOL OF 442 (RUN FROM SYS:).
37700 ;
37800 ;601 10-35493 RCB 22-JUL-86
37900 ; ALLOW [-] AS A PATH SPEC.
38000 ;
38100 ;602 10-35500 MEM 16-JAN-87
38200 ; ONLY PUT OUT EXT AND PPN IF /REL WAS SPECIFIED
38300 ;
38400 ;603 10-35688 9-SEP-87
38500 ; EXPLICIT "DSK" ON A FILESPEC DOESN'T OVERRIDE STICKY DEVICE NAME
38600 ; FROM A PREVIOUS FILESPEC.
38700 ;
38800 ;604 10-35708 9-SEP-87
38900 ; EDIT 567 WENT TOO FAR. DON'T SPECIAL CASE COMMA SEPARATORS WHEN
39000 ; TERMINATING INDIRECT COMMAND FILESPECS UNLESS THEY IMMEDIATELY
39100 ; FOLLOW A TERMINATOR.
39200 ;
39300 ;605 10-35989 9-SEP-87
39400 ; EDIT 602 WAS TOO RESTRICTIVE. TRIED TO SUPPRESS THE OUTPUT OF
39500 ; EXTENSIONS, BUT OMITTED THE PPN AS WELL.
39600 ;
39700 ;;;END OF REVISION HISTORY
00100 SUBTTL ASSIGNMENTS
00200
00300 ;ACS
00400 P=17 ;PUSHDOWN POINTER
00500 C=16 ;CHARACTERS RETURNED HERE
00600 CS=15 ;CHARACTER STATUS BITS HERE
00700 SVPT=14 ;POINTER TO CURRENT FILE IN LIST OF FILES (AOBJN)
00800 SWPT=13 ;BYTE POINTER INTO SWITCH STORAGE AREA
00900 SWCNT=12 ;NUMBER OF BYTES LEFT FOR SWITCH STORAGE
01000 FL3=11 ;FLAG REGISTER (LEFT HALF IS GLOBAL SWITCHES)
01100 FL2=10 ;FLAG REGISTER (LEFT HALF INDICATES PROCESSOR)
01200 ;RIGHT HALF IS DEFAULT LOCAL PROCESSOR (SET BY /F ETC)
01300 IOP=7 ;PDL FOR INPUT NESTING
01400 IOPNT=6 ;POINTER TO CURRENT INPUT FILE
01500
01600 T5=5 ;USED IN OUTPUT ROUTINES ONLY (DMN)
01700 T4=4 ;TEMPORARY ACCUMS
01800 T3=3
01900 T2=2
02000 T1=1
02100 FL=0 ;FLAG REGISTER (LEFT HALF LOCAL SWITCHES)
02200 ;(RIGHT HALF MISC BITS)
02300
02400 IFN PURESW,<IFE RUNSW,<
02500 PRINTX ;ASSEMBLY SWITCHES CONFLICT>>
02600
02700 SALL ;SUPPRESS ALL MACROS AND REPEATS
02800
02900 MLON
03000
03100 IFE DEBSW,<OPDEF GOTO [JRST]>
03200 IFN DEBSW,<OPDEF GOTO [PUSHJ P,] ;LEAVE TRACES IN STACK>
03300
03400 IFE SFDSW,<PDL==100 ;LENGTH OF PDL>
03500 IFN SFDSW,<PDL==200 ;NESTING TAKES UP MORE SPACE>
03600 SWBK==30 ;[575] NUMBER OF WORDS FOR SWITCHES TO PROCESSOR
03700 LODSCT==^D200 ;[446] # OF CHRS IN LINK SWITCHES PER FILE ALLOWED
03800 DEBSIZ==5 ;[221] NO. OF WORDS OF FORDDT SWITCHES
03900 .TYSPL==(1B13) ;DEVTYP BIT FOR SPOOLING
04000 .RBSIZ==5 ;[240] LAST WORD USED IN 4-WORD LOOKUP
04100 .RBTIM==35 ;[240] INTERNAL CREATION DATE OF DSK FILE
04200 DV.DSK==(1B1) ;[240] DEVICE IS A DSK
04300 FRSCOD==1 ;[242] MEANS USE FORSE
04400 FRTCOD==2 ;[242] MEANS USE FOROTS
00100 ;[463] FLAG WORD
00200 SCANCH==000001 ;[463] USE SCAN CHAINING ARG CONVENTIONS
00300
00400 ;FLAGS (RH OF FL)
00500
00600 PROCS==1 ;PROCESSOR SWITCHES SEEN
00700 DOLOD==2 ;WE WANT TO DO LOADING
00800 PCM1==4 ;FIRST COMMA SEEN IN PROCESSOR SWITCHES
00900 PCM2==10 ;SECOND COMMA SEEN
01000 IDF==20 ;SCAN SAW AN IDENTIFIER
01100 LODOUT==40 ;SOME OUTPUT HAS BEEN DONE TO LINK [441]
01200 PERF==200 ;PERMANENT TYPE FLAGS
01300 CMDSN==1000 ;THE COMMAND SHOULD BE WRITTEN AS SVC OR EDS
01400 INCRF==2000 ;WE ARE FINISHING CREF OUTPUT
01500 INPRNT==4000 ;WE ARE PRINTING A CHARACTER STRING IN ERROR MSG
01600 PIPF==10000 ;DOING SOMETHING FOR PIP
01700 EDITF==20000 ;IN EDIT OR CREATE
01800 CREATF==40000 ;CREATE
01900 NODAT==PCM1 ;FILE FROM OTHER THAN DSK
02000 NOLOOK==PCM2 ;LOOKUP FAILED
02100 TECOF==100000 ;WE WANT TECO
02200 RECALF==200000 ;WE ARE READING A COMMAND SAVE FILE
02300 F.STKY==400000 ;[302] DEVICE'S AND PPN'S SHOULD NOT STICK
02400
02500
02600 ;TABLE OF NEW DEVICES
02700 DEFINE DEVICE<
02800 X NEW,NEW
02900 X OLD,OLD
03000 X SYS,SYS
03100 X SELF,DSK
03200 >
03300 ;FLAGS (SWITCH TYPE)
03400 LISTSW==1 ;DO LISTING
03500 CRSW==2 ;DO A CREF
03600 LIBSW==4 ;DO A LIBRARY SEARCH OF THIS FILE
03700 DEBUGSW==10 ;[221] COMPIL SPECIAL CODE FOR FORDDT
03800 COMPLS==20 ;COMPILE REGARDLESS OF DATES
03900 NOCMPL==2000 ;[445] NOCOMPLE REGARDLESS OF DATES
04000 NOBINSW==40 ;DON'T DO A REL FILE
04100 C68SW==100 ;[324] COMPIL COBOL WITH COBOL-68
04200 C74SW==200 ;[324] COMPIL COBOL WITH COBOL-74
04300 F40SW==400 ;COMPILE FORTRAN WITH F40
04400 F10SW==1000 ;COMPILE FORTRAN WITH FORTRAN-10
04500 F66SW==2000 ;[574] F66 CODE
04600 GFLSW==4000 ;[574] GFLOATING CODE
04700 OPTSW==10000 ;OPTIMIZED CODE
04800 NOPTSW==20000 ;NON-OPTIMIZED CODE
04900 DEVSW==(1B0) ;INITIAL VALUE
05000 DEVSWS==0 ;SUM OF DEVSW
05100 DEFINE X(A,B)<
05200 A'SW==DEVSW
05300 DEVSWS==DEVSWS!DEVSW
05400 DEVSW==DEVSW_-1>
05500 DEVICE
05600
00100 REPEAT 0,< THE MACRO PROCESS DEFINES DETAILS ABOUT THE VARIOUS
00200 PROCESSORS WHICH COMPILE IS EXPECTED TO HANDLE BY CALLING
00300 THE MACRO X WHICH IS REDEFINED TO PRODUCE THE INFORMATION REQUIRED.
00400 THE ARGUMENTS ARE :-
00500 A SWITCH NAME
00600 B EXTENSION
00700 C PROCESSOR NAME
00800 D <OPTIONAL>EXTENSION OF NEXT PROCESSOR IF MUST BE PROCESSED MORE THAN ONCE
00900 E EXTENSION PRODUCED
01000 F DEBUGGING AID USED ON DEBUG COMMAND (DDT IF NULL)
01100 G SEPARATOR, EITHER "=" OR "_"
01200 H COMPILER ATTRIBUTE FLAGS, USED FOR SCAN VS. BANG CHAINING
01300 >
01400
01500 DEFINE PROCESS<
01600 IFN DFORTRAN,<X FORTRAN,FOR,FORTRAN,,,FORDDT,=,SCANCH>
01700 IFE DFORTRAN,<X FORTRAN,FOR,F40,,,,=>
01800 IFN PASCAL,<X PASCAL,PAS,PASCAL,,,PASDDT,=,SCANCH>;[462] PASCAL USES SCAN ARGS
01900 X MACRO,MAC,MACRO,,,,=
02000 IFN SIMULA,<X SIMULA,SIM,SIMULA,,,SIMDDT,=> ;[452] SW,EXT,PROC,,,DEBUG
02100 IFE DCOBOL,<X COBOL,CBL,COBOL,,,COBDDT,=>
02200 IFN DCOBOL,<X COBOL,CBL,CBL74,,,COBDDT,=>
02300 X ALGOL,ALG,ALGOL,,,ALGDDT,=
02310 IFN BCPL,<X BCPL,BCP,BCPL,,,,=> ;[1000]
02400 IFN SNOBOL,<X SNOBOL,SNO,SNOBOL,,,,_>
02500 IFN MACY11,<X MACY11,P11,MACY11,,OBJ,,_>
02600 IFN BLISS,<X BLISS,BLI,BLIS10,,,,=>
02700 IFN FAIL,<X FAIL,FAI,FAIL,,,SDDT,_>
02800 IFN SAIL,<X SAIL,SAI,SAIL,,,SDDT,_>
02900 IFN PAL10,<X PAL10,PAL,PAL10,,,,=>
03000 >
03100
03200 DEFINE XPROCESS<
03300 X LINK,LNK,LINK ;[441] FT LINK
03400 X CREF,CRF,CREF
03500 X PIP,PIP,PIP
03600 X EDT,EDT
03700 IFN LSTRSW,<X LIST,LST,LISTER>
03800 >
03900
00100 ;PROCESSOR FLAGS IN FL2
00200 RELSW==1 ;DO A LOAD ONLY ON THIS FILE (PROCESSOR IS LOADER)
00300 ALPROC==RELSW ;OR OF BITS FOR ALL THE PROCESSORS
00400 NPROCS==0 ;NUMBER OF PROCESSORS
00500 PROCBIT==400000 ;USE TO ASSIGN PROCESSOR FLAGS
00600 MXPROC==^D17 ;MAXIMUM PROCESSORS ALLOWED (REAL COMPILERS)
00700 XTPROC==0 ;EXTRA "PROCESSORS (PIP,LOADER, ETC)
00800 SPRC==0 ;BITS FOR THOSE PROCESSORS WHICH OUTPUT TO ANOTHER
00900
01000 DEFINE X (A,B,C,D,E,F,G,H)<
01100 CHN'B==NPROCS ;INDEX TO OUTPUT ROUTINE
01200 B'SW==PROCBIT ;PROCESSOR BIT
01300 IFDIF <D><>,<SPRC==SPRC!PROCBIT>
01400 ALPROC==ALPROC!PROCBIT
01500 NPROCS==NPROCS+1
01600 PROCBIT==PROCBIT_-1>
01700
01800 PROCESS
01900 IFG NPROCS-MXPROC,<PRINTX TOO MANY PROCESSORS DEFINED>
02000
02100
02200 DEFINE X (A,B,C,D,E,F,G,H)<
02300 CHN'B==MXPROC+XTPROC
02400 XTPROC==XTPROC+1>
02500 XPROCESS
02600
02700 IFE SIMULA,<SIMSW==0> ;[452] FOR LATER TESTS
02800 IFE BLISS,<BLISW==0> ;MAKES TESTS EASIER AND NEATER
02900 UNKSW==0 ;[462] AN UNKNOWN PROC TYPE
02950 IFE BCPL,<BCPSW==0> ;[1000] MAKES TESTS EASIER AND NEATER
03000 LOOK==0 ;CHANNEL FOR DOING LOOKUPS FOR INFORMATION
03100 NFILE==^D40 ;NUMBER OF FILES PERMITTED IN A + CONSTRUCTION
03200 IFNDEF NESTDP,<NESTDP==17> ;MAXIMUM NESTING DEPTH TO PERMIT
03300 IFLE NESTDP,<NESTDP==17>
03400 IFG NESTDP-17,<NESTDP==17>
03500
03600 ;[324] LINK BLOCK TYPE 6 COMPILER CODES
03700
03800 L%F40==1 ;F40
03900 L%C68==2 ;COBOL-68
04000 L%F10==10 ;FORTRAN
04100 L%C74==16 ;COBOL-74
04200
00100 SUBTTL MACROS
00200
00300 EXTERN .JBFF,.JBREL,.JBERR,.JBSA
00400
00500 %LOREL:! ;RELOCATABLE BEGINNING OF LOW SEGMENT
00600
00700 IFN PURESW,< TWOSEGMENTS
00800 .ZZ:
00900 RELOC 400000>
01000
01100 COPYRIGHT (c) DIGITAL EQUIPMENT CORPORATION 1968,1986. ALL RIGHTS RESERVED.
01200 \;END COPYRIGHT MACRO
01300
01400 OPDEF STRING [TTCALL 3,]
01500 OPDEF PJRST [JRST] ;POPJ RETURN
01600
01700 DEFINE SKIP (J)<JRST .+1+'J>
01800
01900 ;MACROS FOR THE DATA STORAGE IN PURE AND IMPURE VERSIONS
02000
02100 DEFINE WORDS(A)<
02200 IRP A,<
02300 U(A,1)>>
02400
02500 IFE PURESW,<
02600 DEFINE U(A,B)<
02700 A: BLOCK B>>
02800
02900 IFN PURESW,<
03000 DEFINE U(A,B)<
03100 RELOC
03200 A: BLOCK B
03300 RELOC>>
00100 SUBTTL COMMAND AND SWITCH TABLES
00200
00300 DEFINE CTABLE<
00400 COMAND COMPILE,<TRZ FL,DOLOD>
00500 COMAND LOAD,JFCL
00600 COMAND DEBUG,<PUSHJ P,DEBUG>
00700 COMAND EXECUTE,<PUSHJ P,XCTR>
00800 COMAND EDIT,<TRO FL,EDITF>
00900 COMAND CREATE,<TRO FL,EDITF!CREATF>
01000 COMAND LIST,<JRST LISTR>
01100 COMAND CREF,<JRST CREFIT>
01200 COMAND DELETE,<JRST DODEL>
01300 COMAND TECO,<TRO FL,EDITF!TECOF>
01400 COMAND MAKE,<TRO FL,EDITF!TECOF!CREATF>
01500 COMAND RENAME,<JRST DOREN>
01600 COMAND TYPE,<JRST TYPR>
01700 COMAND COPY,<JRST DOCOPY>
01800 COMAND PRESERVE,<JRST DOPRES>
01900 COMAND PROTECT,<JRST DOPROT>
02000 COMAND REWIND,<JRST DOREW>
02100 COMAND UNLOAD,<JRST DOUNLD>
02200 COMAND ZERO,<JRST DOZERO>
02300 COMAND ZER,<JRST DOZERO>
02400 COMAND SKIP,<JRST DOSKIP>
02500 COMAND BACKSPACE,<JRST DOBKSP>
02600 COMAND EOF,<JRST DOEOF>
02700 COMAND FUDGE,<JRST FUDGIT>
02800 COMAND CTEST,<JRST TESTIT>
02900 COMAND LABEL,<JRST IDENT> ;[460] REINSERT COMMAND
03000 >
00100 DEFINE STABLE<
00200 SWITCH CREF,<XWD CRSW!LISTSW,0>
00300 SWITCH C,<XWD CRSW!LISTSW,0>
00400 SWITCH SEARCH,<LIBSW,,0>
00500 SWITCH LIBRARY,<LIBSW,,0>
00600 SWITCH NOLIST,LISTSW
00700 SWITCH NOSEARCH,LIBSW
00800 SWITCH N,LISTSW
00900 SWITCH COMPILE,<XWD COMPLS,0>
01000 SWITCH NOCOMPILE,<NOCMPL,,0> ;;[445] MAKE A SEPERATE BIT FOR NOCOMP
01100 SWITCH NOBINARY,<NOBINSW,,0>
01200 SWITCH BINARY,NOBINSW
01300 SWITCH NODEBUG,DEBUGSW
01400 SWITCH C68,<C68SW,,C74SW>
01500 SWITCH C74,<C74SW,,C68SW>
01600 SWITCH F40,<F40SW,,F10SW>
01700 SWITCH F10,<F10SW,,F40SW>
01800 SWITCH F66,<F66SW,,0> ;[574]
01900 SWITCH GFLOATING,<GFLSW,,0> ;[574]
02000 SWITCH OPTIMIZE,<OPTSW,,NOPTSW>
02100 SWITCH NOPTIMIZE,<NOPTSW,,OPTSW>
02200 SWITCH NEW,<NEWSW,,DEVSWS>
02300 SWITCH OLD,<OLDSW,,DEVSWS>
02400 SWITCH SYS,<SYSSW,,DEVSWS>
02500 SWITCH SELF,<SELFSW,,DEVSWS>
02600 >
02700 DEFINE PTABLE<
02800 SWITCH REL,<XWD RELSW,ALPROC>
02900 SWITCH M,<XWD MACSW,ALPROC>
03000 SWITCH F,<XWD FORSW,ALPROC>
03100 SWITCH MA,<XWD MACSW,ALPROC>
03200 SWITCH FO,<XWD FORSW,ALPROC>
03300 SWITCH MAC,<XWD MACSW,ALPROC>
03400 SWITCH FOR,<XWD FORSW,ALPROC>
03500 PROCESS
03600 >
03700 DEFINE ATABLE<
03800 SWITCH MAP,<0,,SETMAP>
03900 SWITCH LMAP,<0,,SETMPL>
04000 SWITCH FUDGE,<0,,SETFUD>
04100 SWITCH DDT,<0,,SETDDT>
04200 SWITCH FOROTS,<0,,FOROTS>
04300 SWITCH FORSE,<0,,FORSE>
04400 SWITCH LINK,<0,,LINKIT>
04500 SWITCH DEBUG,<0,,SETDEB>
04600 SWITCH FORDDT,<0,,FORDDT>
04700 SWITCH SAVE,<0,,SAVE>
04800 SWITCH SSAVE,<0,,SSAVE>
04900 SWITCH LIST,<0,,SETLPT> ;[251]
05000 SWITCH L,<0,,SETLPT> ;[251]
05100 SWITCH DLIST,<0,,SETDSK> ;[251]
05200 SWITCH DL,<0,,SETDSK> ;[251]
05300 >
00100 SUBTTL RUN UUO
00200
00300 IFE RUNSW,<
00400 NUNPNT==6
00500 NUNTOP==7
00600 EXTERN .JBDDT,.JBSA,.JBS41,.JBCOR
00700
00800 OFFSET==INHERE-74
00900
01000 NUNCOM: IOWD 0,INHERE
01100 0
01200 NUNGO2: CALLI 15,11 ;GET PROPER CORE SIZE
01300 JRST NOCOR ;LOSE
01400 IN 1,NUNCOM ;GET IT
01500 JRST NUNGO3 ;OK
01600 NUNERR: CALLI NUNPNT,3 ;WE LOSE, PRINT ERROR
01700 CALLI 12
01800 NUNERM: ASCIZ #?LINKAGE ERROR - I/O#
01900 NUNGO3: SKIPE 12,OFFSET+.JBCOR ;GET JOBCOR
02000 CAMG 12,.JBREL ;AND SEE IF WE SHOULD EXPAND
02100 JRST NUNGO4 ;NO, START THE BLT
02200 MOVEI NUNPNT,NUNCER
02300 CALLI 12,11 ;YES, DO IT
02400 JRST NUNERR ;LOSE
02500 MOVE 12,OFFSET+.JBS41 ;RESET 41
02600 MOVEM 12,41
02700 JRST NUNGO4 ;WIN
02800 NUNCER: ASCIZ /?CORE NEEDED/
02900 INHERE:
03000
03100 NUNAC: PHASE 0 ;THE CODE TO GO IN THE ACS
03200 NUNGO4: MOVE 12,OFFSET+.JBDDT;SET JOBDDT
03300 CALLI 12,2 ;SET JOBDDT
03400 NUNBLT: BLT NUNTOP,0
03500 CALLI ;RESET THE WORLD
03600 AOS 1,.JBSA ;GET STARTING ADDRESS
03700 JRST (1)
03800 NUNERM
03900 XWD INHERE+1,75 ;THE BLT WORD
04000 DEPHASE
04100 %RNBLK==NAME-1
04200 >
00100 CREFIT: SKIPA T1,[SIXBIT /CREF/]
00200 FUDGIT: MOVSI T1,'PIP'
00300 NUNDO: MOVSI T2,1 ;START ADDR PLUS ONE
00400 RUNIT: MOVEM T1,%RNBLK+1 ;[216] SET FILE NAME SINCE WE HAVE IT IN T1
00500 RESET ;RESET THINGS
00600 SETZM %RNBLK+4 ;[277] USE DEFAULT PPN
00700 MOVE T1,RUNCOR ;GET CORE ARG (USUALLY 0)
00800 MOVEM T1,%RNBLK+5 ;BUT NOT FOR COPY (^D10)
00900 IFN RUNSW,<
01000 SKIPN T1,PCDEV ;USE SPECIAL DEVICE IF SET
01100 MOVSI T1,'SYS' ;GET SYS DEVICE
01200 MOVEM T1,%RNBLK ;SET IT IN LOW SEG RUN BLOCK
01300 SETZM %RNBLK+2 ;CLEAR EXTENSION - LET MONITOR CHOOSE
01400 SETZM %RNBLK+3 ;THIS ALSO (DATE, TIME, ETC)
01500 HRRI T2,%RNBLK ;GET LOWSEG ADDRESS OF RUN BLOCK
01600 MOVSI T1,1 ;SET TO REMOVE HIGH SEGMENT
01700 HRRI T1,%LENTH-1 ;REDUCE LOWSEG FOR SIMILAR REASON
01800 MOVE T3,[%RUN1,,%LOREL] ;GET READY TO PHASE CODE INTO LOWSEG
01900 BLT T3,%RNBLK-1 ;PERFORM THE TRANSFER
02000 MOVEM T2,%RUNT2 ;INCASE OF FAILURE
02100 JRST %LOREL ;DO UUO'S IN LOWSEG SINCE HIGH SEG GONE
02200
02300 %RUN1:
02400 PHASE %LOREL
02500 CORE T1, ;ALREADY SET UP IN HIGH SEG
02600 JFCL ;DON'T CARE IF IT FAILS
02700 %RUN: RUN T2, ;T2 ALREADY SET UP ABOVE
02800 HRRZ T1,T2 ;GET ERROR CODE
02900 CAIN T1,10 ;NOT ENOUGH CORE ERROR?
03000 SKIPN %RNBLK+5 ;ONLY IF TOO MUCH ASKED FOR
03100 JRST %RUN2 ;NO, U LOSE
03200 SETZM %RNBLK+5 ;USE WHAT WE GET
03300 SKIPA T2,%RUNT2 ;RESET T2
03400 %RUNT2: Z ;SET FROM HIGH SEG
03500 JRST %RUN ;TRY AGAIN
03600
03700 %RUN2: OUTSTR RUNER1 ;WARN USER OF FAILURE
03800 IDIVI T1,10 ;[170] MAY BE 2 DIGITS
03900 JUMPE T1,LRUN3 ;NO, ONLY ONE [441] use LRUN3
04000 ADDI T1,"0" ;MAKE ASCII
04100 OUTCHR T1 ;OUTPUT IT
04200 LRUN3: ADDI T2,"0" ;[441] loop out
04300 OUTCHR T2
04400 OUTSTR RUNER2 ;REST OF MESSAGE
04500 MOVE T2,%RNBLK ;PICK UP DEVICE
04600 LRUN4: SETZ T1, ;CLEAR OUT JUNK [441] label LRUN4
04700 LSHC T1,6 ;MOVE LEADING CHARACTER INTO T1
04800 MOVEI T1,40(T1) ;FORM ASCII
04900 OUTCHR T1 ;PRINT IT
05000 JUMPN T2,LRUN4 ;MORE TO GO [441] use LRUN4
05100 MOVEI T1,":" ;USUAL SEPARATOR
05200 OUTCHR T1
05300 MOVE T2,%RNBLK+1 ;FILE NAME
05400 LRUN5: SETZ T1, ;[441] label LRUN5
05500 LSHC T1,6
05600 MOVEI T1,40(T1)
05700 OUTCHR T1
05800 JUMPN T2,LRUN5 ;[441] use LRUN5
05900 EXIT ;AND GIVE UP
06000
06100 RUNER1:! ASCIZ /?CMLRUF RUN UUO failure (/
06200 RUNER2:! ASCIZ /) for /
06300
06400 %RNBLK:! ;SIZE OF PHASED CODE FOR BLT
06500 %LENTH==%RNBLK+6 ;FOR CORE UUO WHICH INCLUDES RUN BLOCK
06600 DEPHASE>
06700
06800 IFE RUNSW,<
06900 NORUN: INIT 1,16 ;GET A DSK IN DUMP MODE
07000 EXP SYSDEV ;SIXBIT SYS OR DSK
07100 0
07200 JRST DSKNA
07300 MOVSI T1,SAVEXT ;SIXBIT FOR SAVE OR DMP.
07400 MOVEM T1,NAME+1
07500 LOOKUP 1,NAME
07600 JRST NOFIL
07700 MOVE T1,NAME ;SET NAME OF NEW PROCESSOR
07800 CALL T1,[SIXBIT /SETNAM/]
07900 HLRO 15,NAME+3 ;GET COUNT
08000 HRLM 15,NUNCOM
08100 MOVNS 15 ;MAKE POSITIVE
08200 MOVEI 16,73(15) ;GET END
08300 ADDI 15,INHERE ;CHECK CORE SIZE
08400 IORI 15,1777
08500 MOVSI NUNTOP,NUNAC
08600 BLT NUNTOP,NUNTOP ;GET ACS LOADER
08700 HRR NUNBLT,16 ;AND SET END OF BLT
08800 JRST NUNGO2
08900 >
00100 SUBTTL SCANNER
00200
00300 TERMF==200000
00400 NUMF==100000
00500 SPCF==400000
00600 SPACT==40000 ;SPECIAL ACTION TO BE TAKEN ON CHAR
00700
00800 SCANAM: PUSHJ P,SCAN ;GET NEXT CHAR. FIRST
00900 GETNAM: SETZM SVNAM(SVPT) ;ZERO OUT CELLS IN CASE NOTHING
01000 SETZM SVEXT(SVPT) ;GETS PUT THERE
01100 SETZM SVPPN(SVPT)
01200 SETZM SWBKS(SVPT)
01300 SETZM SVDEV(SVPT)
01400 IFN SFDSW,<X==0 ;INITIAL CONDITION
01500 REPEAT SFDLEN,<
01600 SETZM SVSFD+X(SVPT)
01700 X==X+NFILE>
01800 > ;END OF IFN SFDSW
01900 GETNM0: TRNE FL,IDF ;[154] WAS THE THING SCANNED AN IDENT
02000 JRST GETDEV ;YES, SEE WHAT WE'VE GOT
02100 CAIE C,"[" ;MIGHT BE A PPN
02200 JRST SYNERP ;NO, LOSE UNLESS A PIP COMMAND
02300 PUSHJ P,GETPP1 ;READ THE PPN
02400 PUSHJ P,SCAN ;AND GET RID OF "]"
02500 SETOM INLFLG ;[305] SET IN-LINE FLAG
02600 TRNE FL,PIPF ;[227] IS THIS PIP?
02700 TRNE FL,IDF ;[227] YES, IDENTIFIER ALREADY SEEN?
02800 JRST GETDEV ;[227] NO
02900 POPJ P, ;IT IS, SO RETURN
03000 GETDEV: SETOM INLFLG ;[305] SET IN-LINE FLAG
03100 PUSH P,ACCUM
03200 PUSHJ P,SCANS ;CHECK FOR EXT OR PPN
03300 CAIE C,":" ;IS IT A DEVICE NAME
03400 JRST NODEV ;NO
03500 POP P,T1 ;[260]WE WERE HIDING IT IN THE STACK
03600 TRNN FL,F.STKY ;[302] DON'T MAKE STICKY IF FROM SWITCH
03700 MOVEM T1,SVDEVV ;[260]REMEMBER FOR 'STICKINESS'
03800 MOVEM T1,SVDEV(SVPT) ;[260]SAVE IT AS DEVICE NOW
03900 PUSHJ P,SCAN ;BYPASS
04000 PUSHJ P,SCANS ;[307] DO LOOK AHEAD
04100 SKIPN SAVCHR ;[307] NEXT CHARACTER A BLANK ?
04200 POPJ P, ;[307] YES--THAT'S IT, RETURN
04300 PUSHJ P,SCAN ;AND GET NEXT
04400 CAIN C,"[" ;CHECK FOR PROJ-PROG
04500 PUSHJ P,[PUSHJ P,GETPP1
04600 JRST SCAN] ;POPJ RETURN
04700 TRNN FL,IDF ;MUST BE AN IDENT
04800 POPJ P, ;RETURN, ONLY DEVICE SEEN
04900 PUSH P,ACCUM
05000 PUSHJ P,SCANS
05100 SETZM SVPPP ;CLEAR STICKY PPN ON NEW DEVICE
05200 IFN SFDSW,<
05300 SETZM SVSFP ;AND STICKY SFD
05400 IFG SFDLEN-1,< ;[426]
05500 MOVE T1,[SVSFP,,SVSFP+1]
05600 BLT T1,SVSFP+SFDLEN-1>> ;[425]
05700 NODEV: POP P,SVNAM(SVPT)
05800 SKIPN T1,SVDEVV ;[302] IF DEVICE, SKIP
05900 JRST NODEV1 ;[302] OTHERWISE, PROCEED
06000 TRNN FL,F.STKY ;[302] IF FROM SWITCH, DON'T SAVE
06100 MOVEM T1,SVDEV(SVPT) ;[254]ELSE, MAKE DEVICE HAPPEN
06200 NODEV1: TRNE FL,F.STKY ;[302] SHOULD PPN STICK ?
06300 JRST GOTSTK ;[302] NO--PROCEED
06400 IFE SFDSW,<
06500 SKIPE T1,SVPPN(SVPT) ;FOUND A NEW STICKY PPN?
06600 MOVEM T1,SVPPP ;YES
06700 >
06800 IFN SFDSW,<
06900 SKIPN T1,SVPPN(SVPT) ;STICKY PPN?
07000 JRST NOTSTK ;NO
07100 MOVEM T1,SVPPP ;YES
07200 X==<Y==0> ;INITIAL CONDITION
07300 REPEAT SFDLEN,<
07400 MOVE T1,SVSFD+X(SVPT)
07500 MOVEM T1,SVSFP+Y
07600 X==X+NFILE
07700 Y==Y+1
07800 >
07900 JRST GOTSTK ;DON'T MOVE IT BACK AGAIN
08000 NOTSTK:
08100 >
08200 MOVE T1,SVPPP ;GET STICKY PPN
08300 MOVEM T1,SVPPN(SVPT) ;SET PPN INCASE ONE NOT FOLLOWING
08400 IFN SFDSW,<X==<Y==0> ;INITIAL CONDITION
08500 REPEAT SFDLEN,<
08600 MOVE T1,SVSFP+Y
08700 MOVEM T1,SVSFD+X(SVPT)
08800 X==X+NFILE
08900 Y==Y+1>