-
Notifications
You must be signed in to change notification settings - Fork 10
/
Copy pathzccdb_get_stores.prog.abap
1127 lines (912 loc) · 37.4 KB
/
zccdb_get_stores.prog.abap
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
*&---------------------------------------------------------------------*
*& Report ZCCDB_GET_STORES
*&---------------------------------------------------------------------*
*& Show an overview about configuration stores in FRUN
*& Author: Frank Buchholz, SAP CoE Security Services
*& https://github.com/SAP-samples/security-services-tools
*&
*& All select options have a value help. After pressing ENTER the already
*& entered values are used to restrict the value help for the current field.
*&
*& You can select stores and use function F2 or you can double click on
*& an entry to show the data of the selected stores. All selected stores
*& have to contain the same field list.
*&
*& You can add filter values to reduce the data shown. Both filter fields
*& are connected with a locical AND.
*&
*& A double click on field value DDIC_TABLENAME shows the table in SE16
*& instead of using the internal viewer.
*&
*& 27.01.2023 Initial version
*& 21.05.2024 Enhance robustness if case of no data
*&---------------------------------------------------------------------*
REPORT zccdb_get_stores.
CONSTANTS: c_program_version(30) TYPE c VALUE '21.05.2024 FQ4'.
SELECTION-SCREEN BEGIN OF BLOCK sel WITH FRAME TITLE text001.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(25) ss_sid FOR FIELD extsid.
SELECT-OPTIONS extsid FOR ('LMDB_ESID'). " Extended System ID
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(25) ss_type FOR FIELD systype.
SELECT-OPTIONS systype FOR ('LMDB_SYSTEM_TYPE'). " Technical System Type
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(25) ss_id FOR FIELD sci_id.
SELECT-OPTIONS sci_id FOR ('CCDB_SCI_ID'). " Store Collect Item
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(25) ss_store FOR FIELD storenam.
SELECT-OPTIONS storenam FOR ('CCDB_STORE_NAME'). " Store Name
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK sel.
SELECTION-SCREEN BEGIN OF BLOCK filter WITH FRAME TITLE text002.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(25) ss_val_1 FOR FIELD val_1.
SELECT-OPTIONS val_1 FOR ('TEXT60'). " Filter value
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(25) ss_val_2 FOR FIELD val_2.
SELECT-OPTIONS val_2 FOR ('TEXT60'). " Filter value
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS showdata AS CHECKBOX.
SELECTION-SCREEN COMMENT 3(25) ss_data FOR FIELD showdata.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK filter.
* Layout of ALV output
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(30) ps_lout FOR FIELD p_layout.
PARAMETERS p_layout TYPE disvariant-variant.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN COMMENT /1(60) ss_vers.
*-----------------------------------------------------------------------
INITIALIZATION.
sy-title = 'Show configuration stores and content'(tit).
text001 = 'Store selection'(001).
ss_sid = 'System'(002).
ss_type = 'System type'(003).
ss_id = 'Store item'(004).
ss_store = 'Store name'(005).
text002 = 'Filter for configuration items or values'(006).
ss_val_1 = 'Value'(007).
ss_val_2 = 'and value'(008).
ss_data = 'Show data directly'(009).
ps_lout = 'Layout'(010).
CONCATENATE 'Program version:'(ver) c_program_version INTO ss_vers
SEPARATED BY space.
*-----------------------------------------------------------------------
AT SELECTION-SCREEN ON VALUE-REQUEST FOR extsid-low.
PERFORM f4_extsid USING 'EXTSID-LOW'.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR extsid-high.
PERFORM f4_extsid USING 'EXTSID-HIGH'.
FORM f4_extsid USING l_dynprofield TYPE help_info-dynprofld.
TYPES:
BEGIN OF ts_value_tab,
extsid TYPE lmdb_esid, " Extended System ID
system_type TYPE lmdb_system_type, " Technical System Type
END OF ts_value_tab.
STATICS:
"dynpro_values TYPE TABLE OF dynpread,
"field_value LIKE LINE OF dynpro_values,
"field_tab TYPE TABLE OF dfies WITH HEADER LINE,
value_tab TYPE STANDARD TABLE OF ts_value_tab.
DATA(progname) = sy-repid.
DATA(dynnum) = sy-dynnr.
"IF value_tab[] IS INITIAL.
SELECT DISTINCT extsid, system_type
FROM ccdb_rt_dirv_dbv " Store Directory - Root (Internal)
INTO TABLE @value_tab
WHERE system_type IN @systype " System type
"AND extsid IN @extsid " System name
AND sci_id IN @sci_id " Store id
AND store_name IN @storenam " Store name
ORDER BY extsid, system_type.
"ENDIF.
CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
EXPORTING
retfield = 'EXTSID'
dynpprog = progname
dynpnr = dynnum
dynprofield = l_dynprofield
value_org = 'S'
TABLES
* field_tab = field_tab
value_tab = value_tab
EXCEPTIONS
parameter_error = 1
no_values_found = 2.
IF sy-subrc <> 0.
* Implement suitable error handling here
ENDIF.
ENDFORM.
*-----------------------------------------------------------------------
AT SELECTION-SCREEN ON VALUE-REQUEST FOR systype-low.
PERFORM f4_systype USING 'SYSTYPE-LOW'.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR systype-high.
PERFORM f4_systype USING 'SYSTYPE-HIGH'.
FORM f4_systype USING l_dynprofield TYPE help_info-dynprofld.
TYPES:
BEGIN OF ts_value_tab,
system_type TYPE lmdb_system_type, " Technical System Type
END OF ts_value_tab.
STATICS:
value_tab TYPE STANDARD TABLE OF ts_value_tab.
DATA(progname) = sy-repid.
DATA(dynnum) = sy-dynnr.
"IF value_tab[] IS INITIAL.
SELECT DISTINCT system_type
FROM ccdb_rt_dirv_dbv " Store Directory - Root (Internal)
INTO TABLE @value_tab
WHERE extsid IN @extsid " System name
"AND system_type IN @systype " System type
AND sci_id IN @sci_id " Store id
AND store_name IN @storenam " Store name
ORDER BY system_type.
"ENDIF.
CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
EXPORTING
retfield = 'SYSTYPE'
dynpprog = progname
dynpnr = dynnum
dynprofield = l_dynprofield
value_org = 'S'
TABLES
* field_tab = field_tab
value_tab = value_tab
EXCEPTIONS
parameter_error = 1
no_values_found = 2.
IF sy-subrc <> 0.
* Implement suitable error handling here
ENDIF.
ENDFORM.
*-----------------------------------------------------------------------
AT SELECTION-SCREEN ON VALUE-REQUEST FOR sci_id-low.
PERFORM f4_sci_id USING 'SCI_ID-LOW'.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR sci_id-high.
PERFORM f4_sci_id USING 'SCI_ID-HIGH'.
FORM f4_sci_id USING l_dynprofield TYPE help_info-dynprofld.
TYPES:
BEGIN OF ts_value_tab,
sci_id TYPE ccdb_sci_id, " Store Collect Item
sci_desc TYPE cof_extr_desc, " Description
END OF ts_value_tab.
STATICS:
value_tab TYPE STANDARD TABLE OF ts_value_tab.
DATA(progname) = sy-repid.
DATA(dynnum) = sy-dynnr.
"IF value_tab[] IS INITIAL.
SELECT DISTINCT sci_id, sci_desc
FROM ccdb_rt_dirv_dbv " Store Directory - Root (Internal)
INTO TABLE @value_tab
WHERE extsid IN @extsid " System name
AND system_type IN @systype " System type
"AND sci_id IN @sci_id " Store id
AND store_name IN @storenam " Store name
ORDER BY sci_id.
"ENDIF.
CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
EXPORTING
retfield = 'SCI_ID'
dynpprog = progname
dynpnr = dynnum
dynprofield = l_dynprofield
value_org = 'S'
TABLES
* field_tab = field_tab
value_tab = value_tab
EXCEPTIONS
parameter_error = 1
no_values_found = 2.
IF sy-subrc <> 0.
* Implement suitable error handling here
ENDIF.
ENDFORM.
*-----------------------------------------------------------------------
AT SELECTION-SCREEN ON VALUE-REQUEST FOR storenam-low.
PERFORM f4_storenam USING 'STORENAM-LOW'.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR storenam-high.
PERFORM f4_storenam USING 'STORENAM-HIGH'.
FORM f4_storenam USING l_dynprofield TYPE help_info-dynprofld.
TYPES:
BEGIN OF ts_value_tab,
store_name TYPE ccdb_store_name, " Store Name
sci_id TYPE ccdb_sci_id, " Store Collect Item
sci_desc TYPE cof_extr_desc, " Description
END OF ts_value_tab.
STATICS:
value_tab TYPE STANDARD TABLE OF ts_value_tab.
DATA(progname) = sy-repid.
DATA(dynnum) = sy-dynnr.
"IF value_tab[] IS INITIAL.
SELECT DISTINCT store_name, sci_id, sci_desc
FROM ccdb_rt_dirv_dbv " Store Directory - Root (Internal)
INTO TABLE @value_tab
WHERE extsid IN @extsid " System name
AND system_type IN @systype " System type
AND sci_id IN @sci_id " Store id
"AND store_name IN @storenam " Store name
ORDER BY store_name, sci_id.
"ENDIF.
CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
EXPORTING
retfield = 'STORE_NAME'
dynpprog = progname
dynpnr = dynnum
dynprofield = l_dynprofield
value_org = 'S'
TABLES
* field_tab = field_tab
value_tab = value_tab
EXCEPTIONS
parameter_error = 1
no_values_found = 2.
IF sy-subrc <> 0.
* Implement suitable error handling here
ENDIF.
ENDFORM.
*----------------------------------------------------------------------*
* AT SELECTION-SCREEN ON p_layout
*----------------------------------------------------------------------*
DATA: gs_alv_lout_variant TYPE disvariant.
AT SELECTION-SCREEN ON p_layout.
CHECK NOT p_layout IS INITIAL.
PERFORM handle_at_selscr_on_p_layout USING p_layout sy-repid 'A'.
*
FORM handle_at_selscr_on_p_layout
USING id_varname TYPE disvariant-variant
id_repid TYPE sy-repid
id_save TYPE c.
DATA: ls_variant TYPE disvariant.
ls_variant-report = id_repid.
ls_variant-variant = id_varname.
CALL FUNCTION 'REUSE_ALV_VARIANT_EXISTENCE'
EXPORTING
i_save = id_save
CHANGING
cs_variant = ls_variant
EXCEPTIONS
wrong_input = 1
not_found = 2
program_error = 3
OTHERS = 4.
IF sy-subrc <> 0.
* Selected layout variant is not found
MESSAGE e204(0k).
ENDIF.
gs_alv_lout_variant-report = id_repid.
gs_alv_lout_variant-variant = id_varname.
ENDFORM. " handle_at_selscr_on_p_layout
*----------------------------------------------------------------------*
* AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_layout
*----------------------------------------------------------------------*
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_layout. " ( Note 890141 )
PERFORM handle_at_selscr_f4_p_layout USING sy-repid 'A'
CHANGING p_layout.
*
FORM handle_at_selscr_f4_p_layout
USING id_repid TYPE sy-repid
id_save TYPE c
CHANGING ed_varname TYPE disvariant-variant.
gs_alv_lout_variant-report = id_repid.
CALL FUNCTION 'REUSE_ALV_VARIANT_F4'
EXPORTING
is_variant = gs_alv_lout_variant
i_save = id_save
IMPORTING
es_variant = gs_alv_lout_variant
EXCEPTIONS
not_found = 1
program_error = 2
OTHERS = 3.
IF sy-subrc = 0.
ed_varname = gs_alv_lout_variant-variant.
ELSE.
MESSAGE s073(0k).
* Keine Anzeigevariante(n) vorhanden
ENDIF.
ENDFORM. " handle_at_selscr_f4_p_layout
*-----------------------------------------------------------------------
CLASS main DEFINITION.
PUBLIC SECTION.
" main report coding
CLASS-METHODS:
authority_check RETURNING VALUE(subrc) TYPE i,
get_stores,
show_stores,
show_all_content.
PRIVATE SECTION.
TYPES:
BEGIN OF ts_storetab.
INCLUDE TYPE ccdb_dirv.
TYPES:
"t_color TYPE lvc_t_scol,
"t_celltype TYPE salv_t_int4_column,
"t_hyperlink TYPE salv_t_int4_column,
"t_dropdown TYPE salv_t_int4_column,
END OF ts_storetab,
tt_outtab TYPE STANDARD TABLE OF ts_storetab.
CLASS-DATA:
lr_alv_table TYPE REF TO cl_salv_table,
lt_storetab TYPE tt_outtab.
" handling the events of cl_salv_table
CLASS-METHODS:
on_user_command FOR EVENT added_function OF cl_salv_events
IMPORTING e_salv_function,
on_double_click FOR EVENT double_click OF cl_salv_events_table
IMPORTING row column.
"on_single_click FOR EVENT link_click OF cl_salv_events_table
" IMPORTING row column.
CLASS-METHODS:
show_content
IMPORTING lt_seleced_rows TYPE salv_t_row.
ENDCLASS.
CLASS main IMPLEMENTATION.
METHOD authority_check.
" Check general CCDB-Read-API authorization
subrc = cl_ccdb_read=>check_read_ext_auth_read( ).
"IF subrc NE 0.
" MESSAGE e016(cx_ccdb_exception). " Permission denied
"ENDIF.
ENDMETHOD.
METHOD get_stores.
" based on function CCDB_GET_STORES
" Get Data
SELECT *
FROM ccdb_rt_dirv_dbv " Store Directory - Root (Internal)
INTO CORRESPONDING FIELDS OF TABLE @lt_storetab
WHERE extsid IN @extsid " System name
AND system_type IN @systype " System type
AND sci_id IN @sci_id " Store id
AND store_name IN @storenam " Store name
ORDER BY extsid, system_type, sci_id
.
" Perform End User Fencing ?
IF cl_ccdb_read=>check_read_ext_auth_readall( ) NE 0.
" End User Fencing
DATA: lt_guid TYPE HASHED TABLE OF cl_cof_lmdb=>ts_guid32 WITH UNIQUE KEY guid.
DATA: lt_guid_show TYPE HASHED TABLE OF cl_cof_lmdb=>ts_guid32 WITH UNIQUE KEY guid.
DATA: ls_guid TYPE cl_cof_lmdb=>ts_guid32.
DATA: li_tabix TYPE i.
DATA ls_storetab TYPE ts_storetab.
LOOP AT lt_storetab INTO ls_storetab.
ls_guid-guid = ls_storetab-rt_cim_guid.
INSERT ls_guid INTO TABLE lt_guid.
IF sy-subrc NE 0.
" filter duplicates
ENDIF.
ENDLOOP.
cl_cof_lmdb=>exec_end_user_fencing(
EXPORTING
im_table = lt_guid
im_guid_column_name = 'GUID'
IMPORTING
ex_table = lt_guid_show ).
IF lt_guid_show NE lt_guid.
LOOP AT lt_storetab INTO ls_storetab.
li_tabix = sy-tabix.
READ TABLE lt_guid_show TRANSPORTING NO FIELDS
WITH KEY guid = ls_storetab-rt_cim_guid.
IF sy-subrc NE 0.
DELETE lt_storetab INDEX li_tabix.
ENDIF.
ENDLOOP.
ENDIF.
ENDIF.
ENDMETHOD.
METHOD show_stores.
" Display a table as ALV-Grid
"CALL FUNCTION 'COF_ITAB_VIEWER'
" EXPORTING
" t_flat_table = lt_storetab
" use_tech_fieldnames = ' '
" hide_initial_columns = ' '.
" Display ALV-Grid
DATA: lr_exception TYPE REF TO cx_salv_error.
TRY.
" Instantiation
cl_salv_table=>factory(
EXPORTING
list_display = abap_false " false: grid, true: list
IMPORTING
r_salv_table = lr_alv_table
CHANGING
t_table = lt_storetab ).
"... activate ALV generic Functions
DATA(lr_functions) = lr_alv_table->get_functions( ).
"lr_functions->set_default( abap_true ). " Enable default ALV toolbar functions
lr_functions->set_all( abap_true ). " Enable all ALV toolbar functions
"lr_functions->set_detail( if_salv_c_bool_sap=>true ).
"lr_functions->set_group_export( if_salv_c_bool_sap=>true ).
"lr_functions->set_group_filter( if_salv_c_bool_sap=>true ).
"lr_functions->set_group_layout( if_salv_c_bool_sap=>true ).
"lr_functions->set_print( if_salv_c_bool_sap=>true ).
"lr_functions->set_print_preview( if_salv_c_bool_sap=>true ).
"lr_functions->set_group_sort( if_salv_c_bool_sap=>true ).
"lr_functions->set_find( if_salv_c_bool_sap=>true ).
"lr_functions->set_graphics( if_salv_c_bool_sap=>false ).
"... allow to save layout
DATA(lr_layout) = lr_alv_table->get_layout( ).
lr_layout->set_key( VALUE #( report = sy-repid ) ). " Set layout key for identifying the particular ALV list
"lr_layout->set_default( abap_true ). " Allow setting layouts as default layouts
lr_layout->set_initial_layout( p_layout ). " Set initial variant
AUTHORITY-CHECK OBJECT 'S_ALV_LAYO'
ID 'ACTVT' FIELD '23'.
IF sy-subrc = 0.
lr_layout->set_save_restriction( cl_salv_layout=>restrict_none ). " Allow variant saving
ELSE.
lr_layout->set_save_restriction( cl_salv_layout=>restrict_user_dependant ). " Allow user specific variant saving
ENDIF.
"... set the display settings
DATA(lr_display) = lr_alv_table->get_display_settings( ).
lr_display->set_list_header( sy-title ).
"lr_display->set_list_header( header ).
"lr_display->set_list_header_size( header_size ).
lr_display->set_striped_pattern( abap_true ).
lr_display->set_horizontal_lines( abap_true ).
lr_display->set_vertical_lines( abap_true ).
"lr_display->set_suppress_empty_data( abap_true ).
"... set the functional settings
DATA(lr_functional) = lr_alv_table->get_functional_settings( ).
lr_functional->set_sort_on_header_click( abap_true ).
"lr_functional->set_f2_code( f2code ).
"lr_functional->set_buffer( gs_test-settings-functional-buffer ).
"... sort
DATA(lr_sorts) = lr_alv_table->get_sorts( ).
"lr_sorts->add_sort( 'EXTSID' ).
"... set selection mode
DATA(lr_selections) = lr_alv_table->get_selections( ).
"allow single line selection
lr_selections->set_selection_mode( if_salv_c_selection_mode=>row_column ). " SINGLE, MULTIPLE, CELL, ROW_COLUMN, NONE
"... register to the events of cl_salv_table
DATA(lr_events) = lr_alv_table->get_event( ).
SET HANDLER on_user_command FOR lr_events.
SET HANDLER on_double_click FOR lr_events.
"... set column appearance
DATA(lr_columns) = lr_alv_table->get_columns( ).
lr_columns->set_optimize( abap_true ).
"... set column attributes
DATA lr_column TYPE REF TO cl_salv_column_table. " Columns in Simple, Two-Dimensional Tables
DATA color TYPE lvc_s_colo.
color-col = 1. " 2=light blue, 3=yellow, 4=blue, 5=green, 6=red, 7=orange
lr_column ?= lr_columns->get_column( 'STORE_ID' ).
"lr_column->set_long_text( 'LONG_HEADER_40__________________________' ).
"lr_column->set_medium_text( 'MEDIUM_HEADER_20____' ).
"lr_column->set_short_text( 'SHORT_10__' ).
lr_column->set_visible( abap_false ).
lr_column ?= lr_columns->get_column( 'RT_CIM_GUID' ).
lr_column->set_long_text( 'Runtime CIM GUID' ).
lr_column->set_medium_text( 'Runtime CIM GUID' ).
lr_column->set_short_text( 'RT GUID' ).
lr_column->set_visible( abap_false ).
lr_column ?= lr_columns->get_column( 'RT_CIM_NSPA' ).
lr_column->set_visible( abap_false ).
lr_column ?= lr_columns->get_column( 'RT_TYPE' ).
lr_column->set_key( abap_false ).
lr_column->set_visible( abap_false ).
lr_column ?= lr_columns->get_column( 'EXTSID' ).
lr_column ?= lr_columns->get_column( 'SYSTEM_TYPE' ).
lr_column ?= lr_columns->get_column( 'SCI_ID' ).
lr_column ?= lr_columns->get_column( 'SCI_DESC' ).
lr_column->set_key( abap_false ).
lr_column ?= lr_columns->get_column( 'PROTECTED' ).
lr_column->set_key( abap_false ).
lr_column->set_visible( abap_false ).
lr_column ?= lr_columns->get_column( 'EC_OB_DEST_ID' ).
lr_column->set_key( abap_false ).
lr_column->set_visible( abap_false ).
lr_column ?= lr_columns->get_column( 'ASSIGNMENT_TYPE' ).
lr_column->set_long_text( 'Assignment type' ).
lr_column->set_medium_text( 'Assignment type' ).
lr_column->set_short_text( 'AssignType' ).
lr_column->set_key( abap_false ).
lr_column->set_visible( abap_false ).
lr_column ?= lr_columns->get_column( 'STORE_CIM_GUID' ).
lr_column->set_long_text( 'Store CIM GUID' ).
lr_column->set_medium_text( 'Store CIM GUID' ).
lr_column->set_short_text( 'Store GUID' ).
lr_column->set_visible( abap_false ).
lr_column ?= lr_columns->get_column( 'STORE_CIM_CLASS' ).
lr_column->set_key( abap_false ).
lr_column ?= lr_columns->get_column( 'STORE_CIM_CAPT' ).
lr_column->set_key( abap_false ).
lr_column ?= lr_columns->get_column( 'STORE_NAME_EXT' ).
lr_column->set_key( abap_false ).
lr_column->set_key( abap_false ).
lr_column ?= lr_columns->get_column( 'STORE_NAME' ).
lr_column ?= lr_columns->get_column( 'DDIC_TABLENAME' ).
lr_column->set_key( abap_false ).
lr_column->set_visible( abap_true ).
lr_column ?= lr_columns->get_column( 'STORE_FROM_DATE' ).
lr_column->set_long_text( 'From date' ).
lr_column->set_medium_text( 'From date' ).
lr_column->set_short_text( 'From date' ).
lr_column->set_edit_mask( '==TSTMP' ). " convert time stamps
lr_column->set_key( abap_false ).
lr_column ?= lr_columns->get_column( 'STORE_TO_DATE' ).
lr_column->set_long_text( 'To date' ).
lr_column->set_medium_text( 'To date' ).
lr_column->set_short_text( 'To date' ).
lr_column->set_edit_mask( '==TSTMP' ). " convert time stamps
lr_column->set_key( abap_false ).
lr_column ?= lr_columns->get_column( 'STORE_TYPE' ).
lr_column->set_key( abap_false ).
"... header
DATA lr_grid_header TYPE REF TO cl_salv_form_layout_grid.
CREATE OBJECT lr_grid_header.
lr_grid_header->create_text(
row = 1
column = 1
text = 'Select multiple stores of the same type and use function F2 to show the data' ).
lr_alv_table->set_top_of_list( lr_grid_header ).
"... select all entries
"if sel_all = ABAP_true.
" lr_selections->set_selected_rows( VALUE #( FOR i = 1 THEN i + 1 WHILE i <= lines( lt_storetab ) ( i ) ) ).
"endif.
"Display the ALV Grid
lr_alv_table->display( ).
CATCH cx_salv_msg
cx_salv_not_found
cx_salv_data_error
cx_salv_existing
INTO lr_exception.
DATA(lv_message) = lr_exception->get_message( ).
MESSAGE ID lv_message-msgid TYPE lv_message-msgty
NUMBER lv_message-msgno
WITH lv_message-msgv1 lv_message-msgv2
lv_message-msgv3 lv_message-msgv4.
ENDTRY.
ENDMETHOD.
METHOD on_user_command.
* importing e_salv_function
* Get selected items
DATA(lr_selections) = lr_alv_table->get_selections( ).
DATA(ls_cell) = lr_selections->get_current_cell( ).
DATA(lt_seleced_rows) = lr_selections->get_selected_rows( ).
CASE e_salv_function.
WHEN 'PICK'.
IF lt_seleced_rows IS NOT INITIAL.
show_content( lt_seleced_rows ).
ENDIF.
ENDCASE.
ENDMETHOD. "on_user_command
METHOD on_double_click. " F2
* importing row column
CASE column.
WHEN 'DDIC_TABLENAME'.
" Show content in transaction SE16
READ TABLE lt_storetab INTO DATA(ls_storetab) INDEX row.
DATA(t_sel) = VALUE rsparams_tt( (
selname = 'I1' " Let's assume that field STORE_ID is the first field always
kind = 'S' " S: Select option, P: Parameter
sign = 'I' " Include
option = 'EQ'
low = ls_storetab-store_id
high = ''
) ).
CALL FUNCTION 'RS_TABLE_LIST_CREATE'
EXPORTING
table_name = ls_storetab-ddic_tablename
"action = 'ANZE'
"without_submit = ' '
"generation_forced =
"new_sel =
"no_structure_check = ' '
"data_exit = ' '
"IMPORTING
"progname =
TABLES
seltab = t_sel
EXCEPTIONS
table_is_structure = 1
table_not_exists = 2
db_not_exists = 3
no_permission = 4
no_change_allowed = 5
table_is_gtt = 6
cds_view_not_supported = 7
OTHERS = 8.
IF sy-subrc <> 0.
* Implement suitable error handling here
ENDIF.
WHEN OTHERS.
" internal viewer
DATA(lr_selections) = lr_alv_table->get_selections( ).
DATA(ls_cell) = lr_selections->get_current_cell( ).
DATA(lt_seleced_rows) = lr_selections->get_selected_rows( ).
IF lt_seleced_rows IS NOT INITIAL.
show_content( lt_seleced_rows ). " Multiple stores are selected
ELSE.
show_content( VALUE #( ( row ) ) ). " Show current store
ENDIF.
ENDCASE.
ENDMETHOD. "on_double_click
METHOD show_content.
" importing lt_seleced_rows
" used global variables: val_1 val_2
DATA:
first_entry TYPE abap_bool VALUE abap_true,
lv_caller TYPE char10 VALUE 'MY_APPL',
lx_data TYPE xstring,
li_rc TYPE i,
lv_rc_string TYPE string.
DATA: ls_fieldlist TYPE sccdb_fieldlist.
DATA: lt_fieldlist TYPE tt_ccdb_fieldlist_sorted. " Current field list
DATA: lt_fieldlist_1 TYPE tt_ccdb_fieldlist_sorted. " Field list of first store
DATA: components TYPE abap_component_tab,
component TYPE abap_componentdescr.
" Dynamic table for raw data
DATA: r_dyntable TYPE REF TO cl_abap_tabledescr,
r_dynstruc TYPE REF TO cl_abap_structdescr.
DATA: lr_table_struc TYPE REF TO data.
DATA: lr_table TYPE REF TO data.
FIELD-SYMBOLS: <table_struc> TYPE any.
FIELD-SYMBOLS: <table> TYPE STANDARD TABLE.
" Dynamic table for extended result data
DATA: r_dyntable_ext TYPE REF TO cl_abap_tabledescr,
r_dynstruc_ext TYPE REF TO cl_abap_structdescr.
DATA: lr_table_struc_ext TYPE REF TO data.
DATA: lr_table_ext TYPE REF TO data.
FIELD-SYMBOLS: <table_struc_ext> TYPE any.
FIELD-SYMBOLS: <table_ext> TYPE STANDARD TABLE.
LOOP AT lt_seleced_rows INTO DATA(row).
READ TABLE lt_storetab INTO DATA(ls_storetab) INDEX row.
CASE ls_storetab-store_type.
WHEN: 'TABLE' OR 'TEXT'.
CALL FUNCTION 'CCDB_GET_TABLE_SN' " Same function gan be used for both store types
EXPORTING
store_id = ls_storetab-store_id
caller = lv_caller
IMPORTING
fieldlist = lt_fieldlist
" SNAPSHOT TYPE TT_CCDB_TROW
snapshot_itsam = lx_data
rc = li_rc
rc_string = lv_rc_string.
IF li_rc NE 0.
MESSAGE lv_rc_string TYPE 'I'.
RETURN.
ENDIF.
IF first_entry EQ abap_false AND lt_fieldlist_1[] NE lt_fieldlist[].
MESSAGE 'Do not mix different store structures' TYPE 'I'.
RETURN.
ENDIF.
lt_fieldlist_1[] = lt_fieldlist[].
IF first_entry = abap_true.
" Determine fieldlist (not neccessary)
"CALL TRANSFORMATION id
" SOURCE XML lx_data
" RESULT fieldlist = lt_fieldlist.
" define table structure
LOOP AT lt_fieldlist INTO ls_fieldlist.
" Process Component if provided
CLEAR component.
component-name = ls_fieldlist-fieldname.
component-type = cl_abap_elemdescr=>get_string( ).
APPEND component TO components.
ENDLOOP.
TRY.
" create raw table structure
r_dynstruc = cl_abap_structdescr=>create(
p_components = components
p_strict = space " allow e.g. '/'
).
" create raw table (Standard table)
r_dyntable = cl_abap_tabledescr=>create(
p_line_type = r_dynstruc
p_table_kind = cl_abap_tabledescr=>tablekind_std
" cl_abap_tabledescr=>TABLEKIND_SORTED
"p_key_kind = cl_abap_tabledescr=>KEYDEFKIND_USER
"p_key = lt_key_fields
"p_unique = 'X'
).
"CREATE DATA lr_table_struc TYPE HANDLE r_dynstruc. " not used
"ASSIGN lr_table_struc->* TO <table_struc>.
CREATE DATA lr_table TYPE HANDLE r_dyntable.
ASSIGN lr_table->* TO <table>.
CATCH cx_sy_struct_creation cx_sy_table_creation INTO DATA(cx_dynabp_error).
MESSAGE cx_dynabp_error->get_text( ) TYPE 'I'.
RETURN.
ENDTRY.
ENDIF. " end of 1st entry
" get raw data
CALL TRANSFORMATION id
SOURCE XML lx_data
RESULT snapshot = <table>.
WHEN: 'XML'.
" call function 'CCDB_GET_XML_SN'...
WHEN: 'EVENT'.
" call function 'CCDB_GET_EVENT_TR'...
ENDCASE.
*-----------------------------------------------------------------------
" copy data to result table
IF first_entry = abap_true.
" create extended result table structure
CLEAR: component, components.
component-name = 'EXTSID'.
component-type = cl_abap_elemdescr=>get_string( ). " Can we use the real type here?
APPEND component TO components.
component-name = 'SCI_ID'.
component-type = cl_abap_elemdescr=>get_string( ). " Can we use the real type here?
APPEND component TO components.
component-name = 'STORE_NAME'.
component-type = cl_abap_elemdescr=>get_string( ). " Can we use the real type here?
APPEND component TO components.
LOOP AT lt_fieldlist INTO ls_fieldlist.
component-name = ls_fieldlist-fieldname.
component-type = cl_abap_elemdescr=>get_string( ).
APPEND component TO components.
ENDLOOP.
TRY.
r_dynstruc_ext = cl_abap_structdescr=>create(
p_components = components
p_strict = space " allow e.g. '/'
).
" create result table (Standard table)
r_dyntable_ext = cl_abap_tabledescr=>create(
p_line_type = r_dynstruc_ext
p_table_kind = cl_abap_tabledescr=>tablekind_std
" cl_abap_tabledescr=>TABLEKIND_SORTED
"p_key_kind = cl_abap_tabledescr=>KEYDEFKIND_USER
"p_key = lt_key_fields
"p_unique = 'X'
).
CATCH cx_sy_struct_creation cx_sy_table_creation INTO cx_dynabp_error.
MESSAGE cx_dynabp_error->get_text( ) TYPE 'I'.
RETURN.
ENDTRY.
CREATE DATA lr_table_struc_ext TYPE HANDLE r_dynstruc_ext.
ASSIGN lr_table_struc_ext->* TO <table_struc_ext>.
CREATE DATA lr_table_ext TYPE HANDLE r_dyntable_ext.
ASSIGN lr_table_ext->* TO <table_ext>.
ENDIF. " end of 1st entry
first_entry = abap_false.
check <table> IS ASSIGNED.
LOOP AT <table> ASSIGNING <table_struc>.
" Filter values
IF val_1 IS NOT INITIAL OR val_2 IS NOT INITIAL.
DATA: pos TYPE i,
found_1 TYPE abap_bool,
found_2 TYPE abap_bool.
FIELD-SYMBOLS: <field> TYPE any.
pos = 1.
found_1 = abap_false.
found_2 = abap_false.
DO.
ASSIGN COMPONENT pos OF STRUCTURE <table_struc> TO <field>.
IF sy-subrc NE 0.
EXIT.
ENDIF.
IF <field> IN val_1. " Compare field value with select option of the report
found_1 = abap_true.
ENDIF.
IF <field> IN val_2. " Compare field value with select option of the report
found_2 = abap_true.
ENDIF.
pos += 1.
ENDDO.
IF found_1 = abap_false OR found_2 = abap_false.
CONTINUE. " Omit this entry
ENDIF.
ENDIF.
" Copy extended data
DATA: "Does there exist a smarter way to copy selected data only?
BEGIN OF temp,
extsid TYPE lmdb_esid,
sci_id TYPE ccdb_sci_id,
store_name TYPE ccdb_store_name,
END OF temp.
MOVE-CORRESPONDING ls_storetab TO temp.
MOVE-CORRESPONDING temp TO <table_struc_ext>.
" Copy data
MOVE-CORRESPONDING <table_struc> TO <table_struc_ext>.
APPEND <table_struc_ext> TO <table_ext>.
ENDLOOP.
ENDLOOP.
IF <table_ext> IS NOT ASSIGNED.
MESSAGE 'No data' TYPE 'I'.
RETURN.