build.gradle

//file:noinspection GrDeprecatedAPIUsage
//file:noinspection GrUnresolvedAccess
//file:noinspection GroovyAssignabilityCheck
import org.apache.tools.ant.filters.ReplaceTokens

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'maven-publish'
}

compileJava {
    options.encoding = 'UTF-8'
}

// VirtualFurnace version
version = '1.1.1'
def oldestJava = 17

repositories {
    mavenCentral()
    mavenLocal()

    // Paper
    maven { url 'https://repo.papermc.io/repository/maven-public/' }
}

dependencies {
    // Paper
    compileOnly("io.papermc.paper:paper-api:1.21.4-R0.1-SNAPSHOT")

    // bStats
    implementation(group: 'org.bstats', name: 'bstats-bukkit', version: '3.0.2')
}

tasks.withType(JavaCompile).configureEach {
    options.compilerArgs += ['-source', '' + oldestJava, '-target', '' + oldestJava]
}

build {
    tasks.withType(JavaCompile).tap {
        configureEach {
            options.compilerArgs.add("-Xlint:unchecked")
            //options.compilerArgs.add("-Xlint:deprecation")
        }
    }
}

processResources {
    filter ReplaceTokens, tokens: ["version": project.version]
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId 'com.shanebeestudios'
            artifactId 'VirtualFurnace'
            version project.version
            artifact jar
        }
    }
}

javadoc {
    destinationDir = file("${buildDir}/javadoc")
    options {
        links('https://hub.spigotmc.org/javadocs/spigot/')
        links('https://jd.advntr.dev/api/4.14.0/')
    }
    options.addStringOption('Xdoclint:none', '-quiet')
    exclude("com/shanebeestudios/vf/**.java", "com/shanebeestudios/vf/command", "com/shanebeestudios/vf/debug")
}