-
Notifications
You must be signed in to change notification settings - Fork 201
/
build.gradle
1636 lines (1473 loc) · 56.2 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* Copyright (c) 2017-2022 TIBCO Software Inc. All rights reserved.
*
* Licensed under the Apache License, Version 2.0 (the "License"); you
* may not use this file except in compliance with the License. You
* may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or
* implied. See the License for the specific language governing
* permissions and limitations under the License. See accompanying
* LICENSE file.
*/
import org.gradle.api.tasks.testing.logging.*
import org.gradle.internal.logging.*
buildscript {
repositories {
maven { url 'https://plugins.gradle.org/m2' }
mavenCentral()
}
dependencies {
classpath 'io.snappydata:gradle-scalatest:0.25'
classpath 'org.github.ngbinh.scalastyle:gradle-scalastyle-plugin_2.11:0.9.0'
classpath 'com.github.jengelman.gradle.plugins:shadow:5.2.0'
classpath 'de.undercouch:gradle-download-task:3.4.3'
classpath 'net.rdrei.android.buildtimetracker:gradle-plugin:0.11.+'
classpath 'com.netflix.nebula:gradle-ospackage-plugin:5.2.+'
classpath 'org.owasp:dependency-check-gradle:7.1.0.1'
}
}
apply plugin: 'wrapper'
apply plugin: 'distribution'
apply plugin: 'nebula.ospackage-base'
apply plugin: "nebula.ospackage"
// def isEnterpriseProduct = rootProject.hasProperty('snappydata.enterprise')
allprojects {
// We want to see all test results. This is equivalent to setting --continue
// on the command line.
gradle.startParameter.continueOnFailure = true
tasks.withType(Javadoc) {
options.addStringOption('Xdoclint:none', '-quiet')
/*
if (javax.tools.ToolProvider.getSystemDocumentationTool().isSupportedOption("--allow-script-in-comments") == 0) {
options.addBooleanOption("-allow-script-in-comments", true)
}
*/
}
repositories {
mavenCentral()
maven { url 'https://packages.atlassian.com/maven-3rdparty' }
maven { url 'https://repository.cloudera.com/artifactory/cloudera-repos' }
maven { url 'https://app.camunda.com/nexus/content/repositories/public' }
maven { url 'https://repo.spring.io/plugins-release' }
}
apply plugin: 'java'
apply plugin: 'maven-publish'
apply plugin: 'scalaStyle'
apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'idea'
apply plugin: "build-time-tracker"
apply plugin: 'org.owasp.dependencycheck'
group = 'io.snappydata'
version = '1.3.1'
// apply compiler options
tasks.withType(JavaCompile) {
options.encoding = 'UTF-8'
options.incremental = true
options.compilerArgs << '-Xlint:-serial,-path,-deprecation,-unchecked,-rawtypes'
options.compilerArgs << '-XDignore.symbol.file'
options.fork = true
options.forkOptions.javaHome = file(System.properties['java.home'])
options.forkOptions.jvmArgs = [ '-J-Xmx2g', '-J-Xms2g', '-J-XX:ReservedCodeCacheSize=512m', '-J-Djava.net.preferIPv4Stack=true' ]
}
tasks.withType(ScalaCompile) {
options.fork = true
options.forkOptions.jvmArgs = [ '-Xmx2g', '-Xms2g', '-XX:ReservedCodeCacheSize=512m', '-Djava.net.preferIPv4Stack=true' ]
// scalaCompileOptions.optimize = true
// scalaCompileOptions.useAnt = false
scalaCompileOptions.deprecation = false
scalaCompileOptions.additionalParameters = [ '-feature' ]
options.encoding = 'UTF-8'
}
jar.duplicatesStrategy = DuplicatesStrategy.EXCLUDE
javadoc.options.charSet = 'UTF-8'
ext {
productName = 'SnappyData'
vendorName = 'TIBCO Software Inc.'
scalaBinaryVersion = '2.11'
scalaVersion = scalaBinaryVersion + '.8'
sparkVersion = '2.1.3'
snappySparkVersion = '2.1.3.2'
sparkDistName = "spark-${sparkVersion}-bin-hadoop2.7"
sparkCurrentVersion = '2.4.8'
sparkCurrentDistName = "spark-${sparkCurrentVersion}-bin-hadoop2.7"
sparkJobServerVersion = '0.6.2.13'
snappySparkMetricsLibVersion = '2.0.0.1'
log4j2Version = '2.17.2'
slf4jVersion = '1.7.32'
junitVersion = '4.13.2'
mockitoVersion = '1.10.19'
hadoopVersion = '3.2.0'
awsSdkVersion = '1.11.375'
gcsHadoop3ConnectorVersion = 'hadoop3-2.1.2'
sparkAvroVersion = '4.0.0'
sparkXmlVersion = '0.4.1'
scalatestVersion = '2.2.6'
py4jVersion = '0.10.7'
jettyVersion = '9.4.43.v20210629'
guavaVersion = '14.0.1'
fastutilVersion = '8.5.6'
kryoVersion = '4.0.1'
thriftVersion = '0.9.3'
jacksonVersion = '2.13.3'
jacksonDatabindVersion = '2.13.3'
hiveVersion = '1.21.2.7.0.3.2-3'
metricsVersion = '4.0.3'
metrics2Version = '2.2.0'
janinoVersion = '3.0.8'
derbyVersion = '10.14.2.0'
parboiledVersion = '2.1.8'
tomcatJdbcVersion = '10.0.10'
hikariCPVersion = '2.7.9'
twitter4jVersion = '4.0.7'
objenesisVersion = '3.0.1'
rabbitMqVersion = '4.9.1'
akkaVersion = '2.3.16'
nettyAkkaVersion = '3.10.6.Final'
sprayVersion = '1.3.4'
sprayJsonVersion = '1.3.5'
sprayShapelessVersion = '1.3.3'
sprayTestkitVersion = '1.3.4'
jodaVersion = '2.1.2'
jodaTimeVersion = '2.10.1'
slickVersion = '2.1.0'
h2Version = '1.3.176'
commonsIoVersion = '2.11.0'
commonsPoolVersion = '1.6'
dbcpVersion = '1.4'
shiroVersion = '1.2.6'
flywayVersion = '3.2.1'
typesafeConfigVersion = '1.3.3'
mssqlVersion = '7.0.0.jre8'
antlr2Version = '2.7.7'
eclipseCollectionsVersion = '10.4.0'
pegdownVersion = '1.6.0'
snappyStoreVersion = '1.6.7'
snappydataVersion = version
zeppelinInterpreterVersion = '0.8.2.1'
buildFlags = ''
createdBy = System.getProperty('user.name')
osArch = System.getProperty('os.arch')
osName = org.gradle.internal.os.OperatingSystem.current()
osFamilyName = osName.getFamilyName().replace(' ', '').toLowerCase()
osVersion = System.getProperty('os.version')
buildDate = new Date().format('yyyy-MM-dd HH:mm:ss Z')
buildDateShort = ''
if (rootProject.hasProperty('withDate')) {
buildDateShort = "${new Date().format('yyyyMMdd')}_"
}
devEdition = ''
if (rootProject.hasProperty('dev')) {
devEdition = "-dev"
}
buildNumber = new Date().format('MMddyy')
jdkVersion = System.getProperty('java.version')
gitCmd = "git --git-dir=${rootDir}/.git --work-tree=${rootDir}"
gitBranch = "${gitCmd} rev-parse --abbrev-ref HEAD".execute().text.trim()
commitId = "${gitCmd} rev-parse HEAD".execute().text.trim()
sourceDate = "${gitCmd} log -n 1 --format=%ai".execute().text.trim()
buildIdPrefix = System.env.USER + ' '
sparkDistDir = "${project.gradle.gradleUserHomeDir}/sparkDist"
sparkProductDir = "${sparkDistDir}/${sparkDistName}"
sparkCurrentProductDir = "${sparkDistDir}/${sparkCurrentDistName}"
}
if (!buildRoot.isEmpty()) {
buildDir = new File(buildRoot, 'scala-' + scalaBinaryVersion + '/' + project.path.replace(':', '/'))
} else {
// default output directory suffix like in sbt/maven
buildDir = 'build-artifacts/scala-' + scalaBinaryVersion
}
if (rootProject.hasProperty('enablePublish')) {
buildIdPrefix = "${vendorName} "
}
if (rootProject.hasProperty('sparkDistDir')) {
sparkDistDir = rootProject.property('sparkDistDir')
sparkProductDir = "${sparkDistDir}/${sparkDistName}"
sparkCurrentProductDir = "${sparkDistDir}/${sparkCurrentDistName}"
}
ext {
testResultsBase = "${rootProject.buildDir}/tests/snappy"
snappyProductDir = "${rootProject.buildDir}/snappy"
}
// force same output directory for IDEA and gradle
idea {
module {
def projOutDir = file("${projectDir}/src/main/scala").exists()
? "${project.sourceSets.main.java.outputDir}/../../scala/main"
: project.sourceSets.main.java.outputDir
def projTestOutDir = file("${projectDir}/src/test/scala").exists()
? "${project.sourceSets.test.java.outputDir}/../../scala/test"
: project.sourceSets.test.java.outputDir
outputDir file(projOutDir)
testOutputDir file(projTestOutDir)
}
}
}
def hasAqpProject = new File(rootDir, 'aqp/build.gradle').exists()
def aqpProject = project(":snappy-aqp_${scalaBinaryVersion}")
def hasJdbcConnectorProject = new File(rootDir, 'snappy-connectors/jdbc-stream-connector/build.gradle').exists()
def hasGemFireConnectorProject = new File(rootDir, 'snappy-connectors/gemfire-connector/build.gradle').exists()
if (!hasAqpProject) {
throw new GradleException('Project repository snappy-aqp not found under aqp/.')
}
if (!hasJdbcConnectorProject) {
throw new GradleException('Project JDBC Stream Connector inside repository snappy-connectors not found.')
}
// set python2 for pyspark if python3 version is an unsupported one
String sparkPython = 'python'
def checkResult = exec {
ignoreExitValue = true
commandLine 'sh', '-c', 'python --version 2>/dev/null | grep -Eq "( 3\\.[0-7])|( 2\\.)"'
}
if (checkResult.exitValue != 0) {
checkResult = exec {
ignoreExitValue = true
commandLine 'sh', '-c', 'python2 --version >/dev/null 2>&1'
}
if (checkResult.exitValue == 0) {
sparkPython = 'python2'
}
}
static def getProcessId() {
String name = java.lang.management.ManagementFactory.getRuntimeMXBean().getName()
return name[0..name.indexOf('@') - 1]
}
static def getStackTrace(def t) {
java.io.StringWriter sw = new java.io.StringWriter()
java.io.PrintWriter pw = new java.io.PrintWriter(sw)
org.codehaus.groovy.runtime.StackTraceUtils.sanitize(t).printStackTrace(pw)
return sw.toString()
}
// Skip snappy-spark and spark-jobserver that have their own
// scalaStyle configuration. Skip snappy-store that will not use it.
configure(subprojects.findAll {!(it.name ==~ /snappy-spark.*/ ||
it.name ==~ /snappy-store.*/ ||
it.name ==~ /spark-jobserver.*/)}) {
scalaStyle {
configLocation = "${rootProject.projectDir}/scalastyle-config.xml"
inputEncoding = 'UTF-8'
outputEncoding = 'UTF-8'
outputFile = "${buildDir}/scalastyle-output.xml"
includeTestSourceDirectory = true
source = 'src/main/scala'
testSource = 'src/test/scala'
failOnViolation = true
failOnWarning = false
}
}
def cleanIntermediateFiles(String projectName) {
def projDir = "${project(projectName).projectDir}"
delete "${projDir}/metastore_db"
delete "${projDir}/warehouse"
delete "${projDir}/datadictionary"
delete fileTree(projDir) {
include 'BACKUPGFXD-DEFAULT-DISKSTORE**', 'locator*.dat'
}
}
static def now() {
return new Date().format('yyyy-MM-dd HH:mm:ss.SSS Z')
}
task cleanScalaTest { doLast {
String workingDir = "${testResultsBase}/scalatest"
delete workingDir
file(workingDir).mkdirs()
} }
task cleanJUnit { doLast {
String workingDir = "${testResultsBase}/junit"
delete workingDir
file(workingDir).mkdirs()
} }
task cleanRecoveryTest { doLast {
String workingDir = "${testResultsBase}/recoveryTest"
delete workingDir
file(workingDir).mkdirs()
} }
task cleanDUnit { doLast {
String workingDir = "${testResultsBase}/dunit"
delete workingDir
file(workingDir).mkdirs()
// clean spark cluster directories
delete "${snappyProductDir}/work", "${snappyProductDir}/logs"
delete "${sparkProductDir}/work", "${sparkProductDir}/logs"
delete "${sparkCurrentProductDir}/work", "${sparkCurrentProductDir}/logs"
} }
task cleanSecurityDUnit { doLast {
String workingDir = "${testResultsBase}/dunit-security"
delete workingDir
file(workingDir).mkdirs()
// clean spark cluster directories
delete "${snappyProductDir}/work", "${snappyProductDir}/logs"
delete "${sparkProductDir}/work", "${sparkProductDir}/logs"
delete "${sparkCurrentProductDir}/work", "${sparkCurrentProductDir}/logs"
} }
task cleanAllReports { doLast {
String workingDir = "${testResultsBase}/combined-reports"
delete workingDir
file(workingDir).mkdirs()
} }
task cleanQuickstart { doLast {
String workingDir = "${testResultsBase}/quickstart"
delete workingDir
file(workingDir).mkdirs()
} }
subprojects {
int maxWorkers = project.hasProperty('org.gradle.workers.max') ?
project.property('org.gradle.workers.max') as int :
Runtime.getRuntime().availableProcessors()
// the run task for a selected sub-project
task run(type: JavaExec) {
if (!project.hasProperty('mainClass')) {
main = 'io.snappydata.app.SparkSQLTest'
} else {
main = mainClass
}
if (project.hasProperty('params')) {
args = params.split(',') as List
}
classpath = sourceSets.main.runtimeClasspath + sourceSets.test.runtimeClasspath
jvmArgs '-Xmx2g', '-Xms2g'
}
task scalaTest(type: Test) {
actions = [ new com.github.maiflai.ScalaTestAction() ]
// top-level default is single process run since scalatest does not
// spawn separate JVMs
maxParallelForks = 1
minHeapSize '4g'
maxHeapSize '4g'
jvmArgs '-ea', '-XX:+HeapDumpOnOutOfMemoryError','-XX:+UseConcMarkSweepGC', '-XX:MaxNewSize=1g',
'-XX:+UseParNewGC', '-XX:+CMSClassUnloadingEnabled', '-Xss4m', '-XX:ReservedCodeCacheSize=1g'
// for benchmarking
// minHeapSize '12g'
// maxHeapSize '12g'
// jvmArgs '-XX:+HeapDumpOnOutOfMemoryError','-XX:+UseConcMarkSweepGC', '-XX:MaxNewSize=2g',
// '-XX:+UseParNewGC', '-XX:+CMSClassUnloadingEnabled', '-Xss4m', '-XX:ReservedCodeCacheSize=1g'
testLogging.exceptionFormat = TestExceptionFormat.FULL
testLogging.events = TestLogEvent.values() as Set
extensions.add(com.github.maiflai.ScalaTestAction.TAGS, new org.gradle.api.tasks.util.PatternSet())
List<String> suites = []
extensions.add(com.github.maiflai.ScalaTestAction.SUITES, suites)
extensions.add('suite', { String name -> suites.add(name) } )
extensions.add('suites', { String... name -> suites.addAll(name) } )
def result = new StringBuilder()
extensions.add(com.github.maiflai.ScalaTestAction.TESTRESULT, result)
extensions.add('testResult', { String name -> result.setLength(0); result.append(name) } )
def output = new StringBuilder()
extensions.add(com.github.maiflai.ScalaTestAction.TESTOUTPUT, output)
extensions.add('testOutput', { String name -> output.setLength(0); output.append(name) })
def errorOutput = new StringBuilder()
extensions.add(com.github.maiflai.ScalaTestAction.TESTERROR, errorOutput)
extensions.add('testError', { String name -> errorOutput.setLength(0); errorOutput.append(name) })
// running a single scala suite
if (rootProject.hasProperty('singleSuite')) {
suite singleSuite
}
workingDir = "${testResultsBase}/scalatest"
// testResult '/dev/tty'
testOutput "${workingDir}/output.txt"
testError "${workingDir}/error.txt"
binResultsDir = file("${workingDir}/binary/${project.name}")
reports.html.destination = file("${workingDir}/html/${project.name}")
reports.junitXml.destination = file(workingDir)
}
test {
maxParallelForks = maxWorkers
maxHeapSize '2g'
jvmArgs '-ea', '-XX:+HeapDumpOnOutOfMemoryError','-XX:+UseConcMarkSweepGC',
'-XX:+UseParNewGC', '-XX:+CMSClassUnloadingEnabled'
testLogging.exceptionFormat = TestExceptionFormat.FULL
def single = System.getProperty('junit.single')
if (single == null || single.length() == 0) {
single = rootProject.hasProperty('junit.single') ?
rootProject.property('junit.single') : null
}
if (single == null || single.length() == 0) {
include '**/*.class'
exclude '**/*TestBase.class'
exclude '**/*DUnit*.class'
} else {
include single
}
workingDir = "${testResultsBase}/junit"
binResultsDir = file("${workingDir}/binary/${project.name}")
reports.html.destination = file("${workingDir}/html/${project.name}")
reports.junitXml.destination = file(workingDir)
doFirst {
String eol = System.getProperty('line.separator')
String now = new Date().format('yyyy-MM-dd HH:mm:ss.SSS Z')
def progress = new File(workingDir, 'progress.txt')
progress << "${eol}${now} ========== STARTING JUNIT TEST SUITE FOR ${project.name} ==========${eol}${eol}"
}
}
task configureDUnitTest(dependsOn: testClasses) {
String dunitSingle = System.getProperty('dunit.single')
if (dunitSingle == null || dunitSingle.length() == 0) {
dunitSingle = rootProject.hasProperty('dunit.single') ?
rootProject.property('dunit.single') : null
}
doLast {
tasks.named('dunitTest').configure {
includes.clear()
excludes.clear()
if (dunitSingle == null || dunitSingle.length() == 0) {
def dunitTests = testClassesDirs.asFileTree.matching {
includes = [ '**/*DUnitTest.class', '**/*DUnit.class' ]
excludes = [
'**/*Suite.class', '**/*DUnitSecurityTest.class', '**/NCJ*DUnit.class', '**/*HDFS*DUnit*.class',
'**/BackwardCompatabilityPart*DUnit.class', '**/*Perf*DUnit.class', '**/ListAggDUnit.class',
'**/SingleHop*TransactionDUnit.class', '**/*Parallel*AsyncEvent*DUnit.class',
'**/pivotal/gemfirexd/wan/**/*DUnit.class', '**/*DUnitRecoveryTest.class',
'**/offheap/**/*DUnit*.class', '**/*OffHeap*DUnit*.class', '**/*Offheap*DUnit*.class'
]
}
FileTree includeTestFiles = dunitTests
int dunitFrom = rootProject.hasProperty('dunit.from') ?
getLast(includeTestFiles, rootProject.property('dunit.from')) : 0
int dunitTo = rootProject.hasProperty('dunit.to') ?
getLast(includeTestFiles, rootProject.property('dunit.to')) : includeTestFiles.size()
int begin = dunitFrom != -1 ? dunitFrom : 0
int end = dunitTo != -1 ? dunitTo : includeTestFiles.size()
def filteredSet = includeTestFiles.drop(begin).take(end-begin+1).collect {f -> "**/" + f.name}
if (begin != 0 || end != includeTestFiles.size()) {
println("Picking DUNIT tests for ${project.path}")
filteredSet.each { a -> println(a) }
}
include filteredSet
} else {
include dunitSingle
}
}
}
}
task dunitTest(type: Test) {
dependsOn ':cleanDUnit'
dependsOn ':product'
dependsOn ':copyShadowJars'
dependsOn configureDUnitTest
// maxParallelForks = Math.max(Math.sqrt(maxWorkers + 1) + 1 as int, 2)
maxParallelForks = 1
minHeapSize '1536m'
maxHeapSize '1536m'
// limit netty buffer arenas to avoid occasional OOMEs with 1.5g heap
int numArenas = Math.min(8, Runtime.getRuntime().availableProcessors())
jvmArgs = ['-XX:+HeapDumpOnOutOfMemoryError',
'-XX:+UseParNewGC', '-XX:+UseConcMarkSweepGC',
'-XX:CMSInitiatingOccupancyFraction=50',
'-XX:+CMSClassUnloadingEnabled', '-ea',
'-Dspark.sql.codegen.cacheSize=1000',
'-Dspark.ui.retainedStages=1000',
'-Dspark.ui.retainedJobs=1000',
'-Dspark.sql.ui.retainedExecutions=500',
'-Dio.netty.allocator.pageSize=8192',
'-Dio.netty.allocator.maxOrder=10',
"-Dio.netty.allocator.numHeapArenas=${numArenas}",
"-Dio.netty.allocator.numDirectArenas=${numArenas}"]
workingDir = "${testResultsBase}/dunit"
binResultsDir = file("${workingDir}/binary/${project.name}")
reports.html.destination = file("${workingDir}/html/${project.name}")
reports.junitXml.destination = file(workingDir)
systemProperties 'java.net.preferIPv4Stack': 'true',
'SNAPPY_HOME': snappyProductDir
int numTestClasses = 0
def testCount = new java.util.concurrent.atomic.AtomicInteger(0)
doFirst {
String eol = System.getProperty('line.separator')
String now = new Date().format('yyyy-MM-dd HH:mm:ss.SSS Z')
def progress = new File(workingDir, 'progress.txt')
numTestClasses = getCandidateClassFiles().getFiles().size()
progress << "${eol}${now} ========== STARTING DUNIT TEST SUITE FOR ${project.name} ==========${eol}${eol}"
}
beforeSuite { desc ->
if (desc.className != null) {
def count = testCount.incrementAndGet()
println "${now()} Start ${desc.className} ($count/$numTestClasses)"
}
}
afterSuite { desc, result ->
if (desc.className != null) {
println "${now()} END ${desc.className}"
}
}
}
task configureRecoveryTest(dependsOn: testClasses) {
String recoverySingle = System.getProperty('recovery.single')
if (recoverySingle == null || recoverySingle.length() == 0) {
recoverySingle = rootProject.hasProperty('recovery.single') ?
rootProject.property('recovery.single') : null
}
doLast {
tasks.named('recoveryTest').configure {
includes.clear()
excludes.clear()
if (recoverySingle == null || recoverySingle.length() == 0) {
def recoveryTests = testClassesDirs.asFileTree.matching {
includes = [ '**/*DUnitRecoveryTest.class' ]
excludes = [
'**/*Suite.class', '**/*DUnitSecurityTest.class', '**/NCJ*DUnit.class', '**/*HDFS*DUnit*.class',
'**/BackwardCompatabilityPart*DUnit.class', '**/*Perf*DUnit.class', '**/ListAggDUnit.class',
'**/SingleHop*TransactionDUnit.class', '**/*Parallel*AsyncEvent*DUnit.class',
'**/pivotal/gemfirexd/wan/**/*DUnit.class', '**/*DUnitTest.class', '**/*DUnit.class'
]
}
FileTree includeTestFiles = recoveryTests
include includeTestFiles.collect {f -> "**/" + f.name}
} else {
include recoverySingle
}
}
}
}
task recoveryTest(type: Test) {
dependsOn ':cleanRecoveryTest'
dependsOn ':product'
dependsOn ':copyShadowJars'
dependsOn configureRecoveryTest
maxParallelForks = 1
minHeapSize '4g'
maxHeapSize '4g'
// limit netty buffer arenas to avoid occasional OOMEs with 1.5g heap
int numArenas = Math.min(8, Runtime.getRuntime().availableProcessors())
jvmArgs = ['-XX:+HeapDumpOnOutOfMemoryError',
'-XX:+UseParNewGC', '-XX:+UseConcMarkSweepGC',
'-XX:CMSInitiatingOccupancyFraction=50',
'-XX:+CMSClassUnloadingEnabled', '-ea',
'-Dspark.sql.codegen.cacheSize=1000',
'-Dspark.ui.retainedStages=1000',
'-Dspark.ui.retainedJobs=1000',
'-Dspark.sql.ui.retainedExecutions=500',
'-Dio.netty.allocator.pageSize=8192',
'-Dio.netty.allocator.maxOrder=10',
"-Dio.netty.allocator.numHeapArenas=${numArenas}",
"-Dio.netty.allocator.numDirectArenas=${numArenas}"]
workingDir = "${testResultsBase}/recoveryTest"
systemProperties 'java.net.preferIPv4Stack': 'true',
'SNAPPY_HOME': snappyProductDir,
'RECOVERY_TEST_DIR': workingDir
binResultsDir = file("${workingDir}/binary/${project.name}")
reports.html.destination = file("${workingDir}/html/${project.name}")
reports.junitXml.destination = file(workingDir)
int numTestClasses = 0
def testCount = new java.util.concurrent.atomic.AtomicInteger(0)
doFirst {
String eol = System.getProperty('line.separator')
String now = new Date().format('yyyy-MM-dd HH:mm:ss.SSS Z')
def progress = new File(workingDir, 'progress.txt')
numTestClasses = getCandidateClassFiles().getFiles().size()
progress << "${eol}${now} ========== STARTING RECOVERY TEST SUITE FOR ${project.name} ==========${eol}${eol}"
}
beforeSuite { desc ->
if (desc.className != null) {
def count = testCount.incrementAndGet()
println "${now()} Start ${desc.className} ($count/$numTestClasses)"
}
}
afterSuite { desc, result ->
if (desc.className != null) {
println "${now()} END ${desc.className}"
}
}
}
task configureDUnitSecurityTest(dependsOn: testClasses) {
String dunitSecSingle = System.getProperty('dunitSecurity.single')
if (dunitSecSingle == null || dunitSecSingle.length() == 0) {
dunitSecSingle = rootProject.hasProperty('dunitSecurity.single') ?
rootProject.property('dunitSecurity.single') : null
}
doLast {
tasks.named('dunitSecurityTest').configure {
includes.clear()
excludes.clear()
if (dunitSecSingle == null || dunitSecSingle.length() == 0) {
def dunitSecurityTests = testClassesDirs.asFileTree.matching {
includes = [ '**/*DUnitSecurityTest.class' ]
excludes = [ '**/*Suite.class', '**/*DUnitTest.class', '**/*DUnit.class', '**/*DUnitRecoveryTest.class' ]
}
FileTree includeTestFiles = dunitSecurityTests
int dunitFrom = rootProject.hasProperty('dunitSecurity.from') ?
getLast(includeTestFiles, rootProject.property('dunitSecurity.from')) : 0
int dunitTo = rootProject.hasProperty('dunitSecurity.to') ?
getLast(includeTestFiles, rootProject.property('dunitSecurity.to')) : includeTestFiles.size()
int begin = dunitFrom != -1 ? dunitFrom : 0
int end = dunitTo != -1 ? dunitTo : includeTestFiles.size()
def filteredSet = includeTestFiles.drop(begin).take(end-begin+1).collect {f -> "**/" + f.name}
if (begin != 0 || end != includeTestFiles.size()) {
println("Picking SECURITY tests for ${project.path}")
filteredSet.each { a -> println(a) }
}
include filteredSet
} else {
include dunitSecSingle
}
}
}
}
task dunitSecurityTest(type: Test) {
dependsOn ':cleanSecurityDUnit'
dependsOn ':product'
dependsOn ':copyShadowJars'
dependsOn configureDUnitSecurityTest
maxParallelForks = 1
minHeapSize '1536m'
maxHeapSize '1536m'
// limit netty buffer arenas to avoid occasional OOMEs with 1.5g heap
int numArenas = Math.min(8, Runtime.getRuntime().availableProcessors())
jvmArgs = ['-XX:+HeapDumpOnOutOfMemoryError',
'-XX:+UseParNewGC', '-XX:+UseConcMarkSweepGC',
'-XX:CMSInitiatingOccupancyFraction=50',
'-XX:+CMSClassUnloadingEnabled', '-ea',
'-Dspark.sql.codegen.cacheSize=1000',
'-Dspark.ui.retainedStages=1000',
'-Dspark.ui.retainedJobs=1000',
'-Dspark.sql.ui.retainedExecutions=500',
'-Dio.netty.allocator.pageSize=8192',
'-Dio.netty.allocator.maxOrder=10',
"-Dio.netty.allocator.numHeapArenas=${numArenas}",
"-Dio.netty.allocator.numDirectArenas=${numArenas}"]
workingDir = "${testResultsBase}/dunit-security"
binResultsDir = file("${workingDir}/binary/${project.name}")
reports.html.destination = file("${workingDir}/html/${project.name}")
reports.junitXml.destination = file(workingDir)
systemProperties 'java.net.preferIPv4Stack': 'true',
'SNAPPY_HOME': snappyProductDir
doFirst {
String eol = System.getProperty('line.separator')
String now = new Date().format('yyyy-MM-dd HH:mm:ss.SSS Z')
def progress = new File(workingDir, 'progress.txt')
progress << "${eol}${now} ========== STARTING SECURITY DUNIT TEST SUITE FOR ${project.name} ==========${eol}${eol}"
}
}
// apply default manifest
if (rootProject.hasProperty('enablePublish')) {
createdBy = vendorName
}
jar {
manifest {
attributes(
'Manifest-Version' : '1.0',
'Created-By' : createdBy,
'Title' : rootProject.name,
'Version' : archiveVersion.get(),
'Vendor' : vendorName
)
}
}
configurations {
testOutput {
extendsFrom testCompile
description 'a dependency that exposes test artifacts'
}
shadowInclude {
description = 'a dependency that is included only in the shadow jar'
canBeResolved = true
canBeConsumed = false
}
/*
all {
resolutionStrategy {
// fail eagerly on version conflict (includes transitive dependencies)
// e.g. multiple different versions of the same dependency (group and name are equal)
failOnVersionConflict()
}
}
*/
}
// force versions for some dependencies that get pulled multiple times
configurations.all {
resolutionStrategy.force "com.google.guava:guava:${guavaVersion}",
"org.apache.derby:derby:${derbyVersion}",
"org.apache.hadoop:hadoop-annotations:${hadoopVersion}",
"org.apache.hadoop:hadoop-auth:${hadoopVersion}",
"org.apache.hadoop:hadoop-client:${hadoopVersion}",
"org.apache.hadoop:hadoop-common:${hadoopVersion}",
"org.apache.hadoop:hadoop-hdfs:${hadoopVersion}",
"org.apache.hadoop:hadoop-mapreduce-client-app:${hadoopVersion}",
"org.apache.hadoop:hadoop-mapreduce-client-common:${hadoopVersion}",
"org.apache.hadoop:hadoop-mapreduce-client-core:${hadoopVersion}",
"org.apache.hadoop:hadoop-mapreduce-client-jobclient:${hadoopVersion}",
"org.apache.hadoop:hadoop-mapreduce-client-shuffle:${hadoopVersion}",
"org.apache.hadoop:hadoop-yarn-api:${hadoopVersion}",
"org.apache.hadoop:hadoop-yarn-client:${hadoopVersion}",
"org.apache.hadoop:hadoop-yarn-common:${hadoopVersion}",
"org.apache.hadoop:hadoop-yarn-server-common:${hadoopVersion}",
"org.apache.hadoop:hadoop-yarn-server-nodemanager:${hadoopVersion}",
"org.apache.hadoop:hadoop-yarn-server-web-proxy:${hadoopVersion}"
exclude(group: 'org.mortbay.jetty', module: 'servlet-api')
}
def projectName = it.name
if (projectName != 'gemfire-shared') {
configurations.all {
if (projectName != 'snappy-core_' + scalaBinaryVersion ||
it.name == 'compileOnly') {
exclude(group: 'log4j', module: 'log4j')
exclude(group: 'log4j', module: 'apache-log4j-extras')
exclude(group: 'org.slf4j', module: 'slf4j-log4j12')
}
}
}
/*
configurations.testRuntime {
// below is included indirectly by hadoop deps and conflicts with embedded 1.5.7 apacheds
exclude(group: 'org.apache.directory.server', module: 'apacheds-kerberos-codec')
exclude(group: 'org.apache.directory.server', module: 'apacheds-i18n')
}
*/
task packageTests(type: Jar, dependsOn: testClasses) {
description 'Assembles a jar archive of test classes.'
archiveClassifier.set('tests')
}
artifacts {
testOutput packageTests
}
dependencies {
compile 'org.slf4j:slf4j-api:' + slf4jVersion
testCompile "junit:junit:${junitVersion}"
}
}
// maven publish tasks
subprojects {
apply plugin: 'signing'
task packageSources(type: Jar, dependsOn: classes) {
archiveClassifier.set('sources')
from sourceSets.main.allSource
}
task packageDocs(type: Jar, dependsOn: javadoc) {
archiveClassifier.set('javadoc')
from javadoc
}
ext {
publishArtifacts = [ jar, packageSources ]
}
pluginManager.withPlugin('scala') {
task packageScalaDocs(type: Jar, dependsOn: scaladoc) {
archiveClassifier.set('javadoc')
from scaladoc
}
publishArtifacts.add(packageScalaDocs)
}
if (rootProject.hasProperty('enablePublish')) {
publishing {
repositories {
maven {
def releasesRepoUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
def snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots/'
url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
name = 'SonatypeOSS'
credentials {
username = ossrhUsername
password = ossrhPassword
}
}
}
publications {
maven(MavenPublication) {
from components.java
afterEvaluate {
artifactId = jar.archiveBaseName.get()
artifacts = publishArtifacts
}
pom {
name = 'SnappyData'
packaging = 'jar'
// optionally artifactId can be defined here
description = 'SnappyData distributed data store and execution engine'
url = 'https://github.com/TIBCOSoftware/snappydata'
scm {
connection = 'scm:git:https://github.com/TIBCOSoftware/snappydata.git'
developerConnection = 'scm:git:https://github.com/TIBCOSoftware/snappydata.git'
url = 'https://github.com/TIBCOSoftware/snappydata'
}
licenses {
license {
name = 'The Apache License, Version 2.0'
url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
}
}
developers {
developer {
id = 'swale'
name = 'Sumedh Wale'
email = '[email protected]'
}
}
}
}
}
}
signing {
useGpgCmd()
sign publishing.publications.maven
}
}
}
// apply common test and misc configuration
gradle.taskGraph.whenReady { graph ->
def allTasks = subprojects.collect { it.tasks }.flatten()
allTasks.each { task ->
if (task instanceof Tar) {
def tar = (Tar)task
tar.compression = Compression.GZIP
tar.archiveExtension.set('tar.gz')
} else if (task instanceof Jar) {
def pack = (Jar)task
if (pack.name == 'packageTests') {
pack.from(pack.project.sourceSets.test.output.classesDirs, pack.project.sourceSets.test.resources.srcDirs)
}
} else if (task instanceof Test) {
def test = (Test)task
test.configure {
String logLevel = System.getProperty('logLevel')
if (logLevel != null && logLevel.length() > 0) {
systemProperties 'gemfire.log-level' : logLevel,
'logLevel' : logLevel
}
logLevel = System.getProperty('securityLogLevel')
if (logLevel != null && logLevel.length() > 0) {
systemProperties 'gemfire.security-log-level' : logLevel,
'securityLogLevel' : logLevel
}
systemProperties 'SNAPPY_HOME': snappyProductDir,
'APACHE_SPARK_HOME': sparkProductDir,
'APACHE_SPARK_CURRENT_HOME': sparkCurrentProductDir,
'gemfire.DUnitLauncher.CHILD_HEAPSIZE': '2g'
environment 'PYSPARK_PYTHON': sparkPython,
'PYSPARK_DRIVER_PYTHON': sparkPython,
'SPARK_TESTING': '1',
'SNAPPY_DIST_CLASSPATH': test.classpath.asPath
def failureCount = new java.util.concurrent.atomic.AtomicInteger(0)
def progress = new File(workingDir, 'progress.txt')
def output = new File(workingDir, 'output.txt')
String eol = System.getProperty('line.separator')
beforeTest { desc ->
String now = now()
progress << "${now} Starting test ${desc.className} ${desc.name}${eol}"
output << "${now} STARTING TEST ${desc.className} ${desc.name}${eol}${eol}"
}
onOutput { desc, event ->
String msg = event.message
if (event.destination.toString() == 'StdErr') {
msg = msg.replace(eol, "${eol}[error] ")
}
output << msg
}
afterTest { desc, result ->
String now = now()
progress << "${now} Completed test ${desc.className} ${desc.name} with result: ${result.resultType}${eol}"
output << "${eol}${now} COMPLETED TEST ${desc.className} ${desc.name} with result: ${result.resultType}${eol}${eol}"
def exceptions = result.exceptions
if (exceptions.size() > 0) {
exceptions.each { t ->
progress << " EXCEPTION: ${getStackTrace(t)}${eol}"
output << "${getStackTrace(t)}${eol}"
}
failureCount.incrementAndGet()
}
}
doLast {
def report = "${test.reports.html.destination}/index.html"
boolean hasProgress = progress.exists()
if (failureCount.get() > 0) {
println()
def failureMsg = "FAILED: There were ${failureCount.get()} failures.${eol}"
if (hasProgress) {
failureMsg += " See the progress report in: file://$progress${eol}"
}
failureMsg += " HTML report in: file://$report"
throw new GradleException(failureMsg)
} else if (hasProgress) {
println()
println("SUCCESS: See the progress report in: file://$progress")
println(" HTML report in: file://$report")
println()
} else {
println()
println("SUCCESS: See the HTML report in: file://$report")
println()
}
}
}
}
}
}
Set<String> skipPublishFor = [
'snappydata_' + scalaBinaryVersion, 'snappy-spark', 'snappy-store',
'snappy-dtests_' + scalaBinaryVersion, 'snappy-compatibility-tests_' + scalaBinaryVersion,
'gemfire-junit', 'gemfire-tests', 'snappydata-store-tests', 'snappydata-native',
'snappydata-store-prebuild', 'snappy-spark-assembly_' + scalaBinaryVersion
]
task publishLocal() {
dependsOn getTasksByName('publishToMavenLocal', true).findAll {
!skipPublishFor.contains(it.project.name) }