iam.tf

# Policy
data "aws_iam_policy_document" "kubernetes_external_secrets" {
  count = var.enabled ? 1 : 0

  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds"
    ]
    resources = [
      "*",
    ]
    effect = "Allow"
  }

  statement {
    actions = [
      "ssm:GetParameter"
    ]
    resources = [
      "*",
    ]
    effect = "Allow"
  }

}

resource "aws_iam_policy" "kubernetes_external_secrets" {
  depends_on  = [var.mod_dependency]
  count       = var.enabled ? 1 : 0
  name        = "${var.cluster_name}-external-secrets"
  path        = "/"
  description = "Policy for external secrets service"

  policy = data.aws_iam_policy_document.kubernetes_external_secrets[0].json
}

# Role
data "aws_iam_policy_document" "kubernetes_external_secrets_assume" {
  count = var.enabled ? 1 : 0

  statement {
    actions = ["sts:AssumeRoleWithWebIdentity"]

    principals {
      type        = "Federated"
      identifiers = [var.cluster_identity_oidc_issuer_arn]
    }

    condition {
      test     = "StringEquals"
      variable = "${replace(var.cluster_identity_oidc_issuer, "https://", "")}:sub"

      values = [
        "system:serviceaccount:${var.namespace}:${var.service_account_name}",
      ]
    }

    effect = "Allow"
  }
}

resource "aws_iam_role" "kubernetes_external_secrets" {
  count              = var.enabled ? 1 : 0
  name               = "${var.cluster_name}-external-secrets"
  assume_role_policy = data.aws_iam_policy_document.kubernetes_external_secrets_assume[0].json
}

resource "aws_iam_role_policy_attachment" "kubernetes_external_secrets" {
  count      = var.enabled ? 1 : 0
  role       = aws_iam_role.kubernetes_external_secrets[0].name
  policy_arn = aws_iam_policy.kubernetes_external_secrets[0].arn
}