build.gradle

    plugins {
    // Apply the Java Gradle plugin development plugin to add support for developing Gradle plugins
    id 'java-gradle-plugin'

    // Apply the Groovy plugin to add support for Groovy
    id 'groovy'
    id 'ivy-publish'
}

version = '0.2-SNAPSHOT'
group = "br.net.carloseugenio.gradle"

repositories {
    jcenter()
}

dependencies {
    compile 'io.github.http-builder-ng:http-builder-ng-core:1.0.4'
    // Use the awesome Spock testing and specification framework
    testImplementation 'org.spockframework:spock-core:1.2-groovy-2.5'
    testImplementation 'org.mock-server:mockserver-netty:5.6.1'
}

gradlePlugin {
    // Define the plugin
    plugins {
        tomcat {
            id = 'br.net.carloseugenio.gradle.tomcat'
            implementationClass = 'br.net.carloseugenio.gradle.tomcat.GradleTomcatPlugin'
        }
    }
}

// Add a source set for the functional test suite
sourceSets {
    functionalTest {
    }
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
    archiveClassifier = 'sources'
}



gradlePlugin.testSourceSets(sourceSets.functionalTest)
configurations.functionalTestImplementation.extendsFrom(configurations.testImplementation)

// Add a task to run the functional tests
task functionalTest(type: Test) {
    testClassesDirs = sourceSets.functionalTest.output.classesDirs
    classpath = sourceSets.functionalTest.runtimeClasspath
}

check {
    // Run the functional tests as part of `check`
    dependsOn(tasks.functionalTest)
}

publishing {
    repositories {
        ivy {
            name "IvyPublicationRepo"
            url "file://opt/ivyRep"
            layout "maven"
        }
    }
}