CONTEN.TEC

!TABLE OF CONTENTS GENERATOR %2:!
[1[2[3[L[S[M[T[P[N[F
 "?" FOR HELP
!ST!HKI:ER

FILE: 
 .U3 !NXCHR! UT  QT-^O10"E .-Q3"N -D' ONXCHR' QT-63"E

TYPE THE FILESPEC OF THE (MACRO) PROGRAM FOR WHICH YOU WANT THE TABLE
OF CONTENTS.  DEFAULT EXTN IS .MAC.  END WITH <CR>.
OST
' QT-^O177"E.-1,.T:-DONXCHR'QT-^O25"E
^U
OST'
QT-^O15"NQTIONXCHR'IJ:S."FZ-1JI.MAC'
HXTMT"F
NOT FOUND.
OST'
!ST2!HKI;Table of Contents for 
NAME: 

.U3 !NXC! UT  QT-^O10"E .-Q3"N -D' ONXC' QT-63"E

TYPE THE NAME TO BE INCLUDED IN THE "TABLE OF CONTENTS FOR <NAME>" HEAD-
ING, WHICH IS INCLUDED IN THE TABLE (PROBABLY THE PROGRAM NAME).
END WITH <CR>.

OST2'QT-^O177"E.-1,.T:-DONXC'QT-^O25"E
^U

OST2'
QT-^O15"NQTIONXC' .U1 (66-.)/2U2 BJ C Q2<i > Q1+Q2J I
;
;
;			   Section			      Page
;
!FIRST!-1UN
FIRST? 
UT QT-^^Z"G QT-^o40UT'
QT-^O15"ENUT'QT-N"NQT-Y"N

TYPE "Y" IF YOU WANT TO INCLUDE THE FIRST SUBTTL IN THE TABLE, "N" IF
NOT (E.G. IF IT'S THE AUTHOR'S NAME).  NO <CR>.

OFIRST'%N'

[WAIT]

1UPHXCY!RESTART!"EA"EORESTART''
!NEWPG!0UF:SSUBTTL"FONXTPG'QN"L%NONEWPG'
!AGAIN!C1A-^O15"N1A-^O12"N1A-^O11"N1A-^O40"N !NOW COPY THE LINE!
0,.KL.,ZKJ:S -- "S!DS!1A-^O40"EDODS'5R!DS2!1A-^O40"EDRODS2'5C
QM"G HXF XL4R.,ZKI
ZUT GS Z-(2*QT)"E QTJI:B,QT\IS
! make sure string is not too long!(Z-.-36)"G(z-.-36)D'
 ZJI
QTJ.,ZXT MT"S OSAME''
HKGFJ:S -- "F
OOPS...
'' 0UM  XL4RKI
-XSHKI; 0UTQN-8"G%TQN-98"G%TQN-998"G%TQN-9998"G%T''''
4-QT<I >%N\I. GS JGCHXC  !SAME! HKI;
0UTQN-9"G%TQN-99"G%TQN-999"G%TQN-9999"G%T''''9-QT<I >QN\I.%M\
0UTQM-9"G%TQM-99"G%TQM-999"G%T'''3-QT<I >OCONT '0UM
XLHKI;0UTQN-8"G%TQN-98"G%TQN-998"G%TQN-9998"G%T''''
!T ==> #DIGITS-1! 4-QT<I >%N\I. !CONT!GL-2DJ:S	"SRK'ZJ
Z-60"G60J.,ZK'I 62-Z<I.>!NOW INSERT PAGE#!
0UTQP-9"G%TQP-99"G%TQP-999"G%T'''3-QT<I >QP\I
 !NOW CONCATENATE TO TEXT ALREADY IN C!
1UFJGCHXC''
!AT THIS POINT, WE EITHER PROCESSED LINE, OR FOUND TAB OR SPACE ABOVE!
QF"EOAGAIN'''!OK, NOW WE CAN PROCESS NEXT LINE!
!NXTPG!"EY!GETFF!"EA"EOGETFF''%P
!NOW WE CAN PROCESS THIS PAGE.! ONEWPG'
!AT THIS POINT, WE ARE DONE.!1et
[CONTENTS ARE IN Q-REG C]

0etHKEF]F]N]P]T]M]S]2]1]L