build.gradle.kts

plugins {
    // this is necessary to avoid the plugins to be loaded multiple times
    // in each subproject's classloader
    alias(libs.plugins.androidApplication) apply false
    alias(libs.plugins.androidLibrary) apply false
    alias(libs.plugins.composeMultiplatform) apply false
    alias(libs.plugins.composeCompiler) apply false
    alias(libs.plugins.kotlinJvm) apply false
    alias(libs.plugins.kotlinMultiplatform) apply false
    alias(libs.plugins.kotlinSerialization) apply false
    alias(libs.plugins.googleKsp) apply false
    alias(libs.plugins.buildKonfig) apply false
    alias(libs.plugins.spotless)
}

subprojects {
    apply(plugin = "com.diffplug.spotless")
    spotless {
        kotlin {
            ktlint("1.4.1")
                .setEditorConfigPath(rootProject.file(".editorconfig"))
            target("**/*.kt")
            targetExclude("**/build/")
            endWithNewline()
            trimTrailingWhitespace()
        }
        format("kts") {
            target("**/*.kts")
            targetExclude("${layout.buildDirectory.get()}/**/*.kts")
        }
        format("misc") {
            target("**/*.md", "**/.gitignore")
            trimTrailingWhitespace()
            indentWithTabs()
            endWithNewline()
        }
    }
}

tasks.register<Copy>("setUpGitHooks") {
    group = "help"
    from("$rootDir/scripts")
    into("$rootDir/.git/hooks")
    filePermissions {
        user {
            read = true
            execute = true
        }
        other.execute = false
    }
}