build.gradle

apply plugin: 'application'
apply plugin: 'idea'
apply plugin: 'java'

def getVersionName = { ->
  def stdout = new ByteArrayOutputStream()
  exec {
    commandLine 'git', 'describe', '--dirty'
    standardOutput = stdout
  }
  return stdout.toString().trim()
}

compileJava.options.encoding = 'UTF-8'
mainClassName = 'gamer.App'
sourceCompatibility = '1.8'
version = getVersionName()

repositories {
  mavenCentral()
}

dependencies {
  compile 'commons-cli:commons-cli:1.4+'
  compile 'com.google.code.gson:gson:2.8+'
  testCompile group: 'junit', name: 'junit', version: '4.12+'
  testCompile group: 'org.hamcrest', name: 'hamcrest-all', version: '1.3+'
}

gradle.projectsEvaluated {
  tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:all"
  }
}

jar {
  manifest {
    attributes 'Main-Class': mainClassName
    attributes 'Implementation-Version': version
  }
}

// Create a single jar with all dependencies.
task fatjar(type: Jar) {
  baseName = project.name + '-all'
  doFirst {
    manifest {
      attributes 'Main-Class': mainClassName
      attributes 'Implementation-Version': version
    }
  }
  from {
    configurations.compile.collect {
      it.isDirectory() ? it : zipTree(it)
    }
  }
  with jar
}

run {
  if (project.hasProperty('args'))  {
    args project.args.split('\\s')
  }
  jvmArgs = ['-Dfile.encoding=utf8']
}

test {
  testLogging.showStandardStreams = false
  //// Uncomment if a test hangs.
  // beforeTest {
  //   descriptor -> logger.lifecycle("Running test: " + descriptor)
  // }
}