build.gradle

plugins {
    id "java"
    id "org.springframework.boot" version "2.1.5.RELEASE"
    id "io.spring.dependency-management" version "1.0.7.RELEASE"
}

group "com.dnastack.discovery.registry"

sourceCompatibility = 11
targetCompatibility = 11

tasks.withType(JavaCompile) {
    configure(options) {
        options.compilerArgs << "-parameters"
    }
}

repositories {
    mavenCentral()
}

ext {
    injectVersion = "1"
    lombokVersion = "1.18.8"
    restAssuredVersion = "4.0.0"
    jdbiVersion = "3.10.1"
}

springBoot {
    buildInfo()
}

dependencies {
    compile "org.springframework.boot:spring-boot-starter"
    compile "org.springframework.boot:spring-boot-starter-web"
    compile "org.springframework.boot:spring-boot-starter-actuator"
    compile 'org.springframework.boot:spring-boot-starter-jdbc'
    compile "org.springframework.boot:spring-boot-starter-json"
    compile "org.springframework.boot:spring-boot-starter-security"
    compile "javax.inject:javax.inject:${injectVersion}"
    compile "org.jdbi:jdbi3-core:${jdbiVersion}"
    compile "org.jdbi:jdbi3-sqlobject:${jdbiVersion}"
    compile "org.jdbi:jdbi3-jackson2:${jdbiVersion}"

    compileOnly "org.projectlombok:lombok:${lombokVersion}"
    annotationProcessor "org.projectlombok:lombok:${lombokVersion}"

    compile "org.postgresql:postgresql"

    testCompile "org.springframework.boot:spring-boot-starter-test"
    testCompile "org.springframework.security:spring-security-test"
    testCompile "com.h2database:h2"
    testCompile "io.rest-assured:rest-assured:${restAssuredVersion}"
    testCompile "io.rest-assured:json-path:${restAssuredVersion}"
    testCompile "io.rest-assured:xml-path:${restAssuredVersion}"
}

test {
    useJUnit {
        exclude "**/*IT.class"
    }
}

task unitTest(type: Test, description: "Runs the unit tests.", group: "Verification") {
    useJUnit {
        include "**/*Test.class"
    }
}

task integrationTest(type: Test, description: "Runs the integration tests", group: "Verification") {
    useJUnit {
        include "**/*IT.class"
    }
    ignoreFailures true
}