build.gradle

plugins {
    id 'java'
    id 'maven-publish'
}

group = 'io.github.hedgehog1029'
version = '1.5.0'

description = "A plugin framework for Spigot/Bukkit."

sourceCompatibility = 1.8
targetCompatibility = 1.8

java {
    withSourcesJar()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'frame'

            from components.java

            pom {
                name = 'Frame'
                description = project.description

                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://spdx.org/licenses/MIT.html'
                    }
                }

                developers {
                    developer {
                        id = 'obw'
                        name = 'offbeatwitch'
                        email = 'obw@generalprogramming.org'
                    }
                }

                scm {
                    connection = 'scm:git:git://github.com/hedgehog1029/Frame.git'
                    url = 'https://github.com/hedgehog1029/Frame'
                }
            }
        }
    }

    repositories {
        maven {
            def releasesUrl = 'https://maven.offbeatwit.ch/repository/releases/'
            def snapshotsUrl = 'https://maven.offbeatwit.ch/repository/snapshots/'

            url = version.endsWith('SNAPSHOT') ? snapshotsUrl : releasesUrl

            credentials(PasswordCredentials) {
                username = project.property('archiva.user')
                password = project.property('archiva.password')
            }
        }
    }
}