How to build and install custom plugins on NixOS

[djelenc]

According to the Wiki, plugins in NixOS can be built using a dedicated nix function hyprlandPlugins.mkHyprlandPlugin. Wiki provides an example, which I list below.

{pkgs, ...}: {
  hy3 = pkgs.callPackage ({
    lib,
    fetchFromGitHub,
    cmake,
    hyprland,
    hyprlandPlugins,
  }:
    hyprlandPlugins.mkHyprlandPlugin pkgs.hyprland {
      pluginName = "hy3";
      version = "0.39.1";

      src = fetchFromGitHub {
        owner = "outfoxxed";
        repo = "hy3";
        rev = "hl0.39.1";
        hash = "sha256-PqVld+oFziSt7VZTNBomPyboaMEAIkerPQFwNJL/Wjw=";
      };

      # any nativeBuildInputs required for the plugin
      nativeBuildInputs = [cmake];

      # set any buildInputs that are not already included in Hyprland
      # by default, Hyprland and its dependencies are included
      buildInputs = [];

      meta = {
        homepage = "https://github.com/outfoxxed/hy3";
        description = "Hyprland plugin for an i3 / sway like manual tiling layout";
        license = lib.licenses.gpl3;
        platforms = lib.platforms.linux;
        maintainers = with lib.maintainers; [aacebedo];
      };
    });
}

However, the wiki does not state where to put this code. Do I create a custom package and then import it into the list of plugins? Does anyone have an example?

(I'm just using hy3 as an example, but the custom plugin will be some other. )

[fufexan]

You can have for example

{pkgs, ...}: {
  wayland.windowManager.hyprland.plugins = [
    (pkgs.callPackage ({
      lib,
      fetchFromGitHub,
      cmake,
      hyprland,
      hyprlandPlugins,
    }:
      hyprlandPlugins.mkHyprlandPlugin pkgs.hyprland {
        pluginName = "hy3";
        version = "0.39.1";

        src = fetchFromGitHub {
          owner = "outfoxxed";
          repo = "hy3";
          rev = "hl0.39.1";
          hash = "sha256-PqVld+oFziSt7VZTNBomPyboaMEAIkerPQFwNJL/Wjw=";
        };

        # any nativeBuildInputs required for the plugin
        nativeBuildInputs = [cmake];

        # set any buildInputs that are not already included in Hyprland
        # by default, Hyprland and its dependencies are included
        buildInputs = [];

        meta = {
          homepage = "https://github.com/outfoxxed/hy3";
          description = "Hyprland plugin for an i3 / sway like manual tiling layout";
          license = lib.licenses.gpl3;
          platforms = lib.platforms.linux;
          maintainers = with lib.maintainers; [aacebedo];
        };
      }) {})
  ];
}

[djelenc]

Thank you, it works!