build.gradle

plugins {
    id 'org.springframework.boot' version '3.2.2'
    id 'io.spring.dependency-management' version '1.1.6'
    id 'java'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '17'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.flywaydb:flyway-core'
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'org.postgresql:postgresql'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

tasks.named('test') {
    useJUnitPlatform()
}

tasks.register('installFrontend', Exec) {
    inputs.file("frontend/yarn.lock")
    inputs.file("frontend/package.json")
    outputs.dir("frontend/node_modules")

    workingDir "frontend"
    executable "yarn"
    args "install", "--update-checksums"
}

tasks.register('buildFrontend', Exec) {
    dependsOn installFrontend
    inputs.files(file("frontend").listFiles({file -> file.name != "build"} as FileFilter))
    outputs.dir("frontend/build")

    workingDir "frontend"
    executable "yarn"
    args "build"
}

tasks.register('copyFrontend', Copy) {
    from buildFrontend.outputs
    into "$buildDir/resources/main/static"
    doLast {
        println "copied frontend artifacts to $buildDir/resources/main/static"
    }
}

bootRun {
    dependsOn(copyFrontend)
}