build.gradle

/*
 * Copyright (C) 2018-2019 Evan Hedbor.
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

import org.apache.tools.ant.filters.ReplaceTokens

plugins {
    id 'idea'
    id 'org.jetbrains.kotlin.jvm' version '1.3.11'
    id 'org.jetbrains.kotlin.kapt' version '1.3.11'
    id 'com.github.johnrengelman.shadow' version '2.0.4'
}

allprojects {
    group 'org.hedbor.evan'
    version '2.3.1'
}

repositories {
    mavenCentral()
    maven {
        url 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'
    }
    maven {
        url 'https://oss.sonatype.org/content/repositories/snapshots/'
    }
}

sourceSets {
    main {
        java {
            srcDir "${buildDir.absolutePath}/tmp/kapt/main/kotlinGenerated/"
        }
    }
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.3.11"
    compileOnly 'org.spigotmc:spigot-api:1.13.2-R0.1-SNAPSHOT'
    compileOnly project(":generator")
    kapt project(":generator")

    testCompile 'org.jetbrains.kotlin:kotlin-test:1.3.11'
}

jar {
    archiveName = "CrunchCommands-${project.version}-nodeps.jar"
    doFirst {
        filesMatching("**/plugin.yml") {
            filter(ReplaceTokens, tokens: ["VERSION": project.version.toString()])
        }
    }
}

shadowJar {
    archiveName = "CrunchCommands-${project.version}.jar"
    doFirst {
        filesMatching("**/plugin.yml") {
            filter(ReplaceTokens, tokens: ["VERSION": project.version.toString()])
        }
    }
}

task copyJar(type: Copy) {
    from shadowJar.outputs.files
    into "test-server/plugins"
}

idea {
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}