flake.nix

{
  description = "Home Manager configuration";

  inputs = {
    nix.url = "https://flakehub.com/f/DeterminateSystems/nix/2.0";

    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";

    nix-darwin.url = "github:LnL7/nix-darwin/master";
    nix-darwin.inputs.nixpkgs.follows = "nixpkgs";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    devenv.url = "github:cachix/devenv/main";

    sops-nix.url = "github:Mic92/sops-nix";

    mac-app-util.url = "github:hraban/mac-app-util";
  };

  outputs =
    { self
    , nix
    , nixpkgs
    , nix-darwin
    , home-manager
    , devenv
    , sops-nix
    , ...
    }:
    let
      supportedSystems = [ "x86_64-linux" "aarch64-darwin" ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
      extraArgs = {
        inherit sops-nix;
        flake = self;
      };
    in
    {
      defaultPackage.x86_64-linux = home-manager.defaultPackage.x86_64-linux;
      defaultPackage.aarch64-darwin = home-manager.defaultPackage.aarch64-darwin;
      defaultPackage.x86_64-darwin = home-manager.defaultPackage.x86_64-darwin;

      darwinConfigurations = {
        phobos = nix-darwin.lib.darwinSystem {
          specialArgs = extraArgs // {
            remapKeys = false;
          };
          system = "aarch64-darwin";
          modules = [
            ./systems/phobos
            home-manager.darwinModules.default
            {
              home-manager.useGlobalPkgs = true;
              home-manager.useUserPackages = true;
              home-manager.extraSpecialArgs = extraArgs;
            }
            nix.darwinModules.default
          ];
        };
      };

      homeConfigurations = {
        # VM running Arch Linux
        "kevin@archlinux-vm" = home-manager.lib.homeManagerConfiguration {
          modules = [ ./home/archlinux-vm.nix ];
          pkgs = import nixpkgs { system = "x86_64-linux"; };
          extraSpecialArgs = extraArgs;
        };

        # WSL2 running Ubuntu
        "kevin@KevinsPC" = home-manager.lib.homeManagerConfiguration {
          modules = [ ./home/kevins-pc.nix ];
          pkgs = import nixpkgs { system = "x86_64-linux"; };
          extraSpecialArgs = extraArgs;
        };
      };
    };
}