build.gradle

plugins {
    id "org.jetbrains.kotlin.jvm" version "1.3.72"
    id "io.spring.dependency-management" version "1.0.10.RELEASE"
}
  
allprojects {
    apply plugin: "org.jetbrains.kotlin.jvm"
    apply plugin: "kotlin-kapt"

    repositories {
        jcenter()
    }

}

subprojects {
    apply plugin: "io.spring.dependency-management"    

    repositories {
        jcenter()
        maven {
            url "https://repo.spring.io/milestone/"
        }
    }

    dependencyManagement {
        imports {
            mavenBom 'org.springframework.boot:spring-boot-dependencies:2.3.3.RELEASE'
        }
    }

    tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
        kotlinOptions {
            jvmTarget = "1.8"
        }
    }

    def arrow_version = "0.10.4"
    dependencies {
        implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.3.72"
        implementation "org.jetbrains.kotlin:kotlin-reflect:1.3.72"
        compile "io.arrow-kt:arrow-core:$arrow_version"
        compile "io.arrow-kt:arrow-syntax:$arrow_version"
        kapt    "io.arrow-kt:arrow-meta:$arrow_version"
    }
}

task copyAppDependencies(type: Copy, dependsOn: subprojects.jar) {
    from(subprojects.jar)
    into 'build/dependencies/app'
}

task copyThirdPartyDependencies(type: Copy, dependsOn: subprojects.jar) {
    from(subprojects.configurations.runtimeClasspath)
    exclude(subprojects.jar*.archiveName)
    into 'build/dependencies/third-party'
}

build.dependsOn copyAppDependencies
build.dependsOn copyThirdPartyDependencies