Adafruit Feather ESP32-S2 Reverse TFT Help #391

neilpas23 · 2023-04-18T10:35:05Z

neilpas23
Apr 18, 2023

Hi, sorry if this questions a little dumb. But I cant seem to get my display Adafruit Display to work with this library. I was previously using the TTGO T-Display and using this code at the start of my sketch (Which Worked) :

#define LGFX_AUTODETECT
#include <LovyanGFX.hpp>
#include <LGFX_AUTODETECT.hpp>

Though when I try this on my Adafruit display it doesn't seem to work. I even tried defining the exact display with:

#define LGFX_FEATHER_ESP32_S2_TFT
#include <LovyanGFX.hpp>
#include <LGFX_AUTODETECT.hpp>

But this didn't seem to work either. Is there a specific way you need to set up this display or am I just missing something
Thanks!

tobozo · 2023-04-18T10:49:49Z

tobozo
Apr 18, 2023
Collaborator

Hi,

Add this before including LovyanGFX.hpp, the other include (LGFX_AUTODETECT.hpp) is implicit so you probably won't need it after adding the macro.

#define LGFX_AUTODETECT

Adafruit boards have dedicated bootloaders that do a lot of stuff under the hood (e.g. USB magic).

The different state at boot may interfer with LGFX autodetect, if adding LFX_AUTODETECT didn't work, you may have to condiser disabling it and use a separate config block.

0 replies

neilpas23 · 2023-04-18T11:07:13Z

neilpas23
Apr 18, 2023
Author

So trying a few different variations of what you suggested didn't seem to work either. This variation is one of the ones that got the LCD backlight to turn on but nothing displaying.

#define LGFX_FEATHER_ESP32_S2_TFT
#define LGFX_AUTODETECT
#include <LovyanGFX.hpp>

Doing:

#define LGFX_AUTODETECT
#include <LovyanGFX.hpp>

Results in the screen not lighting up at all. You may be right about a different config block, but I'm just learning how to code, so im unsure what that entails.

Thanks!

0 replies

tobozo · 2023-04-18T11:58:50Z

tobozo
Apr 18, 2023
Collaborator

If you have a working example with all pinout documented (e.g. TFT_eSPI, Arduino_GFX), it's worth comparing with the pin configuration used in the autodetect sequence

If you have a doubt on the autodetect sequence, it's still possible to disable autodetect and create a custom config from the basic config example, and flash it using the default ESP32S2 Dev Module board profile.

However, troubleshooting this requires more information e.g. you'll have to share details about the IDE/platform versions and settings, and also the sketch.

0 replies

neilpas23 · 2023-04-19T09:26:27Z

neilpas23
Apr 19, 2023
Author

So this code works with the display using the Adafruit GFX Library, no surprise there. I went though and checked all the pin outs on the LGFX configs for this board and they all seemed to check out. I also tried going through the adafruit GFX library to see what they are doing differently but that codes above my head and I cant make heads or tails of it. I cant even find where they are defining the Pins. The one thing I did find is that they are using I2C power to power on the TFT, In the code below they define a pin for the power and then set it to high.

pinMode(TFT_I2C_POWER, OUTPUT); digitalWrite(TFT_I2C_POWER, HIGH);

Im unsure if this has anything to do with that. I tried setting up the User Settings for this display as well and it compiles but does not work, I can post that code as well if you think it might help. Unsure whats going on here, its probably me since Im new at this.

#include <Adafruit_GFX.h>    // Core graphics library
#include <Adafruit_ST7789.h> // Hardware-specific library for ST7789
#include <SPI.h>

// Use dedicated hardware SPI pins
Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_RST);

float p = 3.1415926;

void setup(void) {
  Serial.begin(9600);
  Serial.print(F("Hello! Feather TFT Test"));

  // turn on backlite
  pinMode(TFT_BACKLITE, OUTPUT);
  digitalWrite(TFT_BACKLITE, HIGH);

  // turn on the TFT / I2C power supply
  pinMode(TFT_I2C_POWER, OUTPUT);
  digitalWrite(TFT_I2C_POWER, HIGH);
  delay(10);

  // initialize TFT
  tft.init(135, 240); // Init ST7789 240x135
  tft.setRotation(3);
  tft.fillScreen(ST77XX_BLACK);

  Serial.println(F("Initialized"));

  uint16_t time = millis();
  tft.fillScreen(ST77XX_BLACK);
  time = millis() - time;

  Serial.println(time, DEC);
  delay(500);

  // large block of text
  tft.fillScreen(ST77XX_BLACK);
  testdrawtext(
      "Lorem ipsum dolor sit amet, consectetur adipiscing elit. Curabitur "
      "adipiscing ante sed nibh tincidunt feugiat. Maecenas enim massa, "
      "fringilla sed malesuada et, malesuada sit amet turpis. Sed porttitor "
      "neque ut ante pretium vitae malesuada nunc bibendum. Nullam aliquet "
      "ultrices massa eu hendrerit. Ut sed nisi lorem. In vestibulum purus a "
      "tortor imperdiet posuere. ",
      ST77XX_WHITE);
  delay(1000);

  // tft print function!
  tftPrintTest();
  delay(4000);

  // a single pixel
  tft.drawPixel(tft.width() / 2, tft.height() / 2, ST77XX_GREEN);
  delay(500);

  // line draw test
  testlines(ST77XX_YELLOW);
  delay(500);

  // optimized lines
  testfastlines(ST77XX_RED, ST77XX_BLUE);
  delay(500);

  testdrawrects(ST77XX_GREEN);
  delay(500);

  testfillrects(ST77XX_YELLOW, ST77XX_MAGENTA);
  delay(500);

  tft.fillScreen(ST77XX_BLACK);
  testfillcircles(10, ST77XX_BLUE);
  testdrawcircles(10, ST77XX_WHITE);
  delay(500);

  testroundrects();
  delay(500);

  testtriangles();
  delay(500);

  mediabuttons();
  delay(500);

  Serial.println("done");
  delay(1000);
}

void loop() {
  tft.invertDisplay(true);
  delay(500);
  tft.invertDisplay(false);
  delay(500);
}

void testlines(uint16_t color) {
  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x = 0; x < tft.width(); x += 6) {
    tft.drawLine(0, 0, x, tft.height() - 1, color);
    delay(0);
  }
  for (int16_t y = 0; y < tft.height(); y += 6) {
    tft.drawLine(0, 0, tft.width() - 1, y, color);
    delay(0);
  }

  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x = 0; x < tft.width(); x += 6) {
    tft.drawLine(tft.width() - 1, 0, x, tft.height() - 1, color);
    delay(0);
  }
  for (int16_t y = 0; y < tft.height(); y += 6) {
    tft.drawLine(tft.width() - 1, 0, 0, y, color);
    delay(0);
  }

  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x = 0; x < tft.width(); x += 6) {
    tft.drawLine(0, tft.height() - 1, x, 0, color);
    delay(0);
  }
  for (int16_t y = 0; y < tft.height(); y += 6) {
    tft.drawLine(0, tft.height() - 1, tft.width() - 1, y, color);
    delay(0);
  }

  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x = 0; x < tft.width(); x += 6) {
    tft.drawLine(tft.width() - 1, tft.height() - 1, x, 0, color);
    delay(0);
  }
  for (int16_t y = 0; y < tft.height(); y += 6) {
    tft.drawLine(tft.width() - 1, tft.height() - 1, 0, y, color);
    delay(0);
  }
}

void testdrawtext(char *text, uint16_t color) {
  tft.setCursor(0, 0);
  tft.setTextColor(color);
  tft.setTextWrap(true);
  tft.print(text);
}

void testfastlines(uint16_t color1, uint16_t color2) {
  tft.fillScreen(ST77XX_BLACK);
  for (int16_t y = 0; y < tft.height(); y += 5) {
    tft.drawFastHLine(0, y, tft.width(), color1);
  }
  for (int16_t x = 0; x < tft.width(); x += 5) {
    tft.drawFastVLine(x, 0, tft.height(), color2);
  }
}

void testdrawrects(uint16_t color) {
  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x = 0; x < tft.width(); x += 6) {
    tft.drawRect(tft.width() / 2 - x / 2, tft.height() / 2 - x / 2, x, x,
                 color);
  }
}

void testfillrects(uint16_t color1, uint16_t color2) {
  tft.fillScreen(ST77XX_BLACK);
  for (int16_t x = tft.width() - 1; x > 6; x -= 6) {
    tft.fillRect(tft.width() / 2 - x / 2, tft.height() / 2 - x / 2, x, x,
                 color1);
    tft.drawRect(tft.width() / 2 - x / 2, tft.height() / 2 - x / 2, x, x,
                 color2);
  }
}

void testfillcircles(uint8_t radius, uint16_t color) {
  for (int16_t x = radius; x < tft.width(); x += radius * 2) {
    for (int16_t y = radius; y < tft.height(); y += radius * 2) {
      tft.fillCircle(x, y, radius, color);
    }
  }
}

void testdrawcircles(uint8_t radius, uint16_t color) {
  for (int16_t x = 0; x < tft.width() + radius; x += radius * 2) {
    for (int16_t y = 0; y < tft.height() + radius; y += radius * 2) {
      tft.drawCircle(x, y, radius, color);
    }
  }
}

void testtriangles() {
  tft.fillScreen(ST77XX_BLACK);
  uint16_t color = 0xF800;
  int t;
  int w = tft.width() / 2;
  int x = tft.height() - 1;
  int y = 0;
  int z = tft.width();
  for (t = 0; t <= 15; t++) {
    tft.drawTriangle(w, y, y, x, z, x, color);
    x -= 4;
    y += 4;
    z -= 4;
    color += 100;
  }
}

void testroundrects() {
  tft.fillScreen(ST77XX_BLACK);
  uint16_t color = 100;
  int i;
  int t;
  for (t = 0; t <= 4; t += 1) {
    int x = 0;
    int y = 0;
    int w = tft.width() - 2;
    int h = tft.height() - 2;
    for (i = 0; i <= 16; i += 1) {
      tft.drawRoundRect(x, y, w, h, 5, color);
      x += 2;
      y += 3;
      w -= 4;
      h -= 6;
      color += 1100;
    }
    color += 100;
  }
}

void tftPrintTest() {
  tft.setTextWrap(false);
  tft.fillScreen(ST77XX_BLACK);
  tft.setCursor(0, 30);
  tft.setTextColor(ST77XX_RED);
  tft.setTextSize(1);
  tft.println("Hello World!");
  tft.setTextColor(ST77XX_YELLOW);
  tft.setTextSize(2);
  tft.println("Hello World!");
  tft.setTextColor(ST77XX_GREEN);
  tft.setTextSize(3);
  tft.println("Hello World!");
  tft.setTextColor(ST77XX_BLUE);
  tft.setTextSize(4);
  tft.print(1234.567);
  delay(1500);
  tft.setCursor(0, 0);
  tft.fillScreen(ST77XX_BLACK);
  tft.setTextColor(ST77XX_WHITE);
  tft.setTextSize(0);
  tft.println("Hello World!");
  tft.setTextSize(1);
  tft.setTextColor(ST77XX_GREEN);
  tft.print(p, 6);
  tft.println(" Want pi?");
  tft.println(" ");
  tft.print(8675309, HEX); // print 8,675,309 out in HEX!
  tft.println(" Print HEX!");
  tft.println(" ");
  tft.setTextColor(ST77XX_WHITE);
  tft.println("Sketch has been");
  tft.println("running for: ");
  tft.setTextColor(ST77XX_MAGENTA);
  tft.print(millis() / 1000);
  tft.setTextColor(ST77XX_WHITE);
  tft.print(" seconds.");
}

void mediabuttons() {
  // play
  tft.fillScreen(ST77XX_BLACK);
  tft.fillRoundRect(25, 5, 78, 60, 8, ST77XX_WHITE);
  tft.fillTriangle(42, 12, 42, 60, 90, 40, ST77XX_RED);
  delay(500);
  // pause
  tft.fillRoundRect(25, 70, 78, 60, 8, ST77XX_WHITE);
  tft.fillRoundRect(39, 78, 20, 45, 5, ST77XX_GREEN);
  tft.fillRoundRect(69, 78, 20, 45, 5, ST77XX_GREEN);
  delay(500);
  // play color
  tft.fillTriangle(42, 12, 42, 60, 90, 40, ST77XX_BLUE);
  delay(50);
  // pause color
  tft.fillRoundRect(39, 78, 20, 45, 5, ST77XX_RED);
  tft.fillRoundRect(69, 78, 20, 45, 5, ST77XX_RED);
  // play color
  tft.fillTriangle(42, 12, 42, 60, 90, 40, ST77XX_GREEN);
}

1 reply

neilpas23 Apr 19, 2023
Author

Never mind on the I2C thing, I found where the pin gets defined in LGFX.

tobozo · 2023-04-19T11:08:27Z

tobozo
Apr 19, 2023
Collaborator

I cant even find where they are defining the Pins.

you don't need to find where they are, you just need to know their value, just use your serial console:

   Serial.printf("Pin value of TFT_I2C_POWER=%d\n", TFT_I2C_POWER );

you won't find those pin definitions in the driver folder anyway, they're in the variants folder from the espressif core:

~/.arduino15/packages/esp32/hardware/esp32/2.0.7/variants/adafruit_feather_esp32_v2/pins_arduino.h

I don't have a feather to test with, so I can't use printf to reveal those values, but ideally you should fill all the missing blanks in this table (I've filled the LGFX part from the autodectect sequence) and confirm that everything matches.

	TFT_CS	TFT_DC	TFT_RST	TFT_MISO	TFT_MOSI	TFT_SCK	TFT_I2C_POWER	TFT_BL

Adafruit_GFX	?	?	?	?	?	?	?	?

LGFX	7	39	40	-1	35	36	21	45

I can post that code as well if you think it might help.

yes please do post the LGFX snippet, it should have both Panel_ST7789 and Light_PWM (TFT_BL) objects

4 replies

neilpas23 Apr 19, 2023
Author

so for some reason when I run what you asked I get all 7s

Pin value of TFT_CS=7
Pin value of TFT_DC=7
Pin value of TFT_RST=7
Pin value of TFT_MISO=7
Pin value of TFT_MOSI=7
Pin value of TFT_SCK=7
Pin value of TFT_I2C_POWER=7
Pin value of TFT_BL=7

neilpas23 Apr 19, 2023
Author

I see my mistake...one sec let me see if I can fix this.

neilpas23 Apr 19, 2023
Author

I accidently left tft_i2c_power in as all the values, but now I get an error saying Miso, Mosi, Sck and BL aren't declared in this scope.

#include <Adafruit_GFX.h>
#include <Adafruit_ST7789.h>
#include <SPI.h>


Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_RST);
float p = 3.1415926;

void setup() {

  Serial.begin(9600);
  Serial.print(F("Hello! Feather TFT Test"));

  // turn on backlite
  pinMode(TFT_BACKLITE, OUTPUT);
  digitalWrite(TFT_BACKLITE, HIGH);

  // turn on the TFT / I2C power supply
  pinMode(TFT_I2C_POWER, OUTPUT);
  digitalWrite(TFT_I2C_POWER, HIGH);
  delay(10);

  // initialize TFT
  tft.init(135, 240); // Init ST7789 240x135
  tft.setRotation(3);
  tft.fillScreen(ST77XX_BLACK);

  Serial.printf("Pin value of TFT_I2C_POWER=%d\n", TFT_I2C_POWER );

}

void loop() {

Serial.printf("Pin value of TFT_CS=%d\n", TFT_CS );
Serial.printf("Pin value of TFT_DC=%d\n", TFT_DC );
Serial.printf("Pin value of TFT_RST=%d\n", TFT_RST );
Serial.printf("Pin value of TFT_MISO=%d\n", TFT_MISO );
Serial.printf("Pin value of TFT_MOSI=%d\n", TFT_MOSI );
Serial.printf("Pin value of TFT_SCK=%d\n", TFT_SCK );
Serial.printf("Pin value of TFT_I2C_POWER=%d\n", TFT_I2C_POWER );
Serial.printf("Pin value of TFT_BL=%d\n", TFT_BL );
delay(9000);
}

neilpas23 Apr 19, 2023
Author

Specifically, Miso, Mosi, Sck and BL arnt declared,

Pin value of TFT_CS=42
Pin value of TFT_DC=40
Pin value of TFT_RST=41
Pin value of TFT_I2C_POWER=7

neilpas23 · 2023-04-19T12:00:18Z

neilpas23
Apr 19, 2023
Author

Also heres the LGFX Snippet for the edited User Settings.

	TFT_CS	TFT_DC	TFT_RST	TFT_MISO	TFT_MOSI	TFT_SCK	TFT_I2C_POWER	TFT_BL

Adafruit_GFX	42	40	41	-1?	SDA?	SCL?	7	45

LGFX	7	39	40	-1	35	36	21	45

#include <LovyanGFX.hpp>

class LGFX : public lgfx::LGFX_Device
{

lgfx::Panel_ST7789      _panel_instance;
lgfx::Bus_SPI        _bus_instance;
lgfx::Light_PWM     _light_instance;

public:

  LGFX(void)
  {
    { 
      auto cfg = _bus_instance.config(); 
      cfg.spi_host = SPI2_HOST;
      cfg.spi_mode = 0;
      cfg.freq_write = 40000000;
      cfg.freq_read  = 16000000;
      cfg.spi_3wire  = true; 
      //cfg.use_lock   = true;
      cfg.dma_channel = SPI_DMA_CH_AUTO;
      cfg.pin_sclk = 36;
      cfg.pin_mosi = 35;
      cfg.pin_miso = -1; 
      cfg.pin_dc   = 39;  

      _bus_instance.config(cfg);  
      _panel_instance.setBus(&_bus_instance); 
    }

    { 
      auto cfg = _panel_instance.config(); 

      cfg.pin_cs           =    7;  //   (-1 = disable)
      cfg.pin_rst          =    40;  //   (-1 = disable)
      cfg.pin_busy         =    -1;  //  (-1 = disable)

      cfg.panel_width      =   135; 
      cfg.panel_height     =   240;
      cfg.offset_x         =    52; 
      cfg.offset_y         =    40; 
      cfg.offset_rotation  =     1; 
      cfg.dummy_read_pixel =     8;
      cfg.dummy_read_bits  =     1;
      cfg.readable         = false; 
      cfg.invert           =  true;
      cfg.rgb_order        = false;  
      //cfg.dlen_16bit       = false;  
      //cfg.bus_shared       =  true;

      _panel_instance.config(cfg);
    }


    { 
      auto cfg = _light_instance.config();

      cfg.pin_bl = 45;  
      cfg.invert = false; 
      cfg.freq   = 12000;  
      //cfg.pwm_channel = 7;  

      _light_instance.config(cfg);
      _panel_instance.setLight(&_light_instance);
    }

    setPanel(&_panel_instance); 
  }
};

LGFX display;

void setup(void)
{

  display.init();

  display.setTextSize((std::max(display.width(), display.height()) + 255) >> 8);

  if (display.touch())
  {
    if (display.width() < display.height()) display.setRotation(display.getRotation() ^ 1);

    display.setTextDatum(textdatum_t::middle_center);
    display.drawString("touch the arrow marker.", display.width()>>1, display.height() >> 1);
    display.setTextDatum(textdatum_t::top_left);

    std::uint16_t fg = TFT_WHITE;
    std::uint16_t bg = TFT_BLACK;
    if (display.isEPD()) std::swap(fg, bg);
    display.calibrateTouch(nullptr, fg, bg, std::max(display.width(), display.height()) >> 3);
  }

  display.fillScreen(TFT_BLACK);
}

uint32_t count = ~0;
void loop(void)
{
  display.startWrite();
  display.setRotation(++count & 7);
  display.setColorDepth((count & 8) ? 16 : 24);

  display.setTextColor(TFT_WHITE);
  display.drawNumber(display.getRotation(), 16, 0);

  display.setTextColor(0xFF0000U);
  display.drawString("R", 30, 16);
  display.setTextColor(0x00FF00U);
  display.drawString("G", 40, 16);
  display.setTextColor(0x0000FFU);
  display.drawString("B", 50, 16);

  display.drawRect(30,30,display.width()-60,display.height()-60,count*7);
  display.drawFastHLine(0, 0, 10);

  display.endWrite();

  int32_t x, y;
  if (display.getTouch(&x, &y)) {
    display.fillRect(x-2, y-2, 5, 5, count*7);
  }
}

2 replies

tobozo Apr 19, 2023
Collaborator

I've edited your comment, added the table with the data you collected, it's still missing the value of TFT_BACKLITE.

There's also a possibility that TFT_MOSI=SDA and TFT_SCK=SCL, so you may want to print SDA and SCL values too.

tobozo Apr 19, 2023
Collaborator

from the values you collected I can confirm that you're using the pinout from Feather ESP32-S2 Reverse TFT, the pin definitions are located here:

~/.arduino15/packages/esp32/hardware/esp32/2.0.7/variants/adafruit_feather_esp32s3_reversetft/pins_arduino.h

since none of the values from LGFX autodetect match the ones from that boad, you can safely assume that this board is not detectable, and creating your own LGFX config is the right thing to do.

now if your display is working with the adafruit configuration, all you have to do is to change all the pin values in your LGFX config snippet, and put the values you collected from your adafruit sketch.

you may have to test two different settings though, here are the variants:

if the tft uses the i2c pins:

  cfg.pin_sclk = SCL;
  cfg.pin_mosi = SDA;
  cfg.pin_miso = -1;

if the tft uses the spi pins:

  cfg.pin_mosi = MOSI;
  cfg.pin_sclk = SCK;
  cfg.pin_miso MISO ;

You don't need to use pinMode with TFT_I2C_POWER though, just call the initVariant() function at the beginning of your setup(), this is a common function to all Adafruit boards and saves you the hassle of having to do it manually or deferring that task to a display driver.

Here's a config snippet I made based on your Feather ESP32-S2 Reverse TFT selected board, just run it as is and eventually change the value of use_i2c_pins to test the other bus mode:

class LGFX : public lgfx::LGFX_Device
{

lgfx::Panel_ST7789 _panel_instance;
lgfx::Bus_SPI      _bus_instance;
lgfx::Light_PWM    _light_instance;

public:
  LGFX(void)
  {
    {
      auto cfg = _bus_instance.config();
      cfg.spi_host = SPI2_HOST; // not sure about this, comment out if unsure
      cfg.spi_mode = 0;         // not sure about this, comment out if unsure
      cfg.freq_write = 40000000;
      cfg.freq_read  = 16000000;

      cfg.dma_channel = SPI_DMA_CH_AUTO;

      bool use_i2c_pins = true; // change this to test one or another confirugation

      if( use_i2c_pins ) {
        cfg.pin_sclk = SCL;
        cfg.pin_mosi = SDA;
        cfg.pin_miso = -1;
        cfg.spi_3wire  = true; // only necessary when pin_miso=-1
      } else {
        cfg.pin_mosi = MOSI;
        cfg.pin_sclk = SCK;
        cfg.pin_miso = MISO;
      }

      cfg.pin_dc   = TFT_DC;
      _bus_instance.config(cfg);
      _panel_instance.setBus(&_bus_instance);
    }

    {
      auto cfg = _panel_instance.config();
      cfg.pin_cs           = TFT_CS;  // (-1 = disable)
      cfg.pin_rst          = TFT_RST; // (-1 = disable)
      cfg.pin_busy         =    -1;   // (-1 = disable)
      cfg.panel_width      =   135;
      cfg.panel_height     =   240;
      cfg.offset_x         =    52;
      cfg.offset_y         =    40;
      cfg.offset_rotation  =     1;
      cfg.dummy_read_pixel =     8;
      cfg.dummy_read_bits  =     1;
      cfg.readable         = false;
      cfg.invert           =  true;
      cfg.rgb_order        = false;
      _panel_instance.config(cfg);
    }


    {
      auto cfg = _light_instance.config();
      cfg.pin_bl = TFT_BACKLITE;
      cfg.invert = false;
      cfg.freq   = 12000;
      _light_instance.config(cfg);
      _panel_instance.setLight(&_light_instance);
    }

    setPanel(&_panel_instance);
  }
};

neilpas23 · 2023-04-19T19:38:54Z

neilpas23
Apr 19, 2023
Author

So the Code snippet you pasted worked when set to false. I added it at the beginning of the code I've been working on and it finally displays. There seems to be an issue with deep sleep waking up randomly after it goes to sleep but I can troubleshoot that more later. Is there a way I can simplify this code so that I don't need to call it all at the beginning of my sketch?

Also I wasn't able to find the values for Mosi and SCK even with the changes to the names, I did however notice something in adafruit_ST7789.cpp.

/*!
    @brief  Instantiate Adafruit ST7789 driver with software SPI
    @param  cs    Chip select pin #
    @param  dc    Data/Command pin #
    @param  mosi  SPI MOSI pin #
    @param  sclk  SPI Clock pin #
    @param  rst   Reset pin # (optional, pass -1 if unused)
*/
Adafruit_ST7789::Adafruit_ST7789(int8_t cs, int8_t dc, int8_t mosi, int8_t sclk,
                                 int8_t rst)
    : Adafruit_ST77xx(240, 320, cs, dc, mosi, sclk, rst) {}

/*!
    @brief  Instantiate Adafruit ST7789 driver with hardware SPI
    @param  cs   Chip select pin #
    @param  dc   Data/Command pin #
    @param  rst  Reset pin # (optional, pass -1 if unused)
*/
Adafruit_ST7789::Adafruit_ST7789(int8_t cs, int8_t dc, int8_t rst)
    : Adafruit_ST77xx(240, 320, cs, dc, rst) {}

it appears that those values aren't needed for the hardware spi? At least that's what I'm assuming since that's what I called at the top of the adafruit code snippet. Maybe thats why I couldnt get values for them?

1 reply

tobozo Apr 19, 2023
Collaborator

Is there a way I can simplify this code so that I don't need to call it all at the beginning of my sketch?

Probably not since autodetect mismatches this board model with another variant.

I you don't like this big code block at the beginning of your sketch you can still move it to an external file along with the include directive, and from you ino sketch include that file instead of LovyanGFX.hpp.

it appears that those values aren't needed for the hardware spi?

hardware spi probably means the defaut MOSI/MISO/SCK pins from pins_arduino.h are implicitely used and don't need to be specified in he constructor

waking up randomly after it goes to sleep

the display is probably still awake, using tft.sleep() and tft.wake() in the correct order should prevent that

neilpas23 · 2023-04-20T01:16:47Z

neilpas23
Apr 20, 2023
Author

Thanks again for your help, This solved my issues, I'm posting the User Setup below that I'm using for the Adafruit ESP32 Reverse Feather TFT if anyone else has issues Hopeful this will help. Also I changed the frequency of the write to 80000000 because I was getting a nasty flicker when ever the tft turned on. Idk if this is the right value but it seems to work and eliminate the flicker. Thanks Again @tobozo !!

#include <LovyanGFX.hpp>
#include "driver/rtc_io.h" //you can ignore this if you aren't using RTC memory to pullup deepsleep pins

class LGFX : public lgfx::LGFX_Device
{

lgfx::Panel_ST7789 _panel_instance;
lgfx::Bus_SPI      _bus_instance;
lgfx::Light_PWM    _light_instance;

public:
  LGFX(void)
  {
    {
      auto cfg = _bus_instance.config();
      cfg.spi_host = SPI2_HOST; // not sure about this, comment out if unsure
      cfg.spi_mode = 0;         // not sure about this, comment out if unsure
      cfg.freq_write = 80000000;
      cfg.freq_read  = 16000000;

      cfg.dma_channel = SPI_DMA_CH_AUTO;

      bool use_i2c_pins = false; // change this to test one or another confirugation

      if( use_i2c_pins ) {
        cfg.pin_sclk = SCL;
        cfg.pin_mosi = SDA;
        cfg.pin_miso = -1;
        cfg.spi_3wire  = true; // only necessary when pin_miso=-1
      } else {
        cfg.pin_mosi = MOSI;
        cfg.pin_sclk = SCK;
        cfg.pin_miso = MISO;
      }

      cfg.pin_dc   = TFT_DC;
      _bus_instance.config(cfg);
      _panel_instance.setBus(&_bus_instance);
    }

    {
      auto cfg = _panel_instance.config();
      cfg.pin_cs           = TFT_CS;  // (-1 = disable)
      cfg.pin_rst          = TFT_RST; // (-1 = disable)
      cfg.pin_busy         =    -1;   // (-1 = disable)
      cfg.panel_width      =   135;
      cfg.panel_height     =   240;
      cfg.offset_x         =    52;
      cfg.offset_y         =    40;
      cfg.offset_rotation  =     1;
      cfg.dummy_read_pixel =     8;
      cfg.dummy_read_bits  =     1;
      cfg.readable         = false;
      cfg.invert           =  true;
      cfg.rgb_order        = false;
      _panel_instance.config(cfg);
    }


    {
      auto cfg = _light_instance.config();
      cfg.pin_bl = TFT_BACKLITE;
      cfg.invert = false;
      cfg.freq   = 12000;
      _light_instance.config(cfg);
      _panel_instance.setLight(&_light_instance);
    }

    setPanel(&_panel_instance);
  }
};
LGFX display;

0 replies

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

Adafruit Feather ESP32-S2 Reverse TFT Help #391

{{title}}

Replies: 8 comments 8 replies

{{title}}

{{title}}

{{title}}

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

{{editor}}'s edit

{{editor}}'s edit

Select a reply

Adafruit Feather ESP32-S2 Reverse TFT Help #391

neilpas23 Apr 18, 2023

Replies: 8 comments · 8 replies

tobozo Apr 18, 2023 Collaborator

neilpas23 Apr 18, 2023 Author

tobozo Apr 18, 2023 Collaborator

neilpas23 Apr 19, 2023 Author

neilpas23 Apr 19, 2023 Author

tobozo Apr 19, 2023 Collaborator

neilpas23 Apr 19, 2023 Author

neilpas23 Apr 19, 2023 Author

neilpas23 Apr 19, 2023 Author

neilpas23 Apr 19, 2023 Author

neilpas23 Apr 19, 2023 Author

tobozo Apr 19, 2023 Collaborator

tobozo Apr 19, 2023 Collaborator

if the tft uses the i2c pins:

if the tft uses the spi pins:

neilpas23 Apr 19, 2023 Author

tobozo Apr 19, 2023 Collaborator

neilpas23 Apr 20, 2023 Author

neilpas23
Apr 18, 2023

Replies: 8 comments 8 replies

tobozo
Apr 18, 2023
Collaborator

neilpas23
Apr 18, 2023
Author

tobozo
Apr 18, 2023
Collaborator

neilpas23
Apr 19, 2023
Author

neilpas23 Apr 19, 2023
Author

tobozo
Apr 19, 2023
Collaborator

neilpas23 Apr 19, 2023
Author

neilpas23 Apr 19, 2023
Author

neilpas23 Apr 19, 2023
Author

neilpas23 Apr 19, 2023
Author

neilpas23
Apr 19, 2023
Author

tobozo Apr 19, 2023
Collaborator

tobozo Apr 19, 2023
Collaborator

neilpas23
Apr 19, 2023
Author

tobozo Apr 19, 2023
Collaborator

neilpas23
Apr 20, 2023
Author