How to use this in recipe

[maulik9898]

I want to use this layer in my recipe which compile java using gradlew. currently its bitbake gives error saying JAVA_HOME is not definde or no java present.

[sebveit]

You should/could execute the distTar task of gradle to create an archive
and copy that archive to your OE/Yocto setup.
You also need a custom layer with a custom recipe in it.
The recipe could be situated under meta-myownlayer/recipes-core/my-java-app/my-java-app_1.0.bb
with the following content:

DESCRIPTION = "My own Java app that runs on the device."
HOMEPAGE = "https://git.example.org/my-java-app"
SECTION = "my-custom"

LICENSE = "Proprietary"
LICENSE_FLAGS = "commercial"
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/Proprietary;md5=0557f9d92cf58f2ccdd50f62f8ac0b28"

# RDEPENDS must be list of package names (not recipe names)
# RDEPENDS:${PN} = "postgresql mysql"

SRC_URI = "file://my-java-app-1.0-SNAPSHOT.tar \
           file://my-java-app.service \
           file://config.properties.dist \
          "

inherit systemd

FILES:${PN} = "/opt/my-java-app"
SYSTEMD_SERVICE:${PN} = "my-java-app.service"

do_configure[noexec] = "1"
do_compile[noexec] = "1"

do_install() {
  install -d ${D}/opt/my-java-app/bin
  install -m 0755 ${S}/bin/my-java-app \
    ${D}/opt/my-java-app/bin/

  install -d ${D}/opt/my-java-app/lib
  install -m 0644 ${S}/lib/* \
    ${D}/opt/my-java-app/lib/

  install -d ${D}/opt/my-java-app/etc
  install -m 0640 ${WORKDIR}/config.properties.dist \
    ${D}/opt/my-java-app/etc/

  install -d ${D}${systemd_system_unitdir}
  install -m 0644 ${WORKDIR}/my-java-app.service \
    ${D}${systemd_system_unitdir}
}

This should work without further config like JAVA_HOME.
Please read the documentation of Yocto about writing your own recipe.
See https://docs.yoctoproject.org/dev-manual/new-recipe.html but make sure to use the correct branch/release on the documentation.

[GeVa2072]

Hi @maulik9898,

don’t forget to add to `RDEPENDS:${PN}ˋ openjdk-xx-jre, where xx is java version to embed in your target for running your app.