build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
    id "com.github.johnrengelman.shadow" version "7.1.2"
}

group 'com.agoramp'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.1'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.1'

    // lombok
    compileOnly 'org.projectlombok:lombok:1.18.26'
    annotationProcessor 'org.projectlombok:lombok:1.18.26'

    // https://mvnrepository.com/artifact/com.google.code.gson/gson
    shadow 'com.google.code.gson:gson:2.10.1'


    // Project reactor
    implementation platform('io.projectreactor:reactor-bom:2022.0.4')
    shadow platform('io.projectreactor:reactor-bom:2022.0.4')
    // https://mvnrepository.com/artifact/io.projectreactor/reactor-core
    shadow 'io.projectreactor:reactor-core'
    testImplementation 'io.projectreactor:reactor-core'
    // Reactor Netty
    shadow 'io.projectreactor.netty:reactor-netty-core'
    // Reactor Netty for HTTP
    shadow 'io.projectreactor.netty:reactor-netty-http'
    // Reactor extras
    shadow 'io.projectreactor.addons:reactor-extra:3.5.0'

    shadow "com.apollographql.apollo3:apollo-api:3.8.1"
}

test {
    useJUnitPlatform()
}

// Configure the shadow plugin
shadowJar {
    configurations = [project.configurations.shadow]
    archiveClassifier.set('')

    relocate 'io.netty', 'com.agoramp.netty'
    relocate 'org.reactivestreams', 'com.agoramp.reactive.streams'
    relocate 'reactor', 'com.agoramp.reactive'
}

build.dependsOn('shadowJar')

// Added publishing configuration
publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact shadowJar // Publish the shadowJar as artifact
            groupId = project.group
            artifactId = project.name
            version = project.version
        }
    }
}