build.gradle

buildscript {
    repositories {
        jcenter()
        mavenCentral()
        mavenLocal()
    }
    dependencies {
        classpath "nu.studer:gradle-credentials-plugin:1.0.1"
    }
}

configure(allprojects) { project ->

    group = "com.github.marsbits.restfbmessenger"

    ext {
        hibernateValidatorVersion = "5.3.5.Final"
        junitVersion = "4.12"
        mockitoVersion = "1.10.19"
        restfbVersion = "2.0.0"
        servletVersion = "2.5"
        servlet3Version = "3.1.0"
        springVersion = "4.3.13.RELEASE"
        springBootVersion = "1.5.9.RELEASE"
    }

    ext.javadocLinks = [
            "http://docs.oracle.com/javase/7/docs/api/",
            "http://docs.oracle.com/javaee/7/api/",
            "http://docs.spring.io/spring/docs/4.3.13.RELEASE/javadoc-api/",
            "http://docs.spring.io/spring-boot/docs/1.5.9.RELEASE/api/",
            "http://restfb.com/javadoc/"
    ] as String[]

    apply plugin: "java"
    apply plugin: "idea"
    apply plugin: "maven"
    apply plugin: "signing"
    apply plugin: "nu.studer.credentials"

    sourceCompatibility = 1.7
    targetCompatibility = 1.7

    [compileJava, compileTestJava]*.options*.compilerArgs = ['-Xlint:none']

    repositories {
        jcenter()
        mavenCentral()
        mavenLocal()
    }

    dependencies {
        testCompile "junit:junit:${junitVersion}"
        testCompile "org.mockito:mockito-core:${mockitoVersion}"
    }

    idea {
        module {
            downloadJavadoc = true
            downloadSources = true
        }
    }
}

configure(subprojects) { subproject ->

    ext."signing.keyId" = credentials.signingKeyId
    ext."signing.password" = credentials.signingPassword
    ext."signing.secretKeyRingFile" = credentials.signingSecretKeyRingFile

    jar {
        manifest.attributes["Created-By"] = "${System.getProperty("java.version")} (${System.getProperty("java.specification.vendor")})"
        manifest.attributes["Implementation-Title"] = subproject.name
        manifest.attributes["Implementation-Version"] = subproject.version
    }

    javadoc {
        description = "Generates project-level Javadoc API documentation."

        options.memberLevel = org.gradle.external.javadoc.JavadocMemberLevel.PROTECTED
        options.author = true
        options.header = project.name
        options.links(javadocLinks)
        options.addStringOption("Xdoclint:none", "-quiet")

        // suppress warnings due to cross-module @see and @link references;
        // note that global 'api' task does display all warnings.
        logging.captureStandardError LogLevel.INFO
        logging.captureStandardOutput LogLevel.INFO // suppress "## warnings" message
    }

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = "sources"
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier = "javadoc"
        from javadoc.destinationDir
    }

    artifacts {
        archives sourcesJar, javadocJar
    }

    signing {
        sign configurations.archives
    }


    uploadArchives {
        repositories {
            mavenDeployer {

                beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

                repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                    authentication(userName: credentials.ossrhUsername, password: credentials.ossrhPassword)
                }

                snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                    authentication(userName: credentials.ossrhUsername, password: credentials.ossrhPassword)
                }

                pom.project {
                    name "RestFB Messenger"
                    packaging "jar"
                    description "RestFB Messenger"
                    url "https://github.com/marsbits/restfbmessenger"

                    scm {
                        connection "scm:git@github.com/marsbits/restfbmessenger.git"
                        developerConnection "scm:git@github.com:marsbits/restfbmessenger.git"
                        url "https://github.com/marsbits/restfbmessenger"
                    }

                    licenses {
                        license {
                            name "The Apache License, Version 2.0"
                            url "http://www.apache.org/licenses/LICENSE-2.0.txt"
                        }
                    }

                    developers {
                        developer {
                            id "marceloverdijk"
                            name "Marcel Overdijk"
                            email "marcel@overdijk.me"
                        }
                    }
                }
            }
        }
    }
}

project("restfbmessenger-core") {

    description = "RestFB Messenger Core"

    dependencies {
        compile "com.restfb:restfb:${restfbVersion}"
        compileOnly "javax.servlet:servlet-api:${servletVersion}"
        testCompile "javax.servlet:servlet-api:${servletVersion}"
    }
}

project("restfbmessenger-spring-boot-starter") {

    description = "RestFB Messenger Spring Boot Starter"

    dependencies {
        compile project(":restfbmessenger-core")
        compile "org.springframework.boot:spring-boot:${springBootVersion}"
        compile "org.springframework.boot:spring-boot-autoconfigure:${springBootVersion}"
        compileOnly "javax.servlet:javax.servlet-api:${servlet3Version}"
        compileOnly "org.hibernate:hibernate-validator:${hibernateValidatorVersion}"
        testCompile "javax.servlet:javax.servlet-api:${servlet3Version}"
        testCompile "org.springframework:spring-web:${springVersion}"
        testCompile "org.springframework.boot:spring-boot-test:${springBootVersion}"
    }
}

configure(rootProject) {

    description = "RestFB Messenger"

    // don't publish the default jar for the root project
    configurations.archives.artifacts.clear()
}