build.gradle

buildscript {
    repositories {
        gradlePluginPortal()
        maven {
			url = 'https://repo.spring.io/plugins-release'
			if (project.hasProperty('artifactoryUsername')) {
				credentials {
					username "$artifactoryUsername"
					password "$artifactoryPassword"
				}
			}
		}
    }
    dependencies {
        classpath "com.github.ben-manes:gradle-versions-plugin:0.17.0"
        classpath("io.spring.gradle:spring-io-plugin:0.0.6.RELEASE")
        classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.12.0"
        classpath 'org.hidetake:gradle-ssh-plugin:2.10.1'
        classpath 'io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.10.0'
    }
}

apply plugin: 'io.spring.convention.root'
apply plugin: 'io.spring.convention.docs'
apply plugin: 's101'

group = "org.springframework.ldap"
description = "Spring LDAP"

nohttp {
	allowlistFile = project.file("etc/nohttp/allowlist.lines")
	source.exclude "buildSrc/build/**"
}

asciidoctor {
	outputDir = new File("$buildDir/docs")
	attributes([
		copycss : '',
		icons : 'font',
		'source-highlighter': 'prettify',
		sectanchors : '',
		toc2: '',
		idprefix: '',
		idseparator: '-',
		doctype: 'book',
		numbered: '',
		'spring-ldap-version' : project.version,
		revnumber : project.version
	])
	options = [
		eruby: 'erubis'
	]
}

s101 {
	configurationDirectory = project.file("etc/s101")
}