-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathUade17.asm
1222 lines (973 loc) · 18.8 KB
/
Uade17.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;.OPT
;UADE17;FILE > Uade17
;.TTL
;Fileserver file UADE17
.UADE17
;INFO/LOGON/PRIV. OPERATIONS ETC.
.CPINFO
{
;Get info in m/c readable format, depending on
;argument.
;1 = creation date
;2 = load/execution addresses
;3 = size
;4 = type/access
;5 = all above 4 in order load/execute/size/access/date
;
;6 = get access, cycle (sequence) number, and last
; component of dir. title for dir. name. NOTE
; does not use retrieve, and does not trap "NOT
; FOUND" error.
JSR GETUSR
BNE CPINLX
LDX BPTR
LDA MIDRX,X
BEQ CPINLK;Zero arg => error
CMP #6
BEQ CPDINF;=> do directory information
BCC CPINLA;Otherwise, is valid arg.
.*CPINLK
LDA #INFERA
BNE CPINLZ;Abort with err. msg.
.CPINLA
LDA #0
STA MIDTX;Set existence flag to "does not exist"
LDA #INFFTO
JSR CPRETR;Retrieve details
BEQ CPINLC;Ok, continue
CMP #DRERRC;If not found, alter existence flag
BNE CPINLZ;Not "not found" => error
LDX #1;Length of reply
BNE CPINLE;Exit, sending reply
.CPINLC
INC MIDTX;Set flag to "is a file"
LDX BPTR
LDA MIDRX,X;Check arg.
LDX #1;Offset for COCOPY
CMP #5;Is "all args" ?
BNE CPINLB;Nope, continue
JSR CPYLXS;Yep, copy all args
BEQ CPINJA;Always jump
.CPINLB
JSR COCOPY;Copy relevant amount of stuff COWORK->MIDTX
.CPINJA
LDY #ARGB;check for OWNER/PUBLIC
LDA (NEWARG),Y
AND #OWNER
BEQ CPINJ
LDA #LO(-1)
.CPINJ
EOR #LO(-1);invert byte [Owner => 0]
STA MIDTX,X;put this at the end of the information
INX
.CPINLD
LDY #INFACC
LDA COWORK,Y
AND #TYPDIR;Check if is a directory
BEQ CPINLE;Is not -> continue
INC MIDTX;Is => set flag to 2 => directory
.CPINLE
TXA;Length of information transfered
JMP DATOT2;Send reply
.CPINLX
JMP COMRTS
.*CPINLZ
JMP ERROR
.CPDINF
JSR STKUSA;Set user info. on stack
LDA #3
STA COZERO;Offset for dir. name result
LDA #HDRLEN + 1;Offset of dir. name arg.
LDX #&C1;force directory here
JSR DIRIN2;Get dir. infomation
BNE CPINLZ
LDY #ARGD;Now set access & sequence number
LDA #0
STA MIDTX +NAMLNT+ 3;Zero => owner, $FF => public
STA MIDTX + 1
LDA #OWNER
AND (NEWARG),Y;Check access to dir.
BNE CPINL7;Is owner, continue
DEC MIDTX +NAMLNT+ 3;Otherwise, give $FF
.CPINL7
INY
LDA (NEWARG),Y
STA MIDTX +NAMLNT+ 4;Set sequence number of dir.
LDA #NAMLNT
STA MIDTX + 2;Set length of dir. name
LDX #NAMLNT+ 5;Length of message - TXHDR
BNE CPINLD;Exit with reply (Note MIDTX undefined)
}
.CPIXTB
EQUB 2;Table of length of data
EQUB 8
EQUB 3
EQUB 1
.CPIATB
EQUB INFDTE;Offset of data in COWORK
EQUB INFLOA
EQUB INFSZE
EQUB INFACC
.CPYLXS
;Copy load/exec/size/access/date into MIDTX
LDA #2
JSR COCOPY;Load/exec
LDA #3
JSR COCOPY;Size
LDA #4
JSR COCOPY;access
LDA #1;creation date
;Fall through into last call of COCOPY
.COCOPY
{
;Copy some object attribute from COWORK into MIDTX
;offset by X. Attribute length and value is determined
;by A on entry which indexes into two tables
TAY
LDA CPIXTB - 1,Y
STA COTEMP;Set length to copy
LDA CPIATB - 1,Y
TAY ;Get offset in COWORK
.COCOP1
LDA COWORK,Y
STA MIDTX,X
INY
INX
DEC COTEMP
BNE COCOP1
RTS ;Note assumed elsewhere always exit EQ
}
.CPSTAT
{
;Set object attributes according to arg.
;1 => set load/execute/access
;2 => set load address
;3 => set execute address
;4 => set access byte
;5 => set date bytes ** 5/9/84 **
;Basically just a call to DIRMAN.SETATTRIBS
JSR STKUSE
BNE ATTLZZ
LDX BPTR
LDA MIDRX,X
BEQ ATTL1
CMP #6;** 5/9/84 **
BCC ATTL2;Arg ok, continue
.ATTL1
LDA #INFERA;Error in arg.
JMP ERROR
.ATTL2
TAY
LDA DRSAT2 - 1,Y;Note uses table in DIPMAN to get data length
BEQ ATTLXX;If setting zero number of bytes, exit
CLC
ADC #HDRLEN + 1;Get offset of file title in RX buffer
LDY #ARGC
JSR SETFTP;Set pointer to file title
INY ;ARGF here
LDA #&C0
STA (NEWARG),Y;wild card flag
LDX BPTR
.ATTL3
INY
LDA MIDRX,X;Load arg. to DIRMAN.SETATTRIBS
STA (NEWARG),Y
INX
CPY #ARGH + 9
BNE ATTL3
;Stack now all set, call DIRMAN.SETATTRIBS
LDA #4
JSR SETRTN
JSR DIRMAN
.ATTLXX
JSR RCODE
.ATTLZZ
JMP COMRTS
}
.CPDEL
{
;Non-command line call to delete object, and return
;object information after deletion.
JSR STKUSE
BNE CPDELZ
LDA #HDRLEN;Offset of file title
JSR CPRETR;Retrieve details of object to delete
BNE CPDELX;No good, error
JSR STKUSA;Reset user pointer on stack
LDA #HDRLEN;File title offset
JSR SETFTP;Set file title pointer
LDA #3
JSR SETRTN
LDY #ARGG
LDA #&80
STA (NEWARG),Y;wild card flag
JSR DIRMAN;** Call DIRMAN.DELETE **
BNE CPDELX;Error
LDX #0;Set offset from MIDTX for file details
JSR CPYLXS;Copy the whole lot over
CLC
TXA
ADC #TXHDR;Length of message
STA LAST
JSR OBJCLR;Clear object out of map
BEQ CPDELY
.CPDELX
JSR RCODE;Send error return
.*CPDELZ
JMP COMRTS;And finish
.CPDELY
LDA LAST
BNE USRENX
}
.USRENV
{
;Return user environment information.
; 1) Call DIRMAN.EXAMINE to get dir. name, and disc
; number of CSD.
; 3) Call MAPMAN.DISCNAME to get name of disc with
; given disc number.
; 4) Call DIRMAN.EXAMINE to get title of LIB.
JSR GETUSR
BNE CPDELZ
LDX BPTR
LDA #TERMIN
STA MIDRX,X;Fool DIRINF into getting CSD info.
LDA #17;Offset from MIDTX for dir. title
JSR DIRINF;Read dir. information
BNE USRENZ;Error -> bomb out
LDA #1;Offset from MIDTX for disc name
JSR CPDNAM;Read disc name (note assumes disc no. on stack)
BNE USRENZ
LDX BPTR
LDA CPLIB,X;Read library handle
LDY #UTHSLD
STA (USTPTR),Y;Set as CSD of user
LDA #27;Offset from MIDTX of LIB name
JSR DIRINF;Entry point not changing CSD handle
BNE USRENZ
LDA #DNAMLN;Disc name length
STA MIDTX
LDA #0
STA CCODE
LDA #TXHDR + 37;Message length
.*USRENX
JSR REPLYC
JMP COMRTS
.USRENZ
JMP ERROR
}
;*************
;* L O G O N *
;*************
.LOGON
{
JSR SPACES
.LGONLP
LDA MIDRX,Y;Step past station if present
CMP #'.';Network number terminator - special case
BEQ LGONL1
CMP #'0'
BCC LGONON;On if <0
CMP #':';On if >9
BCS LGONON
.LGONL1
INY
BNE LGONLP
.LGONON
JSR BUFTXT;Read User
BNE LOGRTS
INX ;Step past CR between userid & pw
JSR BTXTA
BNE LOGRTS
JSR COMEND;Check to end of C.line
BNE LOGRTS
LDY #ARGB
LDX QPTR
LDA CBSTID,X
STA (NEWARG),Y
STA MCNUMB
INY
LDA CBSTID+1,X
STA (NEWARG),Y
STA MCNUMB+1
INY
LDA CBFLG,X
AND #&78
STA (NEWARG),Y;pass station id
STA MCNUMB+2
JSR SBUFPT;pointer to TXTBUF
LDA #1
JSR SETRTN
JSR USRMAN;attempt logon
BNE LOGERR;failed
LDY #ARGH;test for priv'd logon
LDA (NEWARG),Y
BNE LOGJ1;no monitor for priv'd users
BIT MONFLG
BPL LOGJ1;skip if monitor off anyway
LDY QPTR
JSR PRTMC;output mc number
JSR VSTRIN
EQUB ": I am "
NOP
LDX #0
.LOGJ2
LDA TXTBUF,X
INX
JSR OSASCI;print the user name
CMP #CR
BNE LOGJ2
.LOGJ1
LDY #ARGG
LDX #3
.LGLPAA
LDA (NEWARG),Y;Get UFD/CSD/LIB handles + option byte
STA MIDTX,X
DEY
DEX
BPL LGLPAA
LDA #CCLGON
STA CCODE
LDA #TXHDR + 4;Message length
JSR REPLYC;Send handles etc. back
.LOGRTS
JMP COMRTS;FINISH
.LOGERR
JMP ERROR
}
;***************
;* L O G O F F *
;***************
.USROFF
{
;(LABEL USROFF TO AVOID NAME CLASH
;WITH USRMAN ROUTINE)
;SET UP ARGS FOR LOGOFF (DELETE USER)
;IN USERMAN, CALL, AND SEND APPROPRIATE
;MESSAGE BACK TO CLIENT.
JSR COMEND
BNE USROEX
;nice if this returns no error if not logged on ** 5/9/84 **
.*FCBYE
JSR GETUSE
BEQ USROL1;check for logged on user here
LDA #0
BEQ USROEZ;exit ok
.USROL1
JSR STKUSE;Entry by function code
BNE USROEX
LDA #2;LOGOFF ROUTINE NUMBER
JSR SETRTN
JSR USRMAN
.USROEZ
JSR RCODE
.USROEX
JMP COMRTS
}
.CPSOPT
{
;Set USER OPTION in pw file
;Just call appropriate AUTMAN routine
JSR STKUSE
BNE CPSOEX
LDA MIDRX,X;Note assumes X is BPTR here
CMP #&10;Check option <16
BCS CPSOER
INY
STA (NEWARG),Y
LDY #UTPRIV
LDA (USTPTR),Y
AND #LOCKPV
BNE CPSOES;USER NOT ALLOWED TO CHANGE OPTIONS
LDA #7
JSR SETRTN
JSR AUTMAN;Call AUTMAN.USEROPTION
.CPSOEZ
JSR RCODE
.CPSOEX
JMP COMRTS
.CPSOER
LDA #INFERA;Bad arg
BNE CPSOEZ
.CPSOES
LDA #ATERRD
BNE CPSOEZ
}
;************************
;* S E L E C T D I S C *
;************************
.SELDSC;SELDSC
{
;ALL WORK DONE IN USRMAN.
JSR RDTITL;GET DISC NAME ON STACK
BNE SELDEX
LDA #&A
JSR SETRTN
JSR SBUFPT
JSR MAPMAN;*** GET DISC NO FOR NAME **
BNE SELDER
LDY #ARGB
LDA (NEWARG),Y
PHA
INY
LDA (NEWARG),Y
INY
INY
STA (NEWARG),Y;MOVE DISC. NO. UP TO MAKE WAY FOR USRPTR
DEY
PLA
STA (NEWARG),Y
JSR STKUSE;SET USER POINTER
BNE SELDEX
LDY #ARGF
JSR STKHND;PUT 3 HANDLES ON STACK
LDA #3
JSR SETRTN
JSR USRMAN;*** SELECT DISC **
BNE SELDER
LDY #ARGD
LDX #2
.SDISLP
LDA (NEWARG),Y
STA MIDTX,X
DEY
DEX
BPL SDISLP
LDA #CCSDIS
STA CCODE
LDA #TXHDR + 3;MESSAGE LENGTH
JSR REPLYC
.SELDEX
JMP COMRTS
.SELDER
JMP ERROR
}
;**********************
;* S E L E C T D I R *
;**********************
.SELDIR;SELDIR
{
;ALL WORK DONE BY USERMAN AGAIN.
JSR RDTITL
BNE SDIREX
JSR STKUSE
BNE SDIREX
JSR SBUFPT;** 5/9/84 **
LDY #ARGF
JSR STKHND;Handles -> stack
JSR SELHAN
BNE SDIRER;error in allocation
LDA #CCSDIR
.*SLIBND ;SHARED WITH SLIB
STA CCODE
LDA #TXHDR + 1;Message length
JSR REPLYC
.SDIREX
.*SLIBEX
JMP COMRTS
.SDIRER
.*SLIBAB
JMP ERROR
}
.SELHAN
{
LDA #5;ROUTINE NUMBER
JSR SETRTN
JSR USRMAN;*** SELECT DIR. **
BNE SELHEX;exit if fail
LDY #ARGB
LDA (NEWARG),Y
STA MIDTX;New s.dir
LDA #0
.SELHEX
RTS
}
;******************************
;* S E L E C T L I B R A R Y *
;******************************
.SLIB;SLIB
{
;as for DIR but null filename is illegal
;if RETRIEVE ok then call USRMAN with LIB as CSD
JSR RDTITL
BNE SLIBEX
JSR STKUSE
BNE SLIBEX
JSR SBUFPT
JSR SCOWPT;Set pointer to COWORK on stack
LDA #2;Dirman retrieve
JSR SETRTN
LDY #ARGH
LDA #&C0
STA (NEWARG),Y;wild card flag
JSR DIRMAN;*** RETRIEVE **
BNE SLIBAB
JSR STKUSE
BNE SLIBEX
JSR SBUFPT
JSR SCOWPT;Set pointer to COWORK on stack
LDY #ARGF
JSR STKHND;handles -> stack
LDY #ARGH
LDA (NEWARG),Y
DEY
STA (NEWARG),Y;LIB->CSD
JSR SELHAN;** 5/9/84 **
BNE SLIBAB;error in allocation
LDA #CCSLIB
BNE SLIBND
}
;*********************
;* S E T A C C E S S *
;*********************
.SETACC
{
;1) PUT USER INFO. POINTER AND FILE TITLE
;POINTER ON STACK.
;2) INTERPRET STRING SENT FROM CLIENT INTO
;AN ACCESS BYTE AND STICK ON STACK.
;3) CALL SETATTRIBS IN DIRMAN
;4) REPLY TO CLIENT
JSR BUFTXT;Get file name
BNE SAEXIT
STY COWORK;Store cmnd. line ptr.
JSR STKUSE
BNE SAEXIT
JSR SBUFPT
LDY COWORK;Restore cmnd. line ptr.
JSR SPACES
LDA #0
STA COZERO;Partial result
DEY
.SALPB
INY
LDX #2;Offset into access tables
JSR CMPACC;Compare letter at Y with access tables
BEQ SALPB;Access letter found
CMP #'/';Owner access delimiter
BEQ SAONF
JSR SPACER;skip trailing spaces ** 25/5/83 **
CMP #CR
BNE SAERR;Invalid character => error
DEY ;Point to CR so will exit after rotating COZERO
.SAONF
ASL COZERO;Rotate access bits to owner position
ASL COZERO
.SALPC
INY ;Increment past '/' delimiter
LDX #1
JSR CMPACC
BEQ SALPC
JSR SPACER;skip trailing spaces ** 25/5/83 **
CMP #CR
BNE SAERR;If here, CR has terminated string => set access
LDY #ARGF
LDA #&C0
STA (NEWARG),Y;wild cards flag
LDA #4
INY ;Set arg to SETATTRIBS => SETACCESS
STA (NEWARG),Y
INY
LDA COZERO;Restore access byte
STA (NEWARG),Y;SET ACCESS BITS
LDA #4;SETACC ROUTINE NO.
JSR SETRTN
JSR DIRMAN;*** SET ACCESS **
JSR RCODE;SEND REPLY
.SAEXIT
JMP COMRTS;FINISH
.SAERR
LDA #SAERRA;BAD ACCESS STRING ERROR
JMP ERROR
.OWNTAB
EQUB "R"
EQUB "W"
EQUB "L"
.POWNTB
EQUB 1;OWNER READ
EQUB 2;OWNER WRITE
EQUB 4
.CMPACC
LDA MIDRX,Y
EOR OWNTAB,X
AND #&DF;Compare with cases forced
BEQ CMPAEX
DEX
BPL CMPACC
LDA MIDRX,Y;Exit, A = char, Z unset
RTS
.CMPAEX
LDA POWNTB,X
ORA COZERO
STA COZERO;Update partial result
LDX #0;Set Z flag; note A corrupted
RTS
}
;******************
;* N E W U S E R *
;******************
.NEWUSE
;ALL WORK DONE IN AUTMAN, ROUTINE NO. 1
JSR RDTITL;Get user name
BNE NUEXIT
JSR STKUSE;Stack caller's user info
BNE NUEXIT
JSR SBUFPT;Stack new user ptr.
LDA #1
.DOUSE
JSR SETRTN;SET ROUTINE NUMBER
JSR AUTMAN;DO NEW USER
JSR RCODE;SEND RETURN CODE
.RUEXIT;Shared with REMUSE
.SPWEXT;Shared with USERIN
.NUEXIT
JMP COMRTS;FINISH
;************************
;* R E M O V E U S E R *
;************************
.REMUSE
;REMARKABLY SIMILAR TO NEWUSER
JSR RDTITL
BNE RUEXIT
JSR STKUSE
BNE RUEXIT
JSR SBUFPT
LDA #4
BNE DOUSE;Always jump
;**************************
;* S E T P A S S W O R D *
;**************************
.SETPW
{
;GET USER INFO AND CALL ROUTINE IN AUTMAN
;TO DO WORK.
JSR BUFTXT;Buffer old pw
BNE SPWEXT
INX ;Ptr. to next free spot in TXTBUF
JSR BTXTA;Buffer new pw
BNE SPWEXT
JSR COMEND
BNE SPWEXT
BIT MONFLG;Do monitor message specially to avoid PW
BPL SETPW1;No monitor -> carry on
LDY QPTR;Point to RX control block
JSR PRTMC;Print machine number
JSR VSTRIN
EQUB ": Pass",CR
NOP
.SETPW1
JSR STKUSE
BNE SPWEXT
JSR SBUFPT
LDY #UTPRIV
LDA (USTPTR),Y
AND #LOCKPV
BNE STPWER;USER NOT ALLOWED TO CHANGE PASSWORD
LDA #3;ROUTINE NUMBER
BNE DOUSE;Always jump
.STPWER
LDA ATERRD
JMP ERROR
}
;**********************
;* C R E A T E D I R *
;**********************
.CDIRFN
{
JSR STKUSE
BNE CDIREX
LDY BPTR
INY
JSR RDTITL
BNE CDIREX
LDY BPTR
LDA MIDRX,Y
BEQ CDIRZ;zero is a silly number
CMP #HI(MAXDIR)+1
BCS CDIRZ
BCC CDIRC;check for overflow
.*CDIR;CDIR
;PASS USER INFO AND DIRECTORY NAME
;TO DIRMAN. THEN CLEAN UP IF NECCESSARY.
JSR RDTITL
BNE CDIREX
LDA #2;size of directory
.CDIRC
CMP CACHSZ+1;** 31/1/85
BCS CDIRZ
LDY #ARGF
STA (NEWARG),Y
INY
LDA #&80;** 11/10/84 **
STA (NEWARG),Y;wild card flag
JSR STKUSE
BNE CDIREX
JSR SBUFPT
LDA #5;CREATE DIR. FUNCTION CODE
JSR SETRTN
JSR DIRMAN;*** DO DIR. CREATE **
BNE CDIRY
JSR OBJCLR;CLEAR OLD OBJECT
.CDIRY
JSR RCODE;store RC
.*SPEXIT;Shared with SETPRIV
.CDIREX
JMP COMRTS
.CDIRZ
LDA #DRERRP
JMP ERROR
}
;******************
;* S E T P R I V *
;******************
.STPRIV
{
;MOST WORK DONE BY AUTMAN
JSR BUFTXT;MOVE USER ID.
BNE SPEXIT
STY COWORK
JSR STKUSE
BNE SPEXIT
JSR SBUFPT
LDY COWORK
JSR SPACES
AND #&DF;Force upper case
CMP #'S';SYSTEM USER
BEQ SPRONA
CMP #'L';LOCK PRIVILEGES
BEQ SPRONC
CMP #CR;NON-SYSTEM USER ??
BNE SPRIER
LDA #0;NON-SYST. USER
BEQ SPRONB
.SPRONA
INY
JSR COMEND
BNE SPEXIT
LDA #1;SYSTEM USER !
.SPRONB
LDY #ARGF
STA (NEWARG),Y;Set user's priv. flag
LDA #5;SET PRIV.
JMP DOUSE
.SPRIER
LDA #SPERRA
.SPRIEX
JMP ERROR
.SPRONC
INY
JSR COMEND
BNE SPEXIT
LDA #2
BNE SPRONB
}
;*************
;* D I S C S *
;*************
.DISCS;DISCS
{
;Provide list of discs currently on system.
;User supplies entry (drive) number, and
;number of drives. For each drive he is interested in,
;call MAPMAN once to get disc number
;and again to get disc name.
LDA #0
STA COZERO;No. of drives found
LDA BBUF
CLC
ADC #TXHDR + 1;Result buffer
STA COZERO + 1
LDA BBUF + 1
ADC #0
STA COZERO + 2
.DSCSLA
LDX BPTR
LDA MIDRX,X
CMP DRIVES
BCS DSCSLB;User drive >= drives
LDY #0
STA (COZERO + 1),Y;Result drive no.