-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathhistoria.asm
executable file
·1837 lines (1789 loc) · 45.7 KB
/
historia.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;
; Historia para Zombie Near
;
; por Oscar Toledo Guti‚rrez
;
; (c) Copyright 2011 Oscar Toledo Guti‚rrez
;
; Creaci¢n: 17-ene-2011.
; Revisi¢n: 26-mar-2011. Se elimina opci¢n para mostrar fotos de
; desarrolladores. Adaptado para presentaci¢n
; armada por partes. La etiqueta del edificio
; se pone por separado. Los retratos ahora
; est n compactados. La tabla aleatoria se
; compacta.
; Revisi¢n: 27-mar-2011. Modificado para ROM linear de 64K.
; Revisi¢n: 28-mar-2011. Desactiva la pantalla mientras arma la
; presentaci¢n. Se cambia el tama¤o de la
; imagen de personaje en el t¡tulo a 128x128 y
; el texto "COMPLEJO" a 96x16, desaparecen
; adem s los zombies en portada, quedan solo
; en historia. Copyright redimensionado a
; 128x16. Paneles redimensionados a 128x64.
; T¡tulo 2 redimensionado a 128x112. M s
; optimizaciones.
; Revisi¢n: 29-mar-2011. Se agregan sonidos al mover la pistola y
; seleccionar opci¢n. M s optimizaciones. Se
; intercambian colores de la pistola por
; redise¤o del sprite.
; Revisi¢n: 31-mar-2011. Cambia la m£sica al pasar de nivel. Utiliza
; el registro R para mover puntos
; aleatoriamente en vez de la enorme tabla.
; Revisi¢n: 01-abr-2011. Se modifica historia para el nuevo formato
; con byte de retrato y ancho combinados.
; Muestra la nueva historia para el mapa 4.
; Revisi¢n: 09-abr-2011. Se reduce m s el c¢digo para puntos
; aleatorios.
; Revisi¢n: 14-abr-2011. Se agrega la parte del beso :). M s c¢digo
; para depuraci¢n de retratos. Se integra un
; tercer t¡tulo para cuando se gana dos veces.
; Revisi¢n: 15-abr-2011. La pistola ahora se mueve de 15 pixeles en
; vez de 16. Se cambia el orden de los t¡tulos
; para mostrar primero la cient¡fica, despu‚s
; Delta-2 y luego Delta-1. Correcci¢n en
; toma_final al salir de helic¢ptero para
; mostrar "FIN", en una oportunidad en mil no
; dejaba bien inicializado el buffer de
; pantalla y quedaba mal una l¡nea del "FIN"
; Ajuste en posici¢n de mensaje beso. Mejoras
; en posiciones iniciales de puntos aleatorios
; Revisi¢n: 16-abr-2011. Se mueven las aspas del helic¢ptero a otro
; segmento. Pone melod¡a de amor.
; Revisi¢n: 26-abr-2011. Algunas peque¤as optimizaciones. Al cambiar
; de mapa no reiniciaba los bits para la
; habitaci¢n de pascua.
;
;
; La presentaci¢n
;
; Puede ponerse voz usando el truco PCM del PSG
;
presentacion:
.0:
call inicia_sonido
call limpia_sprites
ld hl,modo
res 2,(hl)
set 0,(hl)
xor a
ld (estado),a
halt
; Prueba de retratos para ajustar pixel por pixel.
; Ugh! eso fue dif¡cil 10-ene-2011
if 0
.888:
ld hl,retrato_investigadora
ld de,$0000
call carga_retrato
ld hl,retrato_jefe
ld de,$0040
call carga_retrato
ld hl,retrato_investigadora3
ld de,$0080
call carga_retrato
ld hl,retrato_jefe3a
ld de,$00c0
call carga_retrato
ld hl,retrato_jefe3b
ld de,$08c0
call carga_retrato
ld hl,retrato_telefonista
ld de,$0800
call carga_retrato
ld hl,retrato_beso1
ld de,$0840
call carga_retrato
ld hl,retrato_beso2
ld de,$0880
call carga_retrato
ld hl,retrato_delta_1
ld de,$1000
call carga_retrato
ld hl,retrato_delta_2
ld de,$1040
call carga_retrato
ld hl,retrato_zombies_1
ld de,$1080
call carga_retrato
ld hl,retrato_zombies_2
ld de,$10c0
call carga_retrato
ld b,200
halt
djnz $-1
ld hl,retrato_investigadora2
ld de,$0080
call carga_retrato
ld hl,retrato_jefe2a
ld de,$00c0
call carga_retrato
ld hl,retrato_jefe2b
ld de,$08c0
call carga_retrato
ld b,200
halt
djnz $-1
jp .888
endif
; Para probar las tomas compactadas con RLE base
if 0
.889: LD HL,GRAFICA_ALERTA_EN AND $FFFF
LD B,4
CALL CARGAR_TOMA
call retardo_cuadro
LD HL,GRAFICA_ALERTA_ES AND $FFFF
LD B,4
CALL CARGAR_TOMA
call retardo_cuadro
LD HL,GRAFICA_HELICOPTERO AND $FFFF
LD B,2
CALL CARGAR_TOMA
call retardo_cuadro
LD HL,GRAFICA_FIN_EN AND $FFFF
LD B,4
CALL CARGAR_TOMA
call retardo_cuadro
LD HL,GRAFICA_FIN_ES AND $FFFF
LD B,4
CALL CARGAR_TOMA
call retardo_cuadro
jr .889
endif
CALL PANTALLA_NEGRA
ld hl,modo ; Permite acceso directo al sonido
set 3,(hl)
call desactiva_video
; Carga pantalla de t¡tulo
;
; Presentaci¢n compactada (son 12288 bytes si no se compacta)
;
; Los zombies ahora se ven cuadrados, retirado 28-mar-2010
; ld hl,retrato_zombies_1
; ld de,$0000
; ld a,retrato_zombies_1>>16
; call carga_retrato
; ld hl,retrato_zombies_2
; ld de,$0040
; ld a,retrato_zombies_2>>16
; call carga_retrato
ld a,(ganado)
.559: sub 3
jr nc,.559
add a,3
ld hl,$0400
ld bc,$1080
ld de,GRAFICA_TITULO_1 AND $FFFF
cp 2
jr z,.555
ld hl,$0500
ld bc,$0e80
ld de,GRAFICA_TITULO_2 AND $FFFF
dec a
jr z,.555
ld hl,$0000
ld bc,$1880
ld de,GRAFICA_TITULO_3 AND $FFFF
.555: call descompacta_rle_imagen
ld de,GRAFICA_LOGO AND $FFFF
ld hl,$0080
ld bc,$0b78
call descompacta_rle_imagen
ld de,GRAFICA_COPYRIGHT AND $FFFF
ld hl,$1680
ld bc,$0280
call descompacta_rle_imagen
ld a,(idioma)
or a
ld de,GRAFICA_PANEL_EN AND $FFFF
jr z,.556
ld de,GRAFICA_PANEL_ES AND $FFFF
.556: ld hl,$0d80
ld bc,$0880
call descompacta_rle_imagen
;
; Vuelve a definir sprite pistola en sprites h‚roes
; y restaura dos sprites que pueden ser borrados por historia
;
ld hl,modo
res 0,(hl)
ld a,(ganado)
rrca
LD HL,figuras_sprites
jr nc,.557
LD HL,sprites_heroes+$90*8
.557: LD DE,$1800
LD BC,$0040
CALL LDIRVM
LD HL,figuras_sprites+64
LD DE,$1840
LD BC,$0040
CALL LDIRVM
;
; Record
;
ld a,(quien)
or a ; ¨Record establecido?
jr z,.558 ; No, salta
ld hl,bits1
ld (hl),$08 ; H
inc hl
ld (hl),$09 ; I
inc hl
ld (hl),$00
inc hl
ld a,(record)
call dos_digitos
ld a,(record+1)
call dos_digitos
ld a,(record+2)
call dos_digitos
ld (hl),$20
inc hl
ld (hl),$00
inc hl
ld a,(quien)
add a,$20
ld (hl),a
inc hl
ld (hl),$15 ; U
inc hl
ld (hl),$90 ; P
ld hl,$0c88
ld de,bits1
ld c,$e1
call visual_mensaje1
.558:
;
; Antirebote
;
IF 0
.7: ld b,5
.2: halt
call boton_oprimido
jr z,.7
djnz .2
ENDIF
call activa_video
ld hl,modo
set 0,(hl) ; Controla sprites y pantalla
ld hl,sprites
ld (hl),$69
inc hl
ld (hl),$88
inc hl
ld (hl),$04 ; La pistola (color obscuro)
inc hl
ld (hl),$0E
inc hl
ld (hl),$69
inc hl
ld (hl),$88
inc hl
ld (hl),$00 ; La pistola (color brillante)
inc hl
ld (hl),$0F
.906:
ld de,(ticks)
.1: halt
if programador=1
ld a,(tecla)
cp $37 ; ¨F3?
jr nz,.907
ld a,$ff
ld (tecla),a
ld a,1 ; Activa depuraci¢n
ld (depura),a
.907:
ld a,(tecla)
cp $36 ; ¨F2?
jr nz,.908
ld a,$ff
ld (tecla),a
ld a,(depura)
cp 1
ld a,2
jr z,.911
xor a
.911: ld (depura),a
.908:
endif
ld a,(tecla)
cp $35 ; ¨F1?
jr nz,.909
ld a,$ff
ld (tecla),a
if programador=1
ld a,(depura)
cp 2 ; ¨Haciendo truco?
ld a,3 ; S¡, pr¢ximo paso
jr z,.910
xor a ; No, cambia idioma
ld (depura),a
endif
ld a,(idioma)
xor 1 ; Cambio de idioma
ld (idioma),a
pop af
jp reinicio
if programador=1
.910: ld (depura),a
endif
.909: ld a,(ticks)
and 12
ld bc,$0E0F
jr nz,.3
ld bc,$0101
.3: ld a,b
ld (sprites+3),a
ld a,c
ld (sprites+7),a
call boton_oprimido ; ¨Se oprimi¢ alg£n bot¢n?
jp z,programa_sonido_sel ; Retorna al mismo tiempo que pone sonido
xor a ; Cursor
push de
call GTSTCK
pop de
cp 1 ; ¨Arriba?
jr z,.900
cp 5 ; ¨Abajo?
jr z,.901
ld a,1 ; Joystick 1
push de
call GTSTCK
pop de
cp 1 ; ¨Arriba?
jr z,.900
cp 5 ; ¨Abajo?
jr z,.901
ld hl,(ticks)
or a
sbc hl,de
ld bc,800 ; ¨Transcurridos 16 segundos?
sbc hl,bc
jp c,.1
jp .902
; Pistola arriba
.900:
ld a,(sprites)
cp $69
jr z,.903
sub $0F
jr .903
; Pistola abajo
.901: ld a,(sprites)
cp $87
jr z,.903
add a,$0F
.903: ld (sprites),a
ld (sprites+4),a
ld hl,tabla_psg1
call programa_sonido
ld de,(ticks)
.904: halt
ld a,(ticks)
and 12
ld bc,$0e0f
jr nz,.905
ld bc,$0101
.905: ld a,b
ld (sprites+3),a
ld a,c
ld (sprites+7),a
call boton_oprimido ; ¨Se oprimi¢ alg£n bot¢n?
jp z,programa_sonido_sel ; Retorna al mismo tiempo que pone sonido
ld hl,(ticks)
or a
sbc hl,de
ld bc,18
sbc hl,bc
jr c,.904
jp .906
;
; Comienza la historia, empezando por una pantalla de alerta
; estilo cine con chicharra inclu¡da.
;
.902:
call limpia_sprites
halt
ld a,(idioma)
or a
LD HL,GRAFICA_ALERTA_EN AND $FFFF
jr z,.913
LD HL,GRAFICA_ALERTA_ES AND $FFFF
.913: LD B,4
CALL CARGAR_TOMA
;
; Programa sonido
;
ld hl,tabla_psg
call programa_sonido
;
; El truco es que el fondo es transparente
;
ld a,6
ld (estado),a
ld de,(ticks)
.4: halt
call boton_oprimido ; ¨Se oprimi¢ alg£n bot¢n?
jp z,.0
ld hl,(ticks)
or a
sbc hl,de
ld bc,200 ; ¨Transcurridos 4 segundos?
sbc hl,bc
jr c,.4
xor a
ld (estado),a
ld bc,$0107
call WRTVDP
call presentacion_limpia
call musica_historia
;
; Todos los cuadros de personaje son de 64x64 pixeles, 1024 bytes,
; se desplazan utilizando truco directo tabla de caracteres.
;
ld hl,retrato_investigadora ; Retrato de chica investigadora
ld de,$08c0
; ld a,retrato_investigadora>>16
call carga_retrato
call entrada_derecha
; "Security failure"
ld hl,$11a8
ld de,mensaje_1
call visual_mensaje_idioma
call retardo_cuadro
ld hl,retrato_jefe ; Retrato de jefe de investigaci¢n
ld de,$0800
; ld a,retrato_jefe>>16
call carga_retrato
call entrada_izquierda
ld hl,$1108
ld de,mensaje_2
call visual_mensaje_idioma
call retardo_cuadro
;
; Edificio compactado, solo verde m s sprites
;
CALL PANTALLA_NEGRA_RAPIDA
ld hl,modo
res 0,(hl)
LD HL,sprites_heroes+$400
LD DE,$1840
LD BC,$0040
CALL LDIRVM
call desactiva_video
LD de,GRAFICA_EDIFICIO AND $FFFF
ld hl,$0000
ld bc,$1800
call descompacta_rle_imagen
ld a,(idioma)
or a
ld de,GRAFICA_COMPLEJO_EN AND $FFFF
jr z,.912
ld de,GRAFICA_COMPLEJO_ES AND $FFFF
.912: ld hl,$0050
ld bc,$0260
call descompacta_rle_imagen
ld hl,$1420
ld de,mensaje_11 ; "INFECTION"
call visual_mensaje_idioma
ld hl,$14A0
ld de,mensaje_11 ; "INFECTION"
call visual_mensaje_idioma
call activa_video
ld hl,$2020
ld (bits1),hl
ld a,$b1
ld (bits1+2),a
LD HL,tabla_puntos
ld de,sprites
ld bc,48
ldir
ld de,(ticks)
.800: ld a,(ticks)
ld b,a
halt
ld a,(ticks)
cp b
jr z,.800
push de
bit 0,a
jr z,.805
;
; Mueve puntos seudoaleatoriamente
;
ld hl,sprites
ld de,tabla_puntos
ld b,12
.803: ld a,r
and $03
ld c,a
ld a,(de)
add a,c
inc de
ld (hl),a
inc hl
ld a,r
and $03
dec a
bit 0,b
jr z,$+3
dec a
ld c,a
ld a,(hl)
add a,c
cp 24
jr nc,$+4
ld a,24
cp 96
jr c,$+4
ld a,96
inc de
ld (hl),a
inc hl
inc hl
ld a,(bits1)
sub $20
add a,a
cp b
jr c,.804
ld (hl),$09
.804: inc hl
inc de
inc de
djnz .803
;
; Para el otro edificio duplica los sprites de puntos
;
.805: ld hl,sprites
ld de,sprites+48
ld bc,$0cff
.809: ldi
ld a,(hl)
cpl
sub 15
ld (de),a
inc hl
inc de
ldi
ldi
djnz .809
ld hl,(bits1)
ld a,h
cp $28
jr nz,.806
ld a,l
cp $29
jr z,.807
.806: inc h
ld a,h
cp $2a
jr nz,.801
inc l
ld h,$20
.801: ld (bits1),hl
ld hl,$1638
ld de,bits1 ; Porcentaje
call visual_mensaje0
ld hl,$16b8
ld de,bits1 ; Porcentaje
call visual_mensaje0
.807: call boton_oprimido ; ¨Se oprimi¢ alg£n bot¢n?
pop de
jp z,presentacion
ld hl,(ticks)
or a
sbc hl,de
ld bc,300 ; ¨Transcurridos 6 segundos?
sbc hl,bc
jp c,.800
CALL limpia_sprites
halt
call presentacion_limpia
ld hl,retrato_investigadora ; Retrato de chica investigadora
ld de,$08c0
; ld a,retrato_investigadora>>16
call carga_retrato
call entrada_derecha
; "Them're through the building!"
ld hl,$1180
ld de,mensaje_3
call visual_mensaje_idioma
call retardo_cuadro
ld hl,retrato_jefe ; Retrato de jefe
ld de,$0800
; ld a,retrato_jefe>>16
call carga_retrato
call entrada_izquierda
; "Call the special team... What's that?"
ld hl,$1108
ld de,mensaje_4
call visual_mensaje_idioma
call retardo_cuadro
call presentacion_limpia
; "Oh my god!... gritos y luego est tica"
ld hl,$1150
ld de,mensaje_5
call visual_mensaje_idioma
call retardo_cuadro
ld hl,retrato_zombies_1 ; Retrato zombies (izq)
ld de,$0800
; ld a,retrato_zombies_1>>16
call carga_retrato
ld hl,retrato_zombies_2 ; Retrato zombies (der)
ld de,$08c0
; ld a,retrato_zombies_2>>16
call carga_retrato
call entrada_doble
ld hl,$1350
ld de,mensaje_6
call visual_mensaje_idioma
call retardo_cuadro
call presentacion_limpia
ld hl,retrato_telefonista ; Retrato de telefonista
ld de,$0060
; ld a,retrato_telefonista>>16
call carga_retrato
call entrada_arriba
; "Emergency! Calling special team"
ld hl,$0208
ld de,mensaje_7
call visual_mensaje_idioma
call retardo_cuadro
ld hl,retrato_delta_1 ; Retrato de Delta-1
ld de,$08c0
; ld a,retrato_delta_1>>16
call carga_retrato
call entrada_derecha
; "Delta 1 ready, I'll enter building A"
ld hl,$1188
ld de,mensaje_8
call visual_mensaje_idioma
call retardo_cuadro
ld hl,retrato_delta_2 ; Retrato de Delta-2
ld de,$0800
; ld a,retrato_delta_2>>16
call carga_retrato
call entrada_izquierda
; "Delta 2 ready, I'll enter building B"
ld hl,$1108
ld de,mensaje_9
call visual_mensaje_idioma
call retardo_cuadro
call retardo_cuadro
jp .0
;
; Tabla para puntos seudoaleatorios
;
tabla_puntos:
db 28 , 83 , 12 ,7
db 28 , 48 , 8 ,7
db 48 , 47 , 12 ,7
db 48 , 24 , 12 ,7
db 68 , 57 , 12 ,7
db 68 , 45 , 8 ,7
db 88 , 25 , 12 ,7
db 88 , 52 , 12 ,7
db 108 , 28 , 8 ,7
db 108 , 49 , 12 ,7
db 128 , 64 , 12 ,7
db 128 , 85 , 8 ,7
;
; Limpia solo la secci¢n de di logos
;
presentacion_limpia_2:
ld hl,modo
res 0,(hl)
ld hl,$3050
ld bc,$0008
xor a
call filvrm
ld hl,modo
set 0,(hl)
ld hl,pantalla+512
jp presentacion_limpia.1
;
; Limpia la pantalla en preparaci¢n para entrada de retratos
;
presentacion_limpia:
ld hl,modo
res 0,(hl)
ld hl,$2050 ; Caracter $0a
ld bc,$0008
xor a
call filvrm
ld hl,$2850
ld bc,$0008
call filvrm
ld hl,$3050
ld bc,$0008
call filvrm
ld hl,modo
set 0,(hl)
ld hl,pantalla
.1: ld (hl),10
inc hl
ld a,h
cp (pantalla+768)>>8
jr nz,.1
halt
ld hl,0
ld (offset),hl
halt
ld hl,384
ld (offset),hl
halt
ret
;
; Sonido de chicharra
;
tabla_psg:
db $00,$01
db $80,$02
db $c0,$04
db $04
db $b8
db $10
db $10
db $10
db $78,$0d
db $08
;
; Movimiento de pistola
;
tabla_psg1:
db $58,$03
db $ac,$01
db $d6,$00
db $00
db $b8
db $10
db $10
db $10
db $78,$04
db $09
;
; Selecci¢n de opci¢n
;
tabla_psg2:
db $d6,$00
db $a8,$00
db $8e,$00
db $00
db $b8
db $10
db $10
db $10
db $78,$20
db $09
;
; Programa una tabla completa de sonido
;
programa_sonido_sel:
ld hl,tabla_psg2
programa_sonido:
xor a
.950: ld e,(hl)
call WRTPSG
inc a
inc hl
cp 14
jr nz,.950
ret
;
; Detecta boton oprimido
; Devuelve A=$FF si bot¢n oprimido, de lo contrario $00
;
boton_oprimido:
push bc
push de
push hl
ld b,0
.1: push bc
ld a,b
call GTTRIG
pop bc
inc a ; ¨Se oprimi¢ alg£n bot¢n?
jr z,.2
inc b
ld a,b
sub 5
jr nz,.1
inc a ; Para que no sea cero
.2: pop hl
pop de
pop bc
ret
;
; Retardo por cuadro de presentaci¢n.
;
retardo_cuadro:
ld de,(ticks)
.1: halt
pop bc
call boton_oprimido ; ¨Se oprimi¢ alg£n bot¢n?
jp z,presentacion
push bc
ld hl,(ticks)
or a
sbc hl,de
ld bc,150 ; ¨Transcurridos 3 segundos?
sbc hl,bc
jr c,.1
ret
;
; Carga un retrato
;
carga_retrato:
ex de,hl
ld bc,$0840
jp descompacta_rle_imagen
;
; Entrada de retrato desde arriba
;
entrada_arriba:
halt
ld hl,$0000
ld (offset),hl
ld bc,$01ec
.1: halt
push bc
ld hl,pantalla+12
ld de,25
.2: ld (hl),c
inc c
inc hl
ld (hl),c
inc c
inc hl
ld (hl),c
inc c
inc hl
ld (hl),c
inc c
inc hl
ld (hl),c
inc c
inc hl
ld (hl),c
inc c
inc hl
ld (hl),c
inc c
inc hl
ld (hl),c
ld a,c
add a,25
ld c,a
add hl,de
djnz .2
pop bc
pop de
call boton_oprimido ; ¨Se oprimi¢ alg£n bot¢n?
jp z,presentacion
push de
ld a,c
sub 32
ld c,a
inc b
ld a,b
cp 9
jr nz,.1
ret
;
; Entrada de retrato desde izquierda
;
entrada_izquierda:
exx
ld bc,$0b01
exx
jp entrada_retrato
;
; Entrada de retrato desde derecha
;
entrada_derecha:
exx
ld bc,$0b02
exx
jp entrada_retrato
;
; Entrada de retratos dobles
;
entrada_doble:
exx
ld bc,$1103
exx
entrada_retrato:
halt
ld hl,$0100
ld (offset),hl
ld bc,$0107
.1: halt
ld hl,pantalla+$0100
ld de,32
exx
bit 0,c
exx
jr z,.8
push bc
.2: push hl
ld a,c
or a
jp p,.4
ld a,10
ld (hl),a
add hl,de
ld (hl),a
add hl,de
ld (hl),a
add hl,de
ld (hl),a
add hl,de
ld (hl),a
add hl,de
ld (hl),a
add hl,de
ld (hl),a
add hl,de
jr .5
.4: ld (hl),a
add a,e
add hl,de
ld (hl),a
add a,e
add hl,de
ld (hl),a
add a,e
add hl,de
ld (hl),a
add a,e
add hl,de
ld (hl),a
add a,e
add hl,de
ld (hl),a
add a,e
add hl,de
ld (hl),a
add a,e
add hl,de
.5: ld (hl),a
pop hl
inc c
inc hl
djnz .2
pop bc
.8: exx
bit 1,c