Simple I2S sketch produces no sound after restart

[Rylern]

Hello,

First of all thanks for this library, it's quite useful and easy to use.

I've got a Nano ESP32 (ESP32-S3, with Arduino) connected to a MAX98357A, itself connected to the speakers of an old laptop. I tested this library with the following code (a simple sine wave to I2S):

#include "AudioTools.h"


AudioInfo info(44100, 2, 16);
SineWaveGenerator<int16_t> sineWave(32000);
GeneratedSoundStream<int16_t> in(sineWave);
I2SStream i2s;
StreamCopy copier(i2s, in);


void setup(void) { 
  Serial.begin(115200);
  delay(5000);

  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  auto config = i2s.defaultConfig(TX_MODE);
  config.copyFrom(info);
  if (i2s.begin(config)) {
    Serial.println("I2S started successfully");
  } else {
    Serial.println("I2S failed to start!");
  }

  in.begin(info);
  sineWave.begin(info, N_B4);

  Serial.println("Setup Complete");
}
                           
void loop() {
  copier.copy();
}

It works correctly (no error message, I can hear some sound) when I upload the sketch from the Arduino IDE.

However, when I press the RST button of the ESP32 or when I unplug/plug the USB cable, there is no sound anymore even though no error is displayed (i2s.begin() is true, copier.copy() is true, I get the [I] StreamCopy.h : 168 - StreamCopy::copy 1024 -> 1024 -> 1024 bytes - in 1 hops messages when I set the logger to info).

It only works again when I first upload the I2S Simple Tone example sketch from the Arduino I2S library, and then upload the previous sketch. It also works when I upload the previous sketch several times in a row, but stops working as soon as I press the RST button of the ESP32 or when I unplug/plug the USB cable.

My guess is that it's an error with I2S that is not properly initialized. Have you encountered this before? If no, I can directly use the I2S Arduino library, but I want to see first if I can use audio-tools as it's much easier.

[pschatzmann]

No, that does not make any sense: Rebooting and resetting of the AudioKit with a regular ESP32 (which uses the same API) has always been working w/o issues.

I rather tend to think that it might be a hardware issue: did you try e.g. to connect the SD pin to 3.3V ?
Or maybe you use an ESP32 Arduino core version that does not support theS3 properly: The actual version is 3.1.1.

You can check if you can reproduce the issue also with the Arduino ESP32 I2S API...

[Rylern]

Thanks. I tried to connect the SD pin to 3.3V, I tried with both the latest version of the board from expressif and the board from Arduino, but that didn't change anything.

When you mention the ESP32 I2S API, are you talking about this:
https://docs.espressif.com/projects/arduino-esp32/en/latest/api/i2s.html
or that:
https://docs.espressif.com/projects/esp-idf/en/stable/esp32/api-reference/peripherals/i2s.html
?

If you refer to https://docs.espressif.com/projects/arduino-esp32/en/latest/api/i2s.html, I tried this simple program (a square wave to I2S, adapted from here) but I don't get any sound:

#include <ESP_I2S.h>

I2SClass I2S;
const int frequency = 440; // frequency of square wave in Hz
const byte amplitude = 255; // amplitude of square wave
const int sampleRate = 8000; // sample rate in Hz
const int halfWavelength = (sampleRate / frequency); // half wavelength of square wave
byte sample = amplitude; // current sample value
int count = 0;


void setup() {
  Serial.begin(115200);
  delay(5000);

  I2S.setPins(D7, D8, D9); //SCK, WS, SDOUT
  if (I2S.begin(I2S_MODE_STD, sampleRate, I2S_DATA_BIT_WIDTH_8BIT, I2S_SLOT_MODE_MONO)) {
    Serial.println("started");
  } else {
    Serial.println("error");
  }
}

void loop() {
  if (count % halfWavelength == 0 ) {
    // invert the sample every half wavelength count multiple to generate square wave
    sample = amplitude - sample;
  }

  I2S.write(sample);
  
  count++;
}

Would you have any idea why?

[pschatzmann]

Why don't you use your first example and just replace the I2SStream with I2SClass ?

If you keep the pins the same, it should be

 I2S.setPins(6, 7, 8); //BCK, WS, SDOUT

[Rylern]

Thanks, the following program works:

#include "AudioTools.h"
#include <ESP_I2S.h>


AudioInfo info(44100, 2, 16);
SineWaveGenerator<int16_t> sineWave(32000);
GeneratedSoundStream<int16_t> in(sineWave);
I2SClass i2s;
StreamCopy copier(i2s, in);


void setup(void) { 
  Serial.begin(115200);
  delay(5000);

  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  i2s.setPins(D7, D8, D9); //SCK, WS, SDOUT
  if (i2s.begin(I2S_MODE_STD, 44100, I2S_DATA_BIT_WIDTH_16BIT, I2S_SLOT_MODE_MONO)) {
    Serial.println("started");
  } else {
    Serial.println("error");
  }

  in.begin(info);
  sineWave.begin(info, N_B4);

  Serial.println("Setup Complete");
}
                           
void loop() {
  copier.copy();
}

And the original issue of this topic is fixed with this program, so I'll use it. Thanks