build.gradle

plugins {
    id "base"

    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "0.12.0-SNAPSHOT" apply false
}

architectury {
    minecraft = rootProject.minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        // The following line declares the mojmap mappings, you may use other mappings as well

        // The following line declares the yarn mappings you may select this one as well.
        mappings "net.fabricmc:yarn:${rootProject.yarn_version}:v2"

        // Mixin Extras for extra compatibility.
        implementation("com.github.LlamaLad7:MixinExtras:${project.mixin_extras_version}")

        annotationProcessor("com.github.LlamaLad7:MixinExtras:${project.mixin_extras_version}")
    }
}

tasks {
    // Register a custom "collect jars" task that copies the Fabric and Forge mod jars
    // into the root project's build/libs. This makes it easier to find them
    // for testing and releasing.
    def collectJars = tasks.register("collectJars", Copy) {copy ->

        subprojects.forEach {
            def task = it.tasks.getByName("remapJar")

            dependsOn(task)

            copy.from task
            copy.into buildDir.path + "/libs"
        }
    }

    // Set up assemble to depend on the collectJars task, so it gets run on gradlew build.
    assemble {
        dependsOn(collectJars)
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    archivesBaseName = rootProject.mod_id
    version = "${rootProject.mod_version}+${rootProject.minecraft_version}"
    group = rootProject.maven_group

    repositories {

        flatDir {
            dirs 'mods'
        }

        mavenLocal()

        maven { url 'https://maven.fabricmc.net' }

        // Add repositories to retrieve artifacts from in here.
        // You should only use this when depending on other mods because
        // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
        // See https://docs.gradle.org/current/userguide/declaring_repositories.html
        // for more information about repositories.
        maven {
            url = "https://www.cursemaven.com"
            allowInsecureProtocol = true
        }

        // Mod Menu.
        maven { url 'https://maven.terraformersmc.com' }

        // MidnightControls.
        maven {
            name 'Gegy'
            url 'https://maven.gegy.dev'
        }
        maven { url = "https://aperlambda.github.io/maven" }
        maven {
            name = "Modrinth"
            url = "https://api.modrinth.com/maven"
            content {
                includeGroup "maven.modrinth"
            }
        }

        // Cloth Config.
        maven { url "https://maven.shedaniel.me/" }
        maven { url "https://maven.terraformersmc.com/releases/" }

        // Jitpack for Mixin Extras.
        maven { url 'https://jitpack.io' }
    }

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
        options.release = 17
    }

    java {
        withSourcesJar()
    }
}

subprojects {
    tasks {
        if (!path.startsWith(":common")) {
            tasks.getByName("remapJar") {
                dependsOn("shadowJar")
                // The project name will be "fabric" or "forge", so this will become the classifier/suffix
                // for the jar. For example: do-a-barrel-roll-2.0.0+1.19.2-fabric.jar
                archiveClassifier.set(project.name)
            }
        }
    }
}