Option to expand for attribute to htmlFor?

[sooqua]

It's nice that there's an option to expand class as className, but how do I go about implementing the same for the for attribute in jsx?

[sooqua]

Quick fix:

(defun +web-emmet-make-tag-a (tag-maker tag-info &optional content)
  "Extract tag info and pass them to tag-maker."
  (let* ((name      (pop tag-info))
         (has-body? (pop tag-info))
         (id        (pop tag-info))
         (classes   (pop tag-info))
         (props     (pop tag-info))
         (txt       (pop tag-info))
         (settings  (gethash name emmet-tag-settings-table))
         (self-closing?
          (and (not (or txt content))
               (or  (not has-body?)
                    (and settings (gethash "selfClosing" settings))))))
    (when (string= name "label")
      (let ((defaultAttr (gethash "defaultAttr" settings)))
        (remhash "for" defaultAttr)
        (remhash "htmlFor" defaultAttr)
        (if (derived-mode-p 'rjsx-mode)
            (puthash "htmlFor" "" defaultAttr)
          (puthash "for" "" defaultAttr))))
    (funcall tag-maker name has-body? id classes props txt settings
             (if content content
               (if (and emmet-leaf-function (not self-closing?))
                   (funcall emmet-leaf-function))))))
(advice-add #'emmet-make-tag :override #'+web-emmet-make-tag-a)

[sooqua]

Or

(defun +web-emmet-make-tag-a (_ tag-info)
  (let ((name (car tag-info)))
    (when (string= name "label")
      (let ((defaultAttr (gethash "defaultAttr" (gethash name emmet-tag-settings-table))))
        (remhash "for" defaultAttr)
        (remhash "htmlFor" defaultAttr)
        (if (derived-mode-p 'rjsx-mode)
            (puthash "htmlFor" "" defaultAttr)
          (puthash "for" "" defaultAttr))))))
(advice-add #'emmet-make-tag :before #'+web-emmet-make-tag-a)