build.gradle

buildscript {
    if (file("/usr/share/proguard/lib").exists()) {
        repositories {
            flatDir dirs: '/usr/share/proguard/lib'
        }
    }

    dependencies {
        classpath 'de.sebastianboegl.gradle.plugins:shadow-log4j-transformer:2.2.0'
        if (file("/usr/share/proguard/lib").exists())
            classpath ':proguard:'
    }
}

plugins {
    id 'java'
    id 'idea'
    id 'application'
    id 'com.github.ben-manes.versions' version '0.22.0'
    id 'org.ajoberstar.grgit' version '3.1.1'
    id 'de.fuerstenau.buildconfig' version '1.1.8'
    id 'com.github.johnrengelman.shadow' version '5.1.0'
}

group 'com.kdrag0n'
version '0.9.1'
compileJava.options.encoding = 'UTF-8'

sourceCompatibility = 1.8
archivesBaseName = 'bluestone'
mainClassName = 'com.kdrag0n.bluestone.Bootstrap'
applicationDefaultJvmArgs = [
        '-Xms1000M',
        '-XX:MaxDirectMemorySize=64M',
        '-XX:MaxMetaspaceSize=95800K',
        '-XX:ReservedCodeCacheSize=240M',
        '-Xss1M',
        '-Xmx3641799K',
        '-Xverify:none',
        '-Djava.lang.invoke.stringConcat=MH_INLINE_SIZED_EXACT',
        '-XX:+UseG1GC',
        '-server',
        '-XX:+CMSClassUnloadingEnabled',
        '-XX:+AggressiveOpts',
        '-XX:MaxGCPauseMillis=2500'
]

import de.sebastianboegl.gradle.plugins.shadow.transformers.Log4j2PluginsFileTransformer

repositories {
    mavenCentral()
    jcenter()
    maven {
        name 'jitpack'
        url 'https://jitpack.io'
    }
}

ext {
    commit = "none"
    shortCommit = "none"
    buildTime = System.currentTimeMillis()

    if (grgit != null) {
        commit = grgit.head().id
        shortCommit = grgit.head().abbreviatedId
    }
}

buildConfig {
    appName = project.name
    version = project.version

    clsName = 'BuildConfig'
    packageName = 'com.kdrag0n.bluestone'
    charset = 'UTF-8'

    buildConfigField 'long', 'BUILD_UNIXTIME', buildTime + 'L'
    buildConfigField 'java.util.Date', 'BUILD_DATE', 'new java.util.Date(' + buildTime + 'L)'
    buildConfigField 'java.time.Instant', 'BUILD_INSTANT', 'java.time.Instant.ofEpochMilli(' + buildTime + 'L)'
    buildConfigField 'String', 'GIT_COMMIT', commit
    buildConfigField 'String', 'GIT_SHORT_COMMIT', shortCommit
}

shadowJar {
    transform(Log4j2PluginsFileTransformer)
    mergeServiceFiles()
    zip64 true
}

if (file("/usr/share/proguard/lib").exists()) {
    task proguard(type: proguard.gradle.ProGuardTask) {
        configuration 'proguard-rules.pro'

        injars "build/libs/bluestone-$version-all.jar"
        outjars "build/libs/bluestone-$version-pro.jar"
    }
}

dependencies {
    implementation 'net.dv8tion:JDA:4.0.0_39'
    implementation 'com.sedmelluq:lavaplayer:1.3.20'
    implementation 'com.squareup.okhttp3:okhttp:4.0.1'
    implementation 'com.google.guava:guava:28.0-jre'
    implementation 'org.json:json:20190722'
    implementation 'org.apache.commons:commons-lang3:3.9'
    implementation 'org.apache.commons:commons-text:1.7'
    implementation 'org.slf4j:slf4j-api:2.0.0-alpha0'
    implementation 'ch.qos.logback:logback-classic:1.3.0-alpha4'
    implementation 'com.j256.ormlite:ormlite-core:5.1' // --
    implementation 'com.j256.ormlite:ormlite-jdbc:5.1'
    implementation 'com.h2database:h2:1.4.199'
    implementation 'com.sedmelluq:jda-nas:1.1.0'
    implementation 'com.zaxxer:HikariCP:3.3.1'
    implementation 'org.mariadb.jdbc:mariadb-java-client:2.4.3'
    implementation 'net.sf.trove4j:trove4j:3.0.3'
    implementation 'com.jagrosh:jda-utilities-menu:3.0.1'
    implementation 'com.jagrosh:jda-utilities-commons:3.0.1'
    implementation 'com.joestelmach:natty:0.13'
    implementation 'com.twelvemonkeys.imageio:imageio-core:3.4.1'
    implementation 'com.google.re2j:re2j:1.3'
    implementation 'io.sentry:sentry-logback:1.7.26'
}