build.gradle

plugins {
	id 'org.springframework.boot' version '2.5.3'
	id 'io.spring.dependency-management' version '1.0.11.RELEASE'
	id 'java'
	id 'jacoco'
}

group = 'org.worldcubeassociation'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

ext {
	jacocoVersion = '0.8.6'
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

bootJar {
	archiveFileName = 'db-sanity-check.jar'
}

test {
	useJUnitPlatform()
	finalizedBy jacocoTestReport
}

jacoco {
	toolVersion = jacocoVersion
	reportsDirectory = file("$buildDir/reports/jacoco")
}

jacocoTestCoverageVerification {
	executionData fileTree("$buildDir/jacoco/").include("*.exec")

	afterEvaluate {
		classDirectories.setFrom(files(classDirectories.files.collect {
			fileTree(dir: it,
					exclude: ['**/config/**'
					]
			)
		}))
	}
	violationRules {
		rule {
			limit {
				minimum = 0.01
			}
		}
	}
}

jacocoTestReport {
	executionData fileTree("$buildDir/jacoco/").include("*.exec")

	reports {
		xml.enabled true
		csv.enabled false
		html.destination file("${buildDir}/reports/jacoco")
	}

	afterEvaluate {
		classDirectories.setFrom(files(classDirectories.files.collect {
			fileTree(dir: it,
					exclude: ['**/config/**']
			)
		}))
	}
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa:2.5.3'
	implementation 'org.springframework.boot:spring-boot-starter-mail:2.5.3'
	implementation 'org.springframework.boot:spring-boot-starter-data-jdbc:2.5.3'
	implementation 'org.springframework.boot:spring-boot-starter-jdbc:2.5.3'
	testImplementation 'org.springframework.boot:spring-boot-starter-test:2.5.3'
	developmentOnly 'org.springframework.boot:spring-boot-devtools:2.5.3'
	implementation 'org.projectlombok:lombok:1.18.20'
	compileOnly 'org.projectlombok:lombok:1.18.20'
	annotationProcessor 'org.projectlombok:lombok:1.18.20'

	testRuntimeOnly("org.junit.platform:junit-platform-launcher:1.7.2")
	testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.7.2")
	testRuntimeOnly("org.junit.vintage:junit-vintage-engine:5.7.2")

	implementation group: 'mysql', name: 'mysql-connector-java', version: '8.0.26'

	implementation group: 'org.json', name: 'json', version: '20201115'
	implementation 'com.google.guava:guava:30.1.1-jre'
	implementation 'commons-io:commons-io:2.8.0'
}