pair_ns.fj

ns Pair {
    first = 0
    len = w
    second = .len*dw
    size = .len * 2

    def init this {
        bit.zero .len,  this+.first
        bit.zero .len, this+.second
    }

    def add_first  this, val {
        ._.add this+.first,  val
    }

    def add_second this, val {
        ._.add this+.second, val
    }

    def add this, src {
        .add_first  this, src+.first
        .add_second this, src+.second
    }

    def print this {
        stl.output '('
        ._.print_hex_int this+.first
        stl.output ','
        stl.output ' '
        ._.print_hex_int this+.second
        stl.output ')'
    }

    def init {
        ._.init
    }

    ns _ {
        def add dst, src < .add, .ret_reg, .temp1, .temp2 {
            bit.xor ..len, .temp2, src
            bit.xor_zero ..len, .temp1, dst
            stl.fcall .add, .ret_reg
            bit.xor_zero ..len, dst, .temp1
            bit.zero ..len, .temp2
        }


        def print_hex_int val < .print_hex_int, .ret_reg, .temp1 {
            bit.xor ..len, .temp1, val
            stl.fcall .print_hex_int, .ret_reg
            bit.xor ..len, .temp1, val
        }

        def init @ data_end > add, print_hex_int, ret_reg, temp1, temp2 {
            ;data_end

            add:
                bit.add ..len, .temp1, .temp2
                stl.fret .ret_reg

            print_hex_int:
                bit.print_hex_int ..len, .temp1, 1
                stl.fret .ret_reg

            ret_reg: bit.bit 0
            temp1: bit.vec ..len, 0
            temp2: bit.vec ..len, 0

            data_end:
        }

    }

    def swap this {
        bit.swap .len, this+.first, this+.second
    }

    ns prints {
        def print_two p1, p2 {
            ..print p1
            stl.output ','
            stl.output ' '
            stl.output ' '
            ..print p2
            stl.output '\n'
        }
    }
}