schema.tql

#
# Copyright (C) 2022 Vaticle
#
# Licensed to the Apache Software Foundation (ASF) under one
# or more contributor license agreements.  See the NOTICE file
# distributed with this work for additional information
# regarding copyright ownership.  The ASF licenses this file
# to you under the Apache License, Version 2.0 (the
# "License"); you may not use this file except in compliance
# with the License.  You may obtain a copy of the License at
#
#   http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing,
# software distributed under the License is distributed on an
# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
# KIND, either express or implied.  See the License for the
# specific language governing permissions and limitations
# under the License.
#

define

# Attributes

name sub attribute,
    value string;
has-required-techs sub attribute,
    value boolean;
has-required-resources sub attribute,
    value boolean;
can-begin sub attribute,
    value boolean;
can-proceed sub attribute,
    value boolean;
started sub attribute,
    value boolean;
progress sub attribute,
    value double;
completed sub attribute,
    value boolean;
quantity sub attribute,
    value long;
quantity-consumed sub attribute,
    value long;

# Static entities

research-project sub entity,
    owns name,
    plays resource-cost-to-begin-research:research-to-begin,
    plays campaign-research-task:research-task,
    plays tech-requirement-to-begin-task:task-begin-required-tech,
    plays tech-requirement-to-begin-research:research-begin-required-tech,
    plays tech-requirement-to-begin-research:research-to-begin,
    owns completed;

item sub entity,
    owns name,
    plays item-ownership:owned-item,
    plays resource-cost:consumes-resource;

# Dynamic entities

campaign sub entity,
    owns name,
    plays campaign-task:campaign-with-tasks,
    plays item-ownership:item-owner;

# Static relations

requirement sub relation,
    relates prerequisite,
    relates outcome,
    plays campaign-task:task;

tech-requirement sub requirement,
    relates required-tech as prerequisite;

tech-requirement-to-begin-task sub tech-requirement,
    relates task-to-begin as outcome,
    relates task-begin-required-tech as required-tech;

tech-requirement-to-begin-research sub tech-requirement,
    relates research-to-begin as outcome,
    relates research-begin-required-tech as required-tech;

resource-cost sub requirement,
    relates consumes-resource as prerequisite,
    owns quantity-consumed;

resource-cost-to-begin-task sub resource-cost,
    relates task-to-begin as outcome;

resource-cost-to-begin-research sub resource-cost,
    relates research-to-begin as outcome;

# Dynamic relations

campaign-task sub relation,
    relates campaign-with-tasks,
    relates task,
    owns has-required-techs,
    owns has-required-resources,
    owns can-begin,
    owns started,
    owns can-proceed,
    owns progress,
    owns completed;

campaign-research-task sub campaign-task,
    relates research-task as task;

item-ownership sub relation,
    relates item-owner,
    relates owned-item,
    owns quantity;

# Rules

# campaign task
rule task-is-not-completed-if-progress-is-less-than-100:
    when {
        $task isa campaign-task, has progress < 100;
    } then {
        $task has completed false;
    };

rule task-is-completed-if-progress-is-at-least-100:
    when {
        $task isa campaign-task, has progress >= 100;
    } then {
        $task has completed true;
    };

rule task-can-not-begin-if-it-is-already-started:
    when {
        $task isa campaign-task, has started true;
    } then {
        $task has can-begin false;
    };

rule task-can-not-begin-if-it-lacks-required-tech:
    when {
        $task isa campaign-task, has has-required-techs false;
    } then {
        $task has can-begin false;
    };

rule task-can-not-begin-if-it-lacks-required-resources:
    when {
        $task isa campaign-task, has has-required-resources false;
    } then {
        $task has can-begin false;
    };

rule task-can-begin-if-it-is-not-started-and-all-requirements-are-met:
    when {
        $task isa campaign-task, has started false, has has-required-techs true, has has-required-resources true;
    } then {
        $task has can-begin true;
    };

rule research-does-not-have-required-techs:
    when {
        $campaign isa campaign;
        $campaign_task($campaign, task: $task) isa campaign-task;
        (research-to-begin: $task, required-tech: $prerequisite) isa tech-requirement-to-begin-research;
        ($campaign, $prerequisite) isa campaign-task, has completed false;
    } then {
        $campaign_task has has-required-techs false;
    };

rule research-has-required-techs:
    when {
        $campaign isa campaign;
        $campaign_task($campaign, task: $task) isa campaign-task;
        not {
            (research-to-begin: $task, required-tech: $prerequisite) isa tech-requirement-to-begin-research;
            ($campaign, $prerequisite) isa campaign-task, has completed false;
        };
    } then {
        $campaign_task has has-required-techs true;
    };

rule research-does-not-have-required-resources:
    when {
        $campaign isa campaign;
        $campaign_task($campaign, task: $task) isa campaign-task;
        (research-to-begin: $task, consumes-resource: $resource) isa resource-cost-to-begin-research, has quantity-consumed $quantity_required;
        ($campaign, $resource) isa item-ownership, has quantity < $quantity_required;
    } then {
        $campaign_task has has-required-resources false;
    };

rule research-does-have-required-resources:
    when {
        $campaign isa campaign;
        $campaign_task($campaign, task: $task) isa campaign-task;
        not {
            (research-to-begin: $task, consumes-resource: $resource) isa resource-cost-to-begin-research, has quantity-consumed $quantity_required;
            ($campaign, $resource) isa item-ownership, has quantity < $quantity_required;
        };
    } then {
        $campaign_task has has-required-resources true;
    };

rule task-can-not-proceed-if-it-is-not-started:
    when {
        $task isa campaign-task, has started false;
    } then {
        $task has can-proceed false;
    };

rule task-can-not-proceed-if-it-is-completed:
    when {
        $task isa campaign-task, has completed true;
    } then {
        $task has can-proceed false;
    };

rule task-can-proceed-if-it-is-started-but-not-completed:
    when {
        $task isa campaign-task, has started true, has completed false;
    } then {
        $task has can-proceed true;
    };

rule task-has-no-progress-if-it-has-not-been-started:
    when {
        $task isa campaign-task, has started false;
    } then {
        $task has progress 0;
    };

rule research-tech-requirements-are-transitive:
    when {
        (research-to-begin: $a, research-begin-required-tech: $b) isa tech-requirement-to-begin-research;
        (research-to-begin: $b, research-begin-required-tech: $c) isa tech-requirement-to-begin-research;
    } then {
        (research-to-begin: $a, research-begin-required-tech: $c) isa tech-requirement-to-begin-research;
    };