build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.4.32'
}

apply plugin: 'maven-publish'
apply plugin: 'signing'

task sourcesJar(type: Jar) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar) {
    archiveClassifier = 'javadoc'
    from javadoc.destinationDir
}

group = 'com.zachary-moore'
version = '0.0.1'

ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

publishing {
    publications {
        mavenJava(MavenPublication) {
            pom {
                name = 'huekontrollr'
                description = 'Kotlin wrapper around the Hue api to provide convenience functions and data objects'
                url = 'https://github.com/zsmoore/huekontrollr'

                organization {
                    name = 'com.zachary-moore'
                    url = 'https://www.zachary-moore.com'
                }

                issueManagement {
                    system = 'GitHub'
                    url = 'https://github.com/zsmoore/huekontrollr/issues'
                }

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'https://github.com/zsmoore/huekontrollr/blob/main/LICENSE'
                        distribution = 'repo'
                    }
                }

                developers {
                    developer {
                        id = 'zsmoore'
                        name = 'Zachary Moore'
                        email = 'zsmoore@zachary-moore.com'
                    }
                }

                scm {
                    connection = 'scm:git:git://github.com/zsmoore/huekontrollr.git'
                    developerConnection = 'scm:git:ssh://git@github.com:zsmoore/huekontrollr.git'
                    url = 'https://github.com/zsmoore/huekontrollr'
                }
            }

            from components.kotlin

            artifact sourcesJar
            artifact javadocJar
        }
    }

    repositories {
        maven {
            url 'https://oss.sonatype.org/service/local/staging/deploy/maven2'
            credentials {
                username = sonatypeUsername
                password = sonatypePassword
            }
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}

tasks.withType(Sign) {
    onlyIf { isReleaseVersion }
}

repositories {
    mavenCentral()
    jcenter()
}

java {
    withJavadocJar()
    withSourcesJar()
}

dependencies {
    testImplementation 'org.jetbrains.kotlin:kotlin-test-junit'
    implementation("com.github.kittinunf.fuel:fuel:2.3.1")
    implementation("org.json:json:20210307")
    implementation 'io.github.microutils:kotlin-logging-jvm:2.0.6'
    implementation 'org.slf4j:slf4j-simple:1.7.29'
}

test {
    useJUnit()
}

compileKotlin {
    kotlinOptions.jvmTarget = '1.8'
}

compileTestKotlin {
    kotlinOptions.jvmTarget = '1.8'
}