build: add flake.nix

run `nix develop` to get a development environment

flake.nix

@@ -0,0 +1,59 @@
+{
+  description = "My haskell library";
+
+  nixConfig = {
+    extra-substituters = [
+      "https://haskell-language-server.cachix.org"
+    ];
+    extra-trusted-public-keys = [
+      "haskell-language-server.cachix.org-1:juFfHrwkOxqIOZShtC4YC1uT1bBcq2RSvC7OMKx0Nz8="
+    ];
+  };
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+    hls.url = "github:haskell/haskell-language-server/854d2c5a1aa3095c93e3f38ef3731be89b4ab09a";
+
+    flake-compat = {
+      url = "github:edolstra/flake-compat";
+      flake = false;
+    };
+  };
+
+  outputs = { self, nixpkgs, flake-utils, hls, ... }:
+    flake-utils.lib.eachSystem ["x86_64-linux"] (system: let
+
+      pkgs = nixpkgs.legacyPackages.${system};
+
+      ghc8107 = pkgs.haskell.packages."ghc8107";
+
+      # modifier used in haskellPackages.developPackage
+      myModifier = hsPkgs: drv: let
+        compilerVersion = pkgs.lib.replaceStrings [ "." ] [ "" ] hsPkgs.ghc.version;
+      in
+        pkgs.haskell.lib.addBuildTools drv ([
+          hsPkgs.cabal-install
+          hls.packages.${system}."haskell-language-server-${compilerVersion}"
+          pkgs.openssl.dev
+          pkgs.zlib
+        ]);
+
+      mkPackage = hsPkgs:
+          hsPkgs.developPackage {
+            root =  pkgs.lib.cleanSource ./. ;
+            name =  "cabal2nix";
+            returnShellEnv = false;
+            withHoogle = true;
+            modifier = myModifier hsPkgs;
+          };
+
+    in {
+      packages = {
+        cabal2nix = self.packages.${system}.cabal2nix-8107;
+        cabal2nix-8107 = mkPackage ghc8107;
+      };
+
+      defaultPackage = self.packages.${system}.cabal2nix;
+  });
+}

shell.nix

@@ -0,0 +1,9 @@
+(import (
+  let
+    lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+  in fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+    sha256 = lock.nodes.flake-compat.locked.narHash; }
+) {
+  src =  ./.;
+}).shellNix