posting: init at 1.10.0

pkgs/by-name/po/posting/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "posting";
+  version = "1.10.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "darrenburns";
+    repo = "posting";
+    rev = "refs/tags/${version}";
+    hash = "sha256-g8SlW7YLz/H5euZZIaNbB+mUqM630HSzVHUoIIZI/1g=";
+  };
+
+  build-system = [ python3Packages.hatchling ];
+
+  dependencies =
+    with python3Packages;
+    [
+      click
+      click-default-group
+      httpx
+      pydantic
+      pydantic-settings
+      pyperclip
+      python-dotenv
+      pyyaml
+      textual
+      textual-autocomplete
+      xdg-base-dirs
+    ]
+    ++ httpx.optional-dependencies.brotli
+    ++ textual.optional-dependencies.syntax;
+
+  pythonRelaxDeps = true;
+
+  # Fix tests by preventing them from writing to /homeless-shelter.
+  preCheck = "export HOME=$(mktemp -d)";
+
+  nativeCheckInputs = with python3Packages; [
+    pytestCheckHook
+    textual-dev
+    jinja2
+    syrupy
+    pytest-xdist
+    pytest-cov
+    pytest-textual-snapshot
+  ];
+
+  pythonImportsCheck = [ "posting" ];
+
+  meta = {
+    description = "Modern API client that lives in your terminal";
+    homepage = "https://github.com/darrenburns/posting";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ taha-yassine ];
+    mainProgram = "posting";
+  };
+}

pkgs/development/python-modules/textual-autocomplete/default.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  poetry-core,
+  textual,
+  typing-extensions,
+}:
+
+buildPythonPackage {
+  pname = "textual-autocomplete";
+  version = "3.0.0a9";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "darrenburns";
+    repo = "textual-autocomplete";
+    rev = "bbacfa91bfd9ff006dab8930a8a3fe4ba46853ab"; # targets `version-two` branch
+    hash = "sha256-m2ATH2BNoVCoEzKb5xxe4KPvUlfrwfE+widRIdApkL8=";
+  };
+
+  build-system = [ poetry-core ];
+
+  dependencies = [
+    textual
+    typing-extensions
+  ];
+
+  pythonImportsCheck = [ "textual_autocomplete" ];
+
+  doCheck = false; # no tests
+
+  meta = {
+    description = "Easily add autocomplete dropdowns to your Textual apps";
+    homepage = "https://github.com/darrenburns/textual-autocomplete";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ taha-yassine ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -15223,6 +15223,8 @@ self: super: with self; {
 
   textual = callPackage ../development/python-modules/textual { };
 
+  textual-autocomplete = callPackage ../development/python-modules/textual-autocomplete { };
+
   textual-dev = callPackage ../development/python-modules/textual-dev { };
 
   textual-universal-directorytree = callPackage ../development/python-modules/textual-universal-directorytree { };