tuxedo-keyboard: fix compilation for kernel 6.10 and 6.11

nixos/modules/hardware/tuxedo-drivers.nix

@@ -0,0 +1,35 @@
+{ config, lib, ... }:
+let
+  cfg = config.hardware.tuxedo-drivers;
+  tuxedo-drivers = config.boot.kernelPackages.tuxedo-drivers;
+in
+{
+  imports = [
+    (lib.mkRenamedOptionModule
+      [
+        "hardware"
+        "tuxedo-keyboard"
+      ]
+      [
+        "hardware"
+        "tuxedo-drivers"
+      ]
+    )
+  ];
+
+  options.hardware.tuxedo-drivers = {
+    enable = lib.mkEnableOption ''
+      The tuxedo-drivers driver enables access to the following on TUXEDO notebooks:
+      - Driver for Fn-keys
+      - SysFS control of brightness/color/mode for most TUXEDO keyboards
+      - Hardware I/O driver for TUXEDO Control Center
+
+      For more inforation it is best to check at the source code description: <https://gitlab.com/tuxedocomputers/development/packages/tuxedo-drivers>
+    '';
+  };
+
+  config = lib.mkIf cfg.enable {
+    boot.kernelModules = [ "tuxedo_keyboard" ];
+    boot.extraModulePackages = [ tuxedo-drivers ];
+  };
+}

nixos/modules/module-list.nix

@@ -97,7 +97,7 @@
   ./hardware/sensor/iio.nix
   ./hardware/steam-hardware.nix
   ./hardware/system-76.nix
-  ./hardware/tuxedo-keyboard.nix
+  ./hardware/tuxedo-drivers.nix
   ./hardware/ubertooth.nix
   ./hardware/uinput.nix
   ./hardware/uni-sync.nix

nixos/modules/services/hardware/tuxedo-rs.nix

@@ -14,7 +14,7 @@ in
 
   config = lib.mkIf cfg.enable (lib.mkMerge [
     {
-      hardware.tuxedo-keyboard.enable = true;
+      hardware.tuxedo-drivers.enable = true;
 
       systemd = {
         services.tailord = {

pkgs/os-specific/linux/tuxedo-drivers/default.nix

@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  kernel,
+  linuxHeaders,
+  pahole,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "tuxedo-drivers-${kernel.version}";
+  version = "4.7.0";
+
+  src = fetchFromGitLab {
+    group = "tuxedocomputers";
+    owner = "development/packages";
+    repo = "tuxedo-drivers";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-wZUQHIkbxt9ckTFs8VTrA5I+ebBeaOm+Fb0+GqX5y0c=";
+  };
+
+  buildInputs = [
+    pahole
+    linuxHeaders
+  ];
+
+  makeFlags = [ "KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build" ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p "$out/lib/modules/${kernel.modDirVersion}"
+
+    find src/ -type f -name '*.ko' \
+      -exec mv {} $out/lib/modules/${kernel.modDirVersion} \;
+
+    runHook postInstall
+  '';
+
+  meta = {
+    broken = stdenv.hostPlatform.isAarch64 || (lib.versionOlder kernel.version "5.5");
+    description = "Keyboard and hardware I/O driver for TUXEDO Computers laptops";
+    homepage = "https://gitlab.com/tuxedocomputers/development/packages/tuxedo-drivers";
+    license = lib.licenses.gpl3Plus;
+    longDescription = ''
+      Drivers for several platform devices for TUXEDO notebooks:
+      - Driver for Fn-keys
+      - SysFS control of brightness/color/mode for most TUXEDO keyboards
+      - Hardware I/O driver for TUXEDO Control Center
+
+      Can be used with the "hardware.tuxedo-drivers" NixOS module.
+    '';
+    maintainers = [ lib.maintainers.blanky0230 ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/top-level/linux-kernels.nix

@@ -481,7 +481,7 @@ in {
 
     rust-out-of-tree-module = if lib.versionAtLeast kernel.version "6.7" then callPackage ../os-specific/linux/rust-out-of-tree-module { } else null;
 
-    tuxedo-keyboard = if lib.versionAtLeast kernel.version "4.14" then callPackage ../os-specific/linux/tuxedo-keyboard { } else null;
+    tuxedo-drivers = if lib.versionAtLeast kernel.version "4.14" then callPackage ../os-specific/linux/tuxedo-drivers { } else null;
 
     jool = callPackage ../os-specific/linux/jool { };
 
@@ -611,6 +611,7 @@ in {
     xmm7360-pci = throw "Support for the XMM7360 WWAN card was added to the iosm kmod in mainline kernel version 5.18";
     amdgpu-pro = throw "amdgpu-pro was removed due to lack of maintenance"; # Added 2024-06-16
     kvdo = throw "kvdo was removed, because it was added to mainline in kernel version 6.9"; # Added 2024-07-08
+    tuxedo-keyboard = self.tuxedo-drivers;
   });
 
   hardenedPackagesFor = kernel: overrides: packagesFor (hardenedKernelFor kernel overrides);