upload of v15

SirinesCall/dialogue/ardrou.d

@@ -0,0 +1,34 @@
+/* updated file by cmorgan */
+
+/* Adding the transition: Ghrey just broke/rebuilt the vanilla state in tra, so just add the action */
+ADD_TRANS_ACTION ~%tutu_var%ARDROU~ BEGIN 0 END BEGIN END ~SetGlobal("J#ArdTalk","GLOBAL",1)~
+
+/* Modifying the string as per Ghrey's edit, since the kid is there, and the original string doesn't match */
+REPLACE_SAY ~%tutu_var%ARDROU~ 2 @0
+
+/* the kid leaves the area after the talk. Ardrouine stays put, in case someone else wants her for another reason. */
+/*By the way, don't add EscapeArea() for her into the A_T_A, or she leaves first and doesn't complete the script... */
+ADD_TRANS_ACTION ~%tutu_var%ARDROU~ BEGIN 2 END BEGIN END ~ActionOverride("J#Bren",EscapeArea())~
+
+REPLACE_STATE_TRIGGER %tutu_var%ARDROU 0
+~Global("J#ArdTalk","GLOBAL",0)
+GlobalLT("WorgsDead","GLOBAL",3)
+!Dead("J#Bren")
+!See("J#Bren")~
+
+REPLACE_STATE_TRIGGER %tutu_var%ARDROU 3
+~GlobalGT("WorgsDead","GLOBAL",3)~
+
+REPLACE_STATE_TRIGGER %tutu_var%ARDROU 1
+~GlobalLT("WorgsDead","GLOBAL",3)
+!Dead("J#Bren") 
+!See("J#Bren")~
+
+ADD_STATE_TRIGGER %tutu_var%ARDROU 2
+~See("J#Bren") !Dead("J#Bren")~
+
+//Brennan is dead
+REPLACE_STATE_TRIGGER %tutu_var%ARDROU 4
+~Dead("J#Bren")~
+
+ADD_TRANS_ACTION ~%tutu_var%ARDROU~ BEGIN 4 END BEGIN END ~Enemy() EscapeArea()~

SirinesCall/dialogue/pirates.d

@@ -0,0 +1,205 @@
+BEGIN J#pirat1
+
+IF ~NumTimesTalkedTo(0)
+!Global("J#SilMurder","GLOBAL",3)~ pirate
+  SAY @0
+=
+@1
+++ @2 GOTO explain
+++ @3 GOTO explain
++ ~Global("J#ArdTalk","GLOBAL",1)~ + @4 GOTO rude
++ ~Global("J#ArdTalk","GLOBAL",1)~ + @5 GOTO polite
++ ~Global("J#ArdTalk","GLOBAL",1)~ + @6 GOTO rescue
+END
+
+IF ~~ explain
+  SAY @7
+  IF ~~ GOTO boyname
+END
+
+IF ~~ rude
+  SAY @8
+  IF ~~ GOTO boyname
+END
+
+IF ~~ polite
+  SAY @9
+  IF ~~ GOTO boyname
+END
+
+IF ~~ rescue
+  SAY @10
+  IF ~~ GOTO boyname
+END
+
+IF ~~ boyname
+  SAY @11
+  IF ~~ EXTERN J#Bren brennan
+END
+
+BEGIN J#bren
+IF ~~ brennan
+  SAY @12
+  + ~!Global("J#ArdTalk","GLOBAL",1)~ + @13 GOTO south
+  + ~!Global("J#ArdTalk","GLOBAL",1)~ + @14 EXTERN J#pirat1 beoff
+  + ~!Global("J#ArdTalk","GLOBAL",1)~ + @15 EXTERN J#pirat1 beoff
+  + ~Global("J#ArdTalk","GLOBAL",1)~ + @16 EXTERN J#pirat1 beoff
+  + ~Global("J#ArdTalk","GLOBAL",1)~ + @17 EXTERN J#pirat1 beoff
+  + ~Global("J#ArdTalk","GLOBAL",1)~ + @18 EXTERN J#pirat1 beoff
+  + ~Global("J#ArdTalk","GLOBAL",1)~ + @19 EXTERN J#pirat1 beoff
+END
+
+IF ~~ south
+  SAY @20
+  IF ~~ THEN EXTERN J#pirat1 beoff
+END
+
+APPEND J#pirat1
+IF ~~ beoff
+  SAY @21
+  IF ~ReactionGT(LastTalkedToBy(),NEUTRAL_UPPER)~ GOTO advice
+  IF ~ReactionLT(LastTalkedToBy(),FRIENDLY_LOWER)
+ReactionGT(LastTalkedToBy(),HOSTILE_UPPER)~ GOTO advice2
+  IF ~ReactionLT(LastTalkedToBy(),NEUTRAL_LOWER)~ GOTO bribe
+END
+
+IF ~~ advice
+  SAY @22
+=
+@23
+  IF ~~ THEN DO ~SetGlobal("J#TalkedPirate","GLOBAL",1)
+%EscapeArea_Move%~ EXIT
+END
+
+IF ~~ advice2
+  SAY @24
+  IF ~~ THEN DO ~SetGlobal("J#TalkedPirate","GLOBAL",1)
+%EscapeArea_Move%~ EXIT
+END
+
+IF ~~ bribe
+  SAY @25
+  IF ~~ THEN DO ~SetGlobal("J#TalkedPirate","GLOBAL",1)
+GivePartyGold(50)
+%EscapeArea_Move%~ EXIT
+END
+
+IF ~Global("J#SireneTreasure","GLOBAL",1)~ pirate_attack
+SAY @63
+= @64
+= @61   
+= @62
+IF ~~ THEN DO ~SetGlobal("J#PirateFight","GLOBAL",1) // His men spawn on this global and turn hostile
+Enemy()~ EXIT
+END
+
+
+IF ~Global("J#TalkedPirate","GLOBAL",1)~ furtherchat
+  SAY @26
+  ++ @27 + sirinewarn
+  ++ @28 + piracy
+  + ~Global("J#TalkedSil","GLOBAL",1)~ + @29 + siltalk
+  ++ @30 EXIT
+END
+
+IF ~~ sirinewarn
+  SAY @31
+=
+@32
+  ++ @28 + piracy
+  + ~Global("J#TalkedSil","GLOBAL",1)~ + @29 + siltalk
+  ++ @33 EXIT
+END
+
+IF ~~ piracy
+  SAY @34
+=
+@35
+  ++ @27 + sirinewarn
+  + ~Global("J#TalkedSil","GLOBAL",1)~ + @29 + siltalk
+  ++ @33 EXIT
+END
+
+IF ~~ siltalk
+  SAY @36
+=
+@37
+  + ~CheckStatGT(LastTalkedToBy(Myself),13,CHR)~ + @38 + confess
+  + ~CheckStatLT(LastTalkedToBy(Myself),14,CHR)~ + @38 + noconfess
+  + ~CheckStatGT(LastTalkedToBy(Myself),12,INT)~ + @39 + confess
+  + ~CheckStatLT(LastTalkedToBy(Myself),13,INT)~ + @39 + noconfess
+  ++ @40 + fight
+  ++ @41 + nofight
+  ++ @42 + confess
+END
+
+IF ~~ fight
+  SAY @43
+=
+@44
+  IF ~~ THEN DO ~SetGlobal("J#PirateFight","GLOBAL",1) // Hostile men spawn
+Enemy()~ EXIT
+END
+
+IF ~~ nofight
+  SAY @45
+=
+@46
+  IF ~~ THEN DO ~SetGlobal("J#TalkedPirate","GLOBAL",2) // If talked to again, will attack~ EXIT
+END
+
+IF ~~ noconfess
+  SAY @47
+=
+@46
+  IF ~~ THEN DO ~SetGlobal("J#TalkedPirate","GLOBAL",2) // If talked to again, will attack~ EXIT
+END
+
+IF ~~ confess
+  SAY @48
+=
+@49
+=
+@50
+++ @51 GOTO fight
+++ @52 GOTO bribeyou
+END
+
+IF ~~ bribeyou
+  SAY @53
+=
+@54
+  ++ @55 + dealstruck
+  ++ @56 + fight
+END
+
+IF ~Global("J#TalkedPirate","GLOBAL",2)~ killjoo
+  SAY @57
+=
+@44
+  IF ~~ THEN DO ~SetGlobal("J#PirateFight","GLOBAL",1) // His men spawn on this global and turn hostile
+Enemy()~ EXIT
+END
+
+IF ~~ dealstruck
+  SAY @58
+  IF ~!Dead("sil")~ THEN DO ~GivePartyGold(1000)
+SetGlobal("J#SilMurder","GLOBAL",1) // Sil has had the hit taken out on her
+EscapeArea()~ EXIT
+  IF ~Dead("sil")~ THEN DO ~GivePartyGold(1000)
+SetGlobal("J#SilMurder","GLOBAL",2) // Sil is already dead
+EscapeArea()~ EXIT
+END
+
+IF WEIGHT #-2 ~Global("J#SilMurder","GLOBAL",3)~ betrayed
+  SAY @59
+=
+@60
+=
+@61
+=
+@62
+  IF ~~ THEN DO ~SetGlobal("J#SilMurder","GLOBAL",4) // His men turn hostile on this global
+Enemy()~ EXIT
+END
+END

SirinesCall/dialogue/sil.d

@@ -0,0 +1,95 @@
+
+REPLACE_STATE_TRIGGER %tutu_var%sil 0 ~!Global("J#TalkedPirate","GLOBAL",1) !Global("J#TalkedSil","GLOBAL",1) !Allegiance(Myself,[ENEMY])~
+
+REPLACE_STATE_TRIGGER %tutu_var%sil 11 ~Allegiance(Myself,[ENEMY])~
+
+
+REPLACE_TRANS_ACTION %tutu_var%sil BEGIN 0 END BEGIN 0 END ~Shout(1)
+Enemy()~ ~~
+
+REPLACE_TRANS_ACTION %tutu_var%sil BEGIN 1 END BEGIN 0 END ~Shout(1)
+Enemy()~ ~~
+
+/* bgee */
+REPLACE_TRANS_ACTION %tutu_var%sil BEGIN 0 END BEGIN 0 END ~Shout(99)
+Enemy()~ ~~
+REPLACE_TRANS_ACTION %tutu_var%sil BEGIN 1 END BEGIN 0 END ~Shout(99)
+Enemy()~ ~~
+
+APPEND %tutu_var%sil
+
+
+IF WEIGHT #-1 ~Global("J#TalkedPirate","GLOBAL",1)
+Global("J#TalkedSil","GLOBAL",0)~ piratetalk
+  SAY @0
+++ @1 GOTO nowwefight
+++ @2 GOTO trespass
+++ @3 + trespass
+++ @4 + nowwefight
+END
+
+IF ~~ nowwefight
+  SAY @5
+  IF ~~ THEN DO ~Shout(1) SetGlobal("J#SilEnemy","GLOBAL",1)
+Enemy()~ EXIT
+END
+
+IF ~~ trespass
+  SAY @6
+=
+@7
+  ++ @8 GOTO helpyou
+  ++ @9 GOTO treasurefight
+  ++ @10 GOTO helpyou
+  ++ @11 GOTO treasurefight
+END
+
+IF ~~ treasurefight
+  SAY @12
+  IF ~~ THEN DO ~Shout(1) SetGlobal("J#SilEnemy","GLOBAL",1)
+Enemy()~ EXIT
+END
+
+IF ~~ helpyou
+  SAY @13
+=
+@14
+  IF ~~ THEN DO ~SetGlobal("J#TalkedSil","GLOBAL",1)~ EXIT
+END
+
+IF WEIGHT #-1 ~Global("J#TalkedSil","GLOBAL",1)~ silkill
+  SAY @15
+  ++ @16 + backtoit
+  + ~Global("J#PirateFight","GLOBAL",2)
+!Dead("J#pirat1")~ + @17 + manythanks
+
+  + ~!Global("J#PirateFight","GLOBAL",2)
+Dead("J#pirat1")~ + @17 + manythanks
+
+
+  + ~Global("J#PirateFight","GLOBAL",2)
+Dead("J#pirat1")~ + @17 + manythanks
+
+  + ~Global("J#SilMurder","GLOBAL",1)~ + @18 + fightme
+END
+
+IF ~~ backtoit
+  SAY @19
+  IF ~~ THEN EXIT
+END
+
+IF ~~ manythanks
+  SAY @20
+  IF ~~ THEN DO ~SetGlobal("J#PirateFight","GLOBAL",3)
+AddExperienceParty(1500) 
+SetGlobal("J#TalkedSil","GLOBAL",2)~ EXIT
+END
+
+IF ~~ fightme
+  SAY @21
+  IF ~~ THEN DO ~Shout(1)
+ReputationInc(-1)
+SetGlobal("J#SilMurder","GLOBAL",2) SetGlobal("J#SilEnemy","GLOBAL",1)
+Enemy()~ EXIT
+END
+END // end APPEND