Update to v1.4.4-SNAPSHOT

.bamboo/log4cplus.properties

@@ -0,0 +1,40 @@
+log4cplus.rootLogger=INFO, STDOUT
+log4cplus.appender.STDOUT=log4cplus::ConsoleAppender
+#
+# see http://log4cplus.sourceforge.net/docs/html/classlog4cplus_1_1PatternLayout.html
+# for conversion pattern documentation
+#
+log4cplus.appender.STDOUT.layout=log4cplus::PatternLayout
+log4cplus.appender.STDOUT.layout.ConversionPattern=%-5p [%c]%b:%L  %m%n
+
+# Logger levels are all prepended by log4cplus.logger.
+# The most specific property wins.
+# Valid levels are OFF, FATAL, ERROR, WARN, INFO, DEBUG, TRACE, and ALL.
+
+# Log levels per section of code:
+#log4cplus.logger.main=WARN
+#log4cplus.logger.logging=WARN
+#log4cplus.logger.logging.init=TRACE
+#log4cplus.logger.Loadable=WARN
+#log4cplus.logger.IMScenario=WARN
+#log4cplus.logger.AircraftIntent=DEBUG
+#log4cplus.logger.RandomGenerator=WARN
+#log4cplus.logger.LocalTangentPlane=WARN
+#log4cplus.logger.IMAircraft=WARN
+#log4cplus.logger.NavigationSensor=WARN
+#log4cplus.logger.FirstOrderGaussMarkovProcess=WARN
+#log4cplus.logger.KineticDescent4DPredictor=WARN
+#log4cplus.logger.KinematicDescent4DPredictor=WARN
+
+# Users can also define a file appender to collect results
+#log4cplus.appender.RANDOM=log4cplus::FileAppender
+#log4cplus.appender.RANDOM.File=random.log
+#log4cplus.appender.RANDOM.ImmediateFlush=true
+#log4cplus.appender.RANDOM.Threshold=trace
+#log4cplus.appender.RANDOM.Append=false
+#log4cplus.appender.RANDOM.layout=log4cplus::PatternLayout
+#log4cplus.appender.RANDOM.layout.ConversionPattern=%M,%m%n
+
+# uncomment these lines to actually use the RANDOM appender for math results
+# log4cplus.additivity.RandomGenerator=false
+# log4cplus.logger.RandomGenerator=TRACE, RANDOM

.cmake/GetGitRevisionDescription.cmake

@@ -0,0 +1,168 @@
+# - Returns a version string from Git
+#
+# These functions force a re-configure on each git commit so that you can
+# trust the values of the variables in your build system.
+#
+#  get_git_head_revision(<refspecvar> <hashvar> [<additional arguments to git describe> ...])
+#
+# Returns the refspec and sha hash of the current head revision
+#
+#  git_describe(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe on the source tree, and adjusting
+# the output so that it tests false if an error occurs.
+#
+#  git_get_exact_tag(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe --exact-match on the source tree,
+# and adjusting the output so that it tests false if there was no exact
+# matching tag.
+#
+#  git_local_changes(<var>)
+#
+# Returns either "CLEAN" or "DIRTY" with respect to uncommitted changes.
+# Uses the return code of "git diff-index --quiet HEAD --".
+# Does not regard untracked files.
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <[email protected]> <[email protected]>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+if(__get_git_revision_description)
+    return()
+endif()
+set(__get_git_revision_description YES)
+
+# We must run the following at "include" time, not at function call time,
+# to find the path to this module rather than the path to a calling list file
+get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
+
+function(get_git_head_revision _refspecvar _hashvar)
+    set(GIT_PARENT_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
+    set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+    while(NOT EXISTS "${GIT_DIR}")	# .git dir not found, search parent directories
+        set(GIT_PREVIOUS_PARENT "${GIT_PARENT_DIR}")
+        get_filename_component(GIT_PARENT_DIR ${GIT_PARENT_DIR} PATH)
+        if(GIT_PARENT_DIR STREQUAL GIT_PREVIOUS_PARENT)
+            # We have reached the root directory, we are not in git
+            set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+            set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+            return()
+        endif()
+        set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+    endwhile()
+    # check if this is a submodule
+    if(NOT IS_DIRECTORY ${GIT_DIR})
+        file(READ ${GIT_DIR} submodule)
+        string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" GIT_DIR_RELATIVE ${submodule})
+        get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
+        get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE} ABSOLUTE)
+    endif()
+    set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
+    if(NOT EXISTS "${GIT_DATA}")
+        file(MAKE_DIRECTORY "${GIT_DATA}")
+    endif()
+
+    if(NOT EXISTS "${GIT_DIR}/HEAD")
+        return()
+    endif()
+    set(HEAD_FILE "${GIT_DATA}/HEAD")
+    configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
+
+    configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
+            "${GIT_DATA}/grabRef.cmake"
+            @ONLY)
+    include("${GIT_DATA}/grabRef.cmake")
+
+    set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
+    set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
+endfunction()
+
+function(git_describe _var)
+    if(NOT GIT_FOUND)
+        find_package(Git QUIET)
+    endif()
+    get_git_head_revision(refspec hash)
+    if(NOT GIT_FOUND)
+        set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
+        return()
+    endif()
+    if(NOT hash)
+        set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
+        return()
+    endif()
+
+    # TODO sanitize
+    #if((${ARGN}" MATCHES "&&") OR
+    #	(ARGN MATCHES "||") OR
+    #	(ARGN MATCHES "\\;"))
+    #	message("Please report the following error to the project!")
+    #	message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
+    #endif()
+
+    #message(STATUS "Arguments to execute_process: ${ARGN}")
+
+    execute_process(COMMAND
+            "${GIT_EXECUTABLE}"
+            describe
+            ${hash}
+            ${ARGN}
+            WORKING_DIRECTORY
+            "${CMAKE_CURRENT_SOURCE_DIR}"
+            RESULT_VARIABLE
+            res
+            OUTPUT_VARIABLE
+            out
+            ERROR_QUIET
+            OUTPUT_STRIP_TRAILING_WHITESPACE)
+    if(NOT res EQUAL 0)
+        set(out "${out}-${res}-NOTFOUND")
+    endif()
+
+    set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
+
+function(git_get_exact_tag _var)
+    git_describe(out --exact-match ${ARGN})
+    set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
+
+function(git_local_changes _var)
+    if(NOT GIT_FOUND)
+        find_package(Git QUIET)
+    endif()
+    get_git_head_revision(refspec hash)
+    if(NOT GIT_FOUND)
+        set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
+        return()
+    endif()
+    if(NOT hash)
+        set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
+        return()
+    endif()
+
+    execute_process(COMMAND
+            "${GIT_EXECUTABLE}"
+            diff-index --quiet HEAD --
+            WORKING_DIRECTORY
+            "${CMAKE_CURRENT_SOURCE_DIR}"
+            RESULT_VARIABLE
+            res
+            OUTPUT_VARIABLE
+            out
+            ERROR_QUIET
+            OUTPUT_STRIP_TRAILING_WHITESPACE)
+    if(res EQUAL 0)
+        set(${_var} "CLEAN" PARENT_SCOPE)
+    else()
+        set(${_var} "DIRTY" PARENT_SCOPE)
+    endif()
+endfunction()

.cmake/GetGitRevisionDescription.cmake.in

@@ -0,0 +1,41 @@
+#
+# Internal file for GetGitRevisionDescription.cmake
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <[email protected]> <[email protected]>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+set(HEAD_HASH)
+
+file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
+
+string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
+if(HEAD_CONTENTS MATCHES "ref")
+	# named branch
+	string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
+	if(EXISTS "@GIT_DIR@/${HEAD_REF}")
+		configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+	else()
+		configure_file("@GIT_DIR@/packed-refs" "@GIT_DATA@/packed-refs" COPYONLY)
+		file(READ "@GIT_DATA@/packed-refs" PACKED_REFS)
+		if(${PACKED_REFS} MATCHES "([0-9a-z]*) ${HEAD_REF}")
+			set(HEAD_HASH "${CMAKE_MATCH_1}")
+		endif()
+	endif()
+else()
+	# detached HEAD
+	configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
+endif()
+
+if(NOT HEAD_HASH)
+	file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
+	string(STRIP "${HEAD_HASH}" HEAD_HASH)
+endif()

.cmake/VersionUtils.cmake

@@ -0,0 +1,32 @@
+# VersionUtils.cmake
+
+#
+# Modeled heavily after macros for the Log4Cplus project
+#
+
+# Get myapp version macro
+# first param - path to include folder, we will rip version from version.h
+macro(get_version _include_PATH vmajor vminor vpatch vsuffix)
+  file(STRINGS "${_include_PATH}/aaesim/version.h" _myapp_VER_STRING_AUX REGEX ".*#define[ ]+AAESIM_VERSION_STR[ ]+")
+  # message(${_myapp_VER_STRING_AUX}) debugging message
+  string(REGEX MATCHALL "[0-9]+" _myapp_VER_LIST "${_myapp_VER_STRING_AUX}") # version numbers
+  list(LENGTH _myapp_VER_LIST _myapp_VER_LIST_LEN)
+
+  # suffix processing
+  string(REGEX MATCH "[\"A-Z,a-z\")]*$" _myapp_VER_SUFFIX "${_myapp_VER_STRING_AUX}") # version suffix (string)
+  string(LENGTH ${_myapp_VER_SUFFIX} _myapp_SUFFIX_LENGTH)
+  if(_myapp_SUFFIX_LENGTH EQUAL 1)
+    set(_myapp_VER_SUFFIX " ")
+  else()
+      string(REPLACE ")" "" _myapp_VER_SUFFIX ${_myapp_VER_SUFFIX}) # trim the suffix
+  endif()
+  # message(${_myapp_VER_SUFFIX}) # debugging message
+
+# get each version value from the list and return
+  set(${vsuffix} ${_myapp_VER_SUFFIX})
+  if(_myapp_VER_LIST_LEN EQUAL 3)
+    list(GET _myapp_VER_LIST 0 ${vmajor})
+    list(GET _myapp_VER_LIST 1 ${vminor})
+    list(GET _myapp_VER_LIST 2 ${vpatch})
+  endif()
+endmacro()

.cmake/aaesim-config.cmake.in

@@ -0,0 +1,16 @@
+@PACKAGE_INIT@
+
+set(aaesim_INCLUDE_DIRS
+        "@PROJECT_SOURCE_DIR@/include"
+        "@PROJECT_SOURCE_DIR@/unitsLib/units-2.1/scalar"
+)
+
+set(aaesim_LIBRARIES
+  "@PROJECT_SOURCE_DIR@/unitsLib/lib/libunits-2.1.a"
+  "@PROJECT_SOURCE_DIR@/Loader/lib/libloader.a"
+  "@PROJECT_SOURCE_DIR@/Utility/lib/libutility.a"
+  "@PROJECT_SOURCE_DIR@/Core/lib/libcore.a"
+  "@PROJECT_SOURCE_DIR@/IntervalManagement/lib/libimalgs.a"
+  "@PROJECT_SOURCE_DIR@/Math/lib/libmath.a"
+  "@PROJECT_SOURCE_DIR@/PairedApproach/lib/libpaalgs.a"
+)