helm: init module

modules/lib/maintainers.nix

@@ -628,4 +628,10 @@
     github = "ALameLlama";
     githubId = 55490546;
   };
+  folliehiyuki = {
+    name = "Hoang Nguyen";
+    email = "[email protected]";
+    github = "folliehiyuki";
+    githubId = 67634026;
+  };
 }

modules/misc/news.nix

@@ -1947,6 +1947,15 @@ in {
           speed, features, or native UIs. Ghostty provides all three.
         '';
       }
+
+      {
+        time = "2025-01-08T06:54:09+00:00";
+        message = ''
+          A new module is available: 'programs.helm'.
+
+          Helm is a package manager for Kubernetes.
+        '';
+      }
     ];
   };
 }

modules/modules.nix

@@ -117,6 +117,7 @@ let
     ./programs/granted.nix
     ./programs/havoc.nix
     ./programs/helix.nix
+    ./programs/helm.nix
     ./programs/hexchat.nix
     ./programs/himalaya.nix
     ./programs/home-manager.nix

modules/programs/helm.nix

@@ -0,0 +1,45 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.programs.helm;
+
+  enableXdgDir = !pkgs.stdenv.hostPlatform.isDarwin || config.xdg.enable;
+in {
+  meta.maintainers = [ hm.maintainers.folliehiyuki ];
+
+  options.programs.helm = {
+    enable = mkEnableOption "helm";
+
+    package = mkPackageOption pkgs "helm" { default = [ "kubernetes-helm" ]; };
+
+    plugins = mkOption {
+      type = with types; attrsOf path;
+      default = { };
+      description = ''
+        Helm plugins to be installed.
+        Values should be a path containing a top-level `plugin.yaml` file.
+        Will be linked to {file}`$XDG_DATA_HOME/helm/plugins/<name>/`.
+      '';
+      example = literalExpression ''
+        {
+          custom = ./custom;
+          diff = ${pkgs.kubernetes-helmPlugins.helm-diff}/helm-diff;
+        }
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ cfg.package ];
+
+    xdg.dataFile = mkIf enableXdgDir (mapAttrs'
+      (name: value: nameValuePair "helm/plugins/${name}" { source = value; })
+      cfg.plugins);
+
+    home.file = mkIf (!enableXdgDir) (mapAttrs' (name: value:
+      nameValuePair "Library/helm/plugins/${name}" { source = value; })
+      cfg.plugins);
+  };
+}

tests/default.nix

@@ -87,6 +87,7 @@ in import nmtSrc {
     ./modules/programs/gradle
     ./modules/programs/granted
     ./modules/programs/helix
+    ./modules/programs/helm
     ./modules/programs/himalaya
     ./modules/programs/htop
     ./modules/programs/hyfetch

tests/modules/programs/helm/default.nix

@@ -0,0 +1,5 @@
+{
+  helm-no-plugins = ./helm-no-plugins.nix;
+  helm-with-plugins = ./helm-with-plugins.nix;
+  helm-with-plugins-no-xdg = ./helm-with-plugins-no-xdg.nix;
+}

tests/modules/programs/helm/helm-no-plugins.nix

@@ -0,0 +1,14 @@
+{ config, ... }:
+
+{
+  config = {
+    programs.helm.enable = true;
+
+    test.stubs.kubernetes-helm = { };
+
+    nmt.script = ''
+      assertPathNotExists home-files/Library/helm
+      assertPathNotExists ${config.xdg.dataHome}/helm
+    '';
+  };
+}

tests/modules/programs/helm/helm-with-plugins-no-xdg.nix

@@ -0,0 +1,28 @@
+{ pkgs, lib, ... }:
+
+{
+  config = {
+    xdg.enable = lib.mkForce false;
+
+    programs.helm = {
+      enable = true;
+
+      plugins.unittest = "${pkgs.kubernetes-helmPlugins.helm-unittest}/helm-unittest";
+    };
+
+    test.stubs.kubernetes-helm = { };
+
+    nmt.script = let
+      helmPluginsDir = if !pkgs.stdenv.isDarwin then
+        ".local/share/helm/plugins"
+      else
+        "Library/helm/plugins";
+    in ''
+      assertFileExists home-files/${helmPluginsDir}/unittest/untt
+      assertFileExists home-files/${helmPluginsDir}/unittest/plugin.yaml
+
+      assertFileContains home-files/${helmPluginsDir}/unittest/plugin.yaml \
+        'command: "$HELM_PLUGIN_DIR/untt"'
+    '';
+  };
+}

tests/modules/programs/helm/helm-with-plugins.nix

@@ -0,0 +1,23 @@
+{ pkgs, ... }:
+
+{
+  config = {
+    xdg.enable = true;
+
+    programs.helm = {
+      enable = true;
+
+      plugins.diff = "${pkgs.kubernetes-helmPlugins.helm-diff}/helm-diff";
+    };
+
+    test.stubs.kubernetes-helm = { };
+
+    nmt.script = ''
+      assertFileExists home-files/.local/share/helm/plugins/diff/bin/diff
+      assertFileExists home-files/.local/share/helm/plugins/diff/plugin.yaml
+
+      assertFileContains home-files/.local/share/helm/plugins/diff/plugin.yaml \
+        'command: "$HELM_PLUGIN_DIR/bin/diff"'
+    '';
+  };
+}