sys-apps/tuned: add 2.23.0

Signed-off-by: Yixun Lan <[email protected]>

sys-apps/tuned/Manifest

@@ -1 +1,2 @@
 DIST tuned-2.22.1.tar.gz 254690 BLAKE2B 1942aed859425494df702a45900d6e0c26c799f19427cb1ff18160ed49cf8ac78ae3b73a39f1120a1dc5d344c3c1e61298085c54655aa13052600b946cb16a41 SHA512 160b1cab5477d84a0da89f584fe646b32162527a138d9b5957799c5f26598b98449733040710133a1c5bdd5588eee72549131ff163e777a105fc24e92edc6d8f
+DIST tuned-2.23.0.tar.gz 261402 BLAKE2B 7fb46fc8eb074779c963c8424c3e802cd9ef216ef80cd96ba8d9d3f1bc83dc03187496044d164cbc1ef6c164ee9004b2dfc6795cf6b6605cb662502f3b4cc5c2 SHA512 b7d95b17ab38ac944e6e5b8b4345ddf65120a03ebb73cdb1795525c237852a8fa4223dcef6ce28189874e5010c8076816bd3646fd7f700983f2449400a2057d8

sys-apps/tuned/tuned-2.23.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit optfeature python-single-r1 tmpfiles xdg-utils
+
+DESCRIPTION="Daemon for monitoring and adaptive tuning of system devices"
+HOMEPAGE="https://github.com/redhat-performance/tuned"
+SRC_URI="https://github.com/redhat-performance/tuned/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/configobj[${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/decorator[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/python-linux-procfs[${PYTHON_USEDEP}]
+		dev-python/pyudev[${PYTHON_USEDEP}]
+	')"
+
+RDEPEND="
+	${DEPEND}
+	app-emulation/virt-what
+	dev-debug/systemtap
+	sys-apps/dbus
+	sys-apps/ethtool
+	sys-power/powertop
+	"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^PYTHON/s:/usr/bin/python3:${EPREFIX}/usr/bin/${EPYTHON}:" \
+		-e "/^export DOCDIR/s/$/&\-\$(VERSION)/g" \
+		-e "/\$(DESTDIR)\/run\/tuned/d" \
+		-e "/\$(DESTDIR)\/var\/lib\/tuned/d" \
+		-e "/\$(DESTDIR)\/var\/log\/tuned/d" \
+		Makefile || die
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	python_fix_shebang "${D}"
+	python_optimize
+}
+
+pkg_postinst() {
+	tmpfiles_process ${PN}.conf
+	xdg_icon_cache_update
+
+	optfeature_header
+	optfeature "Optimize for power saving by spinning-down rotational disks" sys-apps/hdparm
+	optfeature "Get hardware info" sys-apps/dmidecode
+	optfeature "Optimize network txqueuelen" sys-apps/iproute2
+}