Flake support, project reorganization, asahi overlay

flake.nix

@@ -0,0 +1,69 @@
+{
+  description = "Apple M1 support for NixOS";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+    rust-overlay.url = "github:oxalica/rust-overlay";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+  };
+
+  outputs = { self, flake-parts, ... }@inputs:
+    flake-parts.lib.mkFlake { inherit inputs; } (
+      { withSystem, ... }: {
+        flake = {
+          overlays = rec {
+            asahi-overlay = import packages/overlay.nix;
+            default = asahi-overlay;
+          };
+
+          nixosModules = rec {
+            m1-support = ./nixos-module;
+            default = m1-support;
+          };
+        };
+
+        # build platforms supported for uboot in nixpkgs
+        systems = [ "aarch64-linux" "x86_64-linux" "i686-linux" ];
+
+        perSystem = { system, pkgs, ... }: {
+          # override the `pkgs` argument used by flake-parts modules
+          _module.args.pkgs = import inputs.nixpkgs {
+            crossSystem.system = "aarch64-linux";
+            localSystem.system = system;
+            overlays = [
+              inputs.rust-overlay.overlays.default
+              self.overlays.default
+            ];
+          };
+
+          packages = {
+            inherit (pkgs) m1n1 uboot-asahi;
+
+            installer-bootstrap =
+              let
+                installer-system = inputs.nixpkgs.lib.nixosSystem {
+                  inherit system;
+
+                  # make sure this matches the post-install
+                  # `hardware.asahi.pkgsSystem`
+                  pkgs = import inputs.nixpkgs {
+                    crossSystem.system = "aarch64-linux";
+                    localSystem.system = system;
+                    overlays = [ self.overlays.default ];
+                  };
+
+                  specialArgs = {
+                    modulesPath = inputs.nixpkgs + "/nixos/modules";
+                  };
+
+                  modules = [
+                    ./iso-configuration
+                    { hardware.asahi.pkgsSystem = system; }
+                  ];
+                };
+              in installer-system.config.system.build.isoImage;
+          };
+        };
+      }
+    );
+}

nix/installer-bootstrap/iso-configuration.nix → iso-configuration/default.nix

@@ -3,22 +3,23 @@
 {
   imports = [
     ./installer-configuration.nix
-    ../m1-support
+    ../nixos-module
   ];
 
   # include those modules so the user can rebuild the install iso. that's not
   # especially useful at this point, but the user will need the m1-support
   # directory for their own config.
   installer.cloneConfigIncludes = [
     "./installer-configuration.nix"
-    "./m1-support"
+    "./m1-support/nixos-module"
   ];
 
   # copy the m1-support and installer configs into the iso
   boot.postBootCommands = lib.optionalString config.installer.cloneConfig ''
     if ! [ -e /etc/nixos/m1-support ]; then
+      mkdir -p /etc/nixos/m1-support
       cp ${./installer-configuration.nix} /etc/nixos/installer-configuration.nix
-      cp -r ${../m1-support} /etc/nixos/m1-support
+      cp -r ${../packages} ${../nixos-module} -t /etc/nixos/m1-support
     fi
   '';
 }

nix/installer-bootstrap/installer-configuration.nix → iso-configuration/installer-configuration.nix

@@ -29,7 +29,7 @@
   fileSystems = lib.mkOverride 60 config.lib.isoFileSystems;
 
   boot.postBootCommands = let
-    asahi-fwextract = pkgs.callPackage ../m1-support/asahi-fwextract {};
+    inherit (config.hardware.asahi.pkgs) asahi-fwextract;
   in ''
     for o in $(</proc/cmdline); do
       case "$o" in
@@ -61,13 +61,13 @@
 
   isoImage.squashfsCompression = "zstd -Xcompression-level 6";
 
-  environment.systemPackages = [
-    pkgs.gptfdisk
-    pkgs.parted
-    pkgs.cryptsetup
-    pkgs.curl
-    pkgs.wget
-    pkgs.wormhole-william
+  environment.systemPackages = with pkgs; [
+    gptfdisk
+    parted
+    cryptsetup
+    curl
+    wget
+    wormhole-william
   ];
 
   # save space and compilation time. might revise?

nix/m1-support/boot-m1n1/default.nix → nixos-module/boot-m1n1/default.nix

@@ -1,12 +1,14 @@
 { config, pkgs, lib, ... }:
 let
-  bootM1n1 = config.hardware.asahi.pkgs.callPackage ../m1n1 {
+  pkgs' = config.hardware.asahi.pkgs;
+
+  bootM1n1 = pkgs'.m1n1.override {
     isRelease = true;
     withTools = false;
     customLogo = config.boot.m1n1CustomLogo;
   };
 
-  bootUBoot = config.hardware.asahi.pkgs.callPackage ../u-boot {
+  bootUBoot = pkgs'.uboot-asahi.override {
     m1n1 = bootM1n1;
   };
 

nix/m1-support/default.nix → nixos-module/default.nix

@@ -7,14 +7,22 @@
     ./boot-m1n1
   ];
 
-  config = {
-    hardware.asahi.pkgs = if config.hardware.asahi.pkgsSystem != "aarch64-linux"
-    then import (pkgs.path) {
-        system = config.hardware.asahi.pkgsSystem;
-        crossSystem.system = "aarch64-linux";
-      }
-    else pkgs;
-  };
+  config =
+    let
+      cfg = config.hardware.asahi;
+    in {
+      nixpkgs.overlays = lib.mkBefore [ cfg.overlay ];
+
+      hardware.asahi.pkgs =
+        if cfg.pkgsSystem != "aarch64-linux"
+        then
+          import (pkgs.path) {
+            crossSystem.system = "aarch64-linux";
+            localSystem.system = cfg.pkgsSystem;
+            overlays = [ cfg.overlay ];
+          }
+        else pkgs;
+    };
 
   options.hardware.asahi = {
     pkgsSystem = lib.mkOption {
@@ -35,5 +43,19 @@
         with the system defined by `hardware.asahi.pkgsSystem`.
       '';
     };
+
+    overlay = lib.mkOption {
+      type = lib.mkOptionType {
+        name = "nixpkgs-overlay";
+        description = "nixpkgs overlay";
+        check = lib.isFunction;
+        merge = lib.mergeOneOption;
+      };
+      default = import ../packages/overlay.nix;
+      defaultText = "overlay provided with the module";
+      description = ''
+        The nixpkgs overlay for asahi packages.
+      '';
+    };
   };
 }

nix/m1-support/kernel/default.nix → nixos-module/kernel/default.nix

@@ -3,11 +3,14 @@
 { config, pkgs, lib, ... }:
 {
   config = {
-    boot.kernelPackages = config.hardware.asahi.pkgs.callPackage ./package.nix {
-      inherit (config.boot) kernelPatches;
-      _4KBuild = config.hardware.asahi.use4KPages;
-      withRust = config.hardware.asahi.withRust;
-    };
+    boot.kernelPackages = let
+      pkgs' = config.hardware.asahi.pkgs;
+    in
+      pkgs'.linux-asahi.override {
+        inherit (config.boot) kernelPatches;
+        _4KBuild = config.hardware.asahi.use4KPages;
+        withRust = config.hardware.asahi.withRust;
+      };
 
     # we definitely want to use CONFIG_ENERGY_MODEL, and
     # schedutil is a prerequisite for using it